Buenos dias Srs, quisiera que me apoye con alguna formula en como convertir los datos de la columna D4 es decir , lo primero que tiene que ir son los Apellidos y luego los nombres, y como se puede apreciar en el archivo primero están los 1 o 2 nombres y luego los apellidos.

 

Desde ya agradezco su apoyo y atencion.

Consulta de Afiliados AFP - PTO ILO.xlsx

En base a lo explicado participo con la siguiente propuesta que debería poder cumplir con lo expuesto.

Saludines.

=CONCATENAR(DERECHA(D4,LARGO(D4)-HALLAR(" ",D4,HALLAR(" ",D4)+1)), " ", IZQUIERDA(D4,HALLAR(" ",D4,HALLAR(" ",D4)+1)-1))

Por favor solo cambia tu separador de argumentos de (;) a (,)

Tu libro

Consulta de Afiliados AFP - PTO ILO.xlsx

Hola a ambos lo mismo pero con macros

Consulta de Afiliados AFP - PTO ILO.xlsm

Muchas gracias a los amigos  @Israel Cassales@JSDJSD, por su apoyo en lo solicitado.

Que tal a todos, me permito aportar otra posible solución empleando M365:

=MAP(D4:D307,LAMBDA(n,CONCAT(INDICE(DIVIDIRTEXTO(n," ")&" ",SI(CONTAR.SI(n,"* * * *"),{3,4,1,2},{2,3,1})))))

Espero les sea útil.

buenas noches @Oscar_MRF, gracias por el aporte.

¡Hola a todos!

Otra opción M365:

=TEXTODESPUES(D4:D307;" ";-2)&", "&TEXTOANTES(D4:D307;" ";-2)

¡Bendiciones!

buenas días @Oscar_MRF, @John Jairo V gracias por el aporte.

y en caso que los nombre sean compuestos?  ejemplo maria del socorro perez ponce

.........¿y en el caso de nombres y apellidos compuestos? 

Por ejemplo:  Felipe Juan Froilán de Todos los Santos de Marichalar y Borbón

Felipe Juan Froilán de Marichalar y Borbón - Wikipedia, la enciclopedia libre

😲

hace 22 horas, Sergio M. P. dijo:

y en caso que los nombre sean compuestos?  ejemplo maria del socorro perez ponce

hace 9 horas, Victor7 dijo:

Por ejemplo:  Felipe Juan Froilán de Todos los Santos de Marichalar y Borbón

Saludos totales,

Bueno, se tiene que editar un poco porqué el tratar de gestionar las múltiples variantes en los nombres aunque no es complicado hay que intentar ser creativos.

=CONCATENAR(EXTRAE(A2, HALLAR("#", SUSTITUIR(A2, " ", "#", LARGO(A2) - LARGO(SUSTITUIR(A2, " ", "")) - C2)) + 1, LARGO(A2))," ",SUSTITUIR(A2,(EXTRAE(A2, HALLAR("#", SUSTITUIR(A2, " ", "#", LARGO(A2) - LARGO(SUSTITUIR(A2, " ", "")) - 1)) + 1, LARGO(A2))),""))

También se debería poder simplificar un poco:

=LET(
    texto, A2,
    espaciosTotales, LARGO(texto) - LARGO(SUSTITUIR(texto, " ", "")),
    posicionSegundoEspacio, HALLAR("#", SUSTITUIR(texto, " ", "#", espaciosTotales - 1)),
    textoRestante, EXTRAE(texto, posicionSegundoEspacio + 1, LARGO(texto)),
    nombreRestante, SUSTITUIR(texto, textoRestante, ""),
    CONCATENAR(textoRestante, " ", nombreRestante)
)

Y bueno, si nos ponemos creativos para anticipar opciones, se podrían reemplazar el "Y" y los "DE" con los "DEL" por "" para eliminarlos.

Lo anterior es solo una idea, no es exacta para TODAS las posibles combinaciones, así por lo general hay que personalizar.

 

AYUDA EXCEL.xlsx

En 10/7/2024 at 13:38 , Israel Cassales dijo:

se tiene que editar un poco porqué el tratar de gestionar las múltiples variantes en los nombres aunque no es complicado hay que intentar ser creativos

excelente truco, si tan solo se pudiera automatizar la cuenta de palabras (o espacios) en los apellidos 🤔

(creo que) seguirá quedando "a ojo de buen cubero" 🫡

@Héctor Miguel

Fíjate que el contar las palabras o los espacios, considero no es el desafío principal, sino la interpretación. Por ejemplo, LUNA puede ser nombre o apellido y como éste hay múltiples situaciones.

Lo que me sorprende es el origen de los datos, por lo regular en los desarrollos el nombre o nombres y los apellidos se escriben en cuadros de texto independientes, algo que no pasa con los usuarios tradicionales cuando hacen su plantillas en las hojas de Excel, por lo regular los dejan juntos y luego ocurre que los necesitan separar para extraer por decir algo el número de identificación RFC, DNI, etc., concatenando algunas letras de los nombres y pasan este tipo de escenarios.

Saludines.

Editado el el 16 de julio1 año por Israel Cassales