NUMERAR CELDAS QUE CONTENGAN TEXTO

[OCTAVIO GONZALEZ]

Buenas noches, yo de nuevo pero con otro tema,

Necesito numerar por orden (1,2,3...) automáticamente las celdas que contengan cualquier texto y que deje en blanco las que no contengan nada, aunque haya espacios entre las filas que lo compongan, ejemplo.

 

Si yo moviera los nombres, los números se moverían automáticamente sin necesidad de yo hacer algo y siguiendo el orden (1,2,3...)

 

NOTA: No quiero que se eliminen las filas en blanco, quiero que se mantenga el cuadro en su originalidad

NOTA2: El nombre escrito en la columna B no tiene relevancia para el número asignado, solo con que vaya en orden.

Gracias por su ayuda

Libro1.xlsx

[GabrielRaigosa]

Hola,

Seguro hay muchas alternativas, he hecho algo al vuelo...

Indicas que tienes MSO 365, la formula trabaja con matrices dinámicas.

 

Saludos,

 

numerar registros.xlsx

[Victor7]

Hola a ambos,

Otra fórmula M365 podría ser:

=MAP(B2:B8;LAMBDA(a;SI(a="";"";CONTARA(B2:a))))

Nota 1:  La fórmula iría en A2 (he borrado el texto que tiene tu ejemplo, ya que el 3º de tus dibujos del post 1 lleva nombres en todas las celdas).

Nota 2:  Una fórmula vulgaris  podría ser:

=SI(B2<>"";CONTARA(B$2:B2);"")

también introducida en A2, que en este caso habrá que copiar verticalmente hasta donde sea necesario.

Saludos,

Numeración (B).xlsx

[OCTAVIO GONZALEZ]

Me van a disculpar, pero al aplicarlo a mi problema surgio un problema ya que en las celdas "sin texto" resultaba ser que "si tenia". pero con una función SI .. 

Resulta que "las celdas que estas vacías" realmente tienen una fórmula de SI (Por ejemplo: SI(F3=4,G3,"")

ANEXO IMAGEN CON SUS 3 RESPUESTAS QUE ME DIERON.

Si bien cuenta las celdas, pero marca las celdas que no tienen nada aparentemente pero si tienen con la función del SI que termina en "", 

Quisiera que se omitan los "", y que cuente solamente los que realmente tengan texto y no un "".

Anexo archivo.

NUMERACION (C).xlsx

[GabrielRaigosa]

Hola,

Revisa el adjunto

=LET(r,D3:D8,t,(ESTEXTO(r)*LARGO(r)>0),SI(t,SCAN(0,t,LAMBDA(up,dn,up+dn)),""))

NUMERACION Celdas txt.xlsx

[OCTAVIO GONZALEZ]

hace 2 horas, GabrielRaigosa dijo:

=LET(r,D3:D8,t,(ESTEXTO(r)*LARGO(r)>0),SI(t,SCAN(0,t,LAMBDA(up,dn,up+dn)),""))

Muchas gracias, esta fórmula es la solución al problema!

[Oscar_MRF]

hace 4 horas, OCTAVIO GONZALEZ dijo:

Quisiera que se omitan los "", y que cuente solamente los que realmente tengan texto y no un "".

Que tal a todos, solo por aportar me permito compartir otra posible solución:

=MAP(D3:D8,LAMBDA(d,SI(LARGO(d),CONTAR.SI(D3:d,">"""),"")))

Espero les sea útil.

[GabrielRaigosa]

Hola nuevamente,

Adicional a la formula que pasa Oscar, se puede modificar la formula que pasé antes así:

=LET(t,LARGO(D3:D8)>0,SI(t,SCAN(0,t,LAMBDA(up,dn,up+dn)),""))

No es necesaria esta parte:

>  ESTEXTO(r)
> r,D3:D8

[John Jairo V]

¡Saludos a todos!

Yéndose por la base... puede quedar también:

=MAP(F3:F8;LAMBDA(x;SI(x=4;CONTAR.SI(F3:x;4);"")))

¡Bendiciones!