Buenas estimados,

He estado buscando en el foro y no encuentro un ejemplo similar a lo que estoy necesitando.

Tengo este número en una celda por ejemplo en A1, 974666666 quisiera que extraiga el número que tiene la mayor cantidad de números repetidos consecutivos, para este ejemplo el número 6.

¡Desde ya muchas gracias, un saludo desde Paraguay!

Hola, con mis conocimientos desconozco de alguna fórmula que haga eso de manera nativa o qué fórmulas puedas combinar manteniendo el contenido como un valor (que serían varias por cierto), pero si la conviertes en un texto previo, tal vez combinando como el ejemplo podría hacerse.

=INDICE(EXTRAE(A1,FILA(INDIRECTO("1:"&LARGO(A1))),1),COINCIDIR(MAX(LARGO(A1)-LARGO(SUSTITUIR(A1,EXTRAE(A1,FILA(INDIRECTO("1:"&LARGO(A1))),1),""))),LARGO(A1)-LARGO(SUSTITUIR(A1,EXTRAE(A1,FILA(INDIRECTO("1:"&LARGO(A1))),1),"")),0))

Pero sin cambiar el origen de la celda de un valor a un texto te devolverá error.

Así que con lo que yo puedo participar es con hacer una función personalizada y con eso llegas sin problemas a lo que estás buscando.

Adjunto libro con ejemplo.

Está interesante la consulta y quedo al pendiente para aprender en caso de que algún maestro participe con algo más simple o eficiente.

Saludines.

 

AYUDA EXCEL.xlsb

Hola!!

Estuve planteando mi formulita muy parecida a la que hizo Israel, pero luego me di cuenta que no cumplía uno de los requisitos:

hace 18 horas, Hbarreto dijo:

repetidos consecutivos

Luego me dije que la mejor forma era con Macros... pero vi que el mensaje fue posteado en la categoría de fórmulas.

Te juro que mi cerebro casi explota, lo logré (pero con fórmulas de M365) aunque seguramente habrán mejores maneras de lograrlo. Espero te sea de utilidad (y no te vuelvas loco en el intento)

=LET(Datos,LET(Datos,LET(Datos,LET(Datos,LET(Datos,LET(Posicion,SECUENCIA(LARGO(A1)),Caracteres,EXTRAE(A1,Posicion,1),CaracteresAnteriores,TOMAR(APILARV("X",Caracteres),LARGO(A1)),CaracteresSiguientes,TOMAR(APILARV(Caracteres,"X"),-LARGO(A1)),SigueSecuencia,SIGNO((CaracteresAnteriores=Caracteres)+(Caracteres=CaracteresSiguientes)),SigueSecuenciaAnterior,TOMAR(APILARV("X",SigueSecuencia),LARGO(A1)),InicioGrupo,SI(SigueSecuencia<>SigueSecuenciaAnterior,Posicion),Desde,K.ESIMO.MENOR(InicioGrupo,Posicion),Hasta,TOMAR(APILARV(TOMAR(Desde,CONTAR(Desde)),"X"),-CONTAR(Desde)),Repeticiones,SI(Hasta="X",LARGO(A1)+1,Hasta)-Desde,EsSecuencial,INDICE(SigueSecuencia,Desde),TOMAR(APILARH(EsSecuencial,Desde,Repeticiones),CONTAR(Desde))),ELEGIRCOLS(FILTRAR(Datos,ELEGIRCOLS(Datos,1)=1),2,3)),Datos),FILTRAR(Datos,ELEGIRCOLS(Datos,2)=MAX(ELEGIRCOLS(Datos,2)))),Letras,EXTRAE(A1,ELEGIRCOLS(Datos,1),1),APILARH(Letras,Datos)),Maximo,MAX(ELEGIRCOLS(Datos,3)),Letras,ELEGIRCOLS(Datos,1,2),CONCATENAR("Máximas repeticiones consecutivas: ",Maximo," ► ",UNIRCADENAS("; ",,BYROW(Letras,LAMBDA(T,UNIRCADENAS(" en la posición ",,T))))))

Me olvidaba!!! Funciona con dígitos numéricos o con alfanuméricos (letras / símbolos)

Funciona también si hay empate en cantidad de repeticiones, indicando qué letra/número se repite, cuántas veces y en qué posiciones (podría repetirse en mismo número/letra la misma cantidad de veces en posiciones diferentes), como por ejemplo: ESTOOOOOY LOOOOOCOOOOO, VERDAD?????

Máximas repeticiones consecutivas: 5 ► O en la posición 4; O en la posición 12; O en la posición 18; ? en la posición 31

En 21/7/2023 at 15:03 , Israel Cassales dijo:

Hola, con mis conocimientos desconozco de alguna fórmula que haga eso de manera nativa o qué fórmulas puedas combinar manteniendo el contenido como un valor (que serían varias por cierto), pero si la conviertes en un texto previo, tal vez combinando como el ejemplo podría hacerse.

=INDICE(EXTRAE(A1,FILA(INDIRECTO("1:"&LARGO(A1))),1),COINCIDIR(MAX(LARGO(A1)-LARGO(SUSTITUIR(A1,EXTRAE(A1,FILA(INDIRECTO("1:"&LARGO(A1))),1),""))),LARGO(A1)-LARGO(SUSTITUIR(A1,EXTRAE(A1,FILA(INDIRECTO("1:"&LARGO(A1))),1),"")),0))

Pero sin cambiar el origen de la celda de un valor a un texto te devolverá error.

Así que con lo que yo puedo participar es con hacer una función personalizada y con eso llegas sin problemas a lo que estás buscando.

Adjunto libro con ejemplo.

Está interesante la consulta y quedo al pendiente para aprender en caso de que algún maestro participe con algo más simple o eficiente.

Saludines.

 

AYUDA EXCEL.xlsb 13.56 kB · 4 descargas

Muchas gracias @Israel Cassales estaba en una fórmula similar a la tuya, me sirve de todos modos.

Saludos estimado!

En 21/7/2023 at 15:47 , DiegoPC dijo:

Me olvidaba!!! Funciona con dígitos numéricos o con alfanuméricos (letras / símbolos)

Funciona también si hay empate en cantidad de repeticiones, indicando qué letra/número se repite, cuántas veces y en qué posiciones (podría repetirse en mismo número/letra la misma cantidad de veces en posiciones diferentes), como por ejemplo: ESTOOOOOY LOOOOOCOOOOO, VERDAD?????

Máximas repeticiones consecutivas: 5 ► O en la posición 4; O en la posición 12; O en la posición 18; ? en la posición 31

@DiegoPC no lo quise decir yo, pero tú lo has dicho jajajaja, muchas gracias por la colaboración estimado!

 

Saludos.-

Que tal a todos, solo por aportar otra posible opción:

=LET(_s,EXTRAE(A1,SECUENCIA(LARGO(A1)),1),_c,COINCIDIRX(_s,_s),_f,EXCLUIR(FRECUENCIA(_c,_c),-1),APILARV({"Numero","Veces"},FILTRAR(APILARH(_s,_f),_f=MAX(_f))))

Espero les sea útil.

Repetir caracter mas repetido (Solucion).xlsx

Wow! super pro con cabeceras dinámicas, muchas gracias @Oscar_MRF por tu gran aporte!

Saludos estimado!

Hola @Oscar_MRF la solución y la lógica están excelentes, sólo un comentario, no dice en el título (perdón por eso) pero si en la descripción del problema que los números deben de ser consecutivos, (tienen que estar uno a lado del otro).

por ejemplo 0974666666 (se repite el 6 y son consecutivos) este extrae.

por ejemplo 0585654535 (se repite el 5 pero no están juntos) no extrae.

Saludos.-

hace 4 horas, Hbarreto dijo:

los números deben de ser consecutivos, (tienen que estar uno a lado del otro).
por ejemplo 0974666666 (se repite el 6 y son consecutivos) este extrae.
por ejemplo 0585654535 (se repite el 5 pero no están juntos) no extrae.

el 'core' de la formula que buscas parece requerir de:
- comparar si 'el que sigue' = 'al anterior' (escalonados) +/- asi:

=1+max(largo(dividirtexto(unircadenas("",,0+(extrae(a1,secuencia(largo(a1)-1,,2),1)=extrae(a1,secuencia(largo(a1)-1),1))),,0)))

devolvera el mayor numero de caracteres/digitos 'seguidos' (pero NO te dice cual es)

si no hay ninguno 'seguido' devuelve 1 (uno), que si no lo quieres ver como 1, envuelves la formula con un SIUSTITUIR(...

=sustituir(1+max(largo(dividirtexto(unircadenas("",,0+(extrae(a1,secuencia(largo(a1)-1,,2),1)=extrae(a1,secuencia(largo(a1)-1),1))),,0))),1,"")

puedes cambiar el ultimo "" por un 0 (cero), te lo devolvera como texto, o le antepones un "0+" al sustituir(...

por si quieres convertir a LET o LAMBDA (y quiza con otras funciones ?)

Muchas gracias @Héctor Miguel voy a desglosar tu fórmula para intentar entenderla.

Saludos desde Paraguay! 

Que tal a todos, va mi propuesta adaptada a la condición de repetidos consecutivos.

Espero les sea útil.

 

Repetir caracter mas repetido (Solucion).xlsx

Muchas gracias @Oscar_MRF funciona perfecto, increíble fórmula! 

@Oscar_MRF nuevamente yo con una petición especial para ti, y me disculpo con el resto, como debería de ser esta misma fórmula si sólo quisiera que me extraiga el número que se repite varias veces y en forma consecutiva. En nuestro ejemplo el número 6, sin cabeceras y sin conteo.

¡De antemano mil disculpas y muchas gracias!

¡Hola @Hbarreto!

Aunque no es expresamente a mi a quien le has pedido el favor, dejo una propuesta:

=LET(s;SECUENCIA(10)-1;b;MAP(s;LAMBDA(x;LET(n;SECUENCIA(LARGO(A1));e;--EXTRAE(A1;n;1);MAX(FRECUENCIA(SI(e=x;n);SI(e<>x;n))))));FILTRAR(s;(b>1)*(b=MAX(b));"No hay"))

¡Bendiciones!

Muchas gracias por su colaboración profesor @John Jairo V gran y valioso aporte como siempre, la solución funciona a la perfección!

Que tal a todos, ya solo por aportar, dejo mi solución corregida según lo requerido:

=LET(_s,EXTRAE(A1,SECUENCIA(LARGO(A1)),1),_m,EXCLUIR(_s,-1)&EXCLUIR(_s,1),_u,UNICOS(_s),_r,_u&_u,_d,ORDENAR(APILARH(_u,ENCOL(1+MMULT(SECUENCIA(,FILAS(_m))^0,--(_m=ENFILA(_r))))),2,-1),FILTRAR(INDICE(_d,,1),INDICE(_d,,2)>1,"No encontrado"))

 

Muchísimas gracias @Oscar_MRF gran aporte, ahora a estudiar la increíble solución proporcionada!

 

¡Saludos desde Paraguay!