FUNCION INDICE CON COINCIDIR - JERARQUIA

[OCTAVIO GONZALEZ]

Buenas tardes compañeros, ocupo de su ayuda para lograr una jerarquia en donde pueden haber varios primeros lugares, varios segundos lugares y asi sucesivamente, pero al momento de usar la funcion INDICE-COINCIDIR con la funcion de JERARQUIA que tengo, repite el mismo nombre y no selecciona a los demás. Ejemplo:

Les dejo el excel donde ya tengo los datos y me ayuden a encontrar la fórmula para que aparezcan los demas nombres aunque ocupen el mismo lugar.

(Como adicional, si se puede acomodar por abecedario los que empaten mucho mejor, si es muy complicado no importa solo con que aparezcan los demas nombres)

JERARQUIA.xlsx

[Oscar_MRF]

Que tal, verificando la consulta y considerando que cuenta con M365 propongo esta posible solución:

=LET(_p,H7:H16,_n,COINCIDIRX(_p,ORDENAR(_p,,-1)), APILARH(ORDENAR(_n),ORDENARPOR(G7:H16,_n)))

Espero le sea útil.

Editado el el 27 de diciembre por Oscar_MRF
Corrección de fórmula

[OCTAVIO GONZALEZ]

hace 3 horas, Oscar_MRF dijo:

=LET(_p,H7:H16,_n,COINCIDIRX(_p,ORDENAR(_p,,-1)), APILARH(ORDENAR(_n),ORDENARPOR(G7:H16,_n)))

Excelentisima aportación, gracias, doy por solucionado el tema.

[John Jairo V]

¡Hola a ambos!

Otra opción:

=ORDENAR(APILARH(JERARQUIA(H7:H16;H7:H16);G7:H16);3;-1)

¡Bendiciones!

[OCTAVIO GONZALEZ]

Buenas noches, gracias a la aportación de los dos! @Oscar_MRF y @John Jairo V

Me acabo de percatar de algo que quisiera modificar a la fórmula, si bien ordena los lugares y pone 2 segundos lugares con distinto nombre el lugar número 3 se lo salta, y se brinca hasta el 4, y luego vuelve a pasar lo mismo ya que el lugar cuarto se repite 3 veces y se va después al lugar 7..

Quisiera que no se salte los números y siga con la numeración que corresponda, debería de quedar así:

Editado el el 31 de diciembre por OCTAVIO GONZALEZ

[Oscar_MRF]

En 30/12/2023 at 23:43 , OCTAVIO GONZALEZ dijo:

Quisiera que no se salte los números y siga con la numeración que corresponda

Que tal nuevamente, atendiendo lo requerido propongo esta posible solución:

=LET(_f, LAMBDA(i, j, ORDENAR(i, j, -1)), APILARH(COINCIDIRX(_f(H7:H16, 1),_f(UNICOS(H7:H16), 1)),_f(G7:H16, 2)))

Espero le sea útil.

[John Jairo V]

¡Hola a ambos!

Otra opción puede ser:

=LET(o;-ORDENAR(-H7:H16);APILARH(COINCIDIRX(o;UNICOS(o));ORDENAR(G7:H16;2;-1)))

¡Bendiciones!

[Victor7]

Hola a todos,

Una tercera opción:

=APILARH(BYROW(H7:H16;LAMBDA(a;CONTAR(UNICOS(H7:a))));ORDENAR(ORDENAR(G7:H16);2;-1))

Esta opción contempla también esta posibilidad:

En 27/12/2023 at 19:35 , OCTAVIO GONZALEZ dijo:

...Como adicional, si se puede acomodar por abecedario los que empaten mucho mejor...

Saludos,

[John Jairo V]

Cierto @Victor7... entonces:

=LET(o;-ORDENAR(-H7:H16);APILARH(COINCIDIRX(o;UNICOS(o));ORDENAR(G7:H16;{2;1};{-1;1})))

Nota: Tu solución tiene las "jerarquías" mal ordenadas...

¡Bendiciones!