Buenos dias, 

Requiero de su ayuda en incorporar a una formula, una segunda condicion, resulta que necesito sumar en siempre "Seguros de Autos" y "Seguros de Mexico", sin embargo, al tratar de incluir la segunda condicion me da un error, por lo que necesito ayuda de los expertos amigos muchas gracias 

Formula:

=SI(O(IGUAL($A14,""), IGUAL(Q$2, "")), "", CONTAR.SI.CONJUNTO('Lista de Seguros'!$D:$D,"Seguro de Auto",'Lista de Seguros'!$Y:$Y,Q2,'Lista de Seguros'!$H:$H,$C$1,'Lista de Seguros'!$B:$B,$A$14))

 

Aqui solo necesito que tambien cuente con la variable o condicion "Seguro de Mexico"

 

Muchisimas Gracias,

 

Quote

Quote

 

Quote

 

 

 

Por favor, ayúdanos subiendo un archivo con un ejemplo de lo que requieres. En caso de que el archivo contenga datos confidenciales, trata de sustituirlos por otros que sirvan para darte solución.

Un saludo,

Sergio estoy usando el google sheets,  te lo adjunto

 

=SI(O(IGUAL($A14,""), IGUAL(Q$2, "")), "", CONTAR.SI.CONJUNTO('Lista de Seguros'!$D:$D,"Seguro de Auto",'Lista de Seguros'!$Y:$Y,Q2,'Lista de Seguros'!$H:$H,$C$1,'Lista de Seguros'!$B:$B,$A$14))

Necesito su ayuda, en incluir ademas de buscar por "Seguro de Auto" Tambien busque "Seguro de Mexico".

Muchisimas Gracias,

ayuda.xlsx

Por lo que veo, las referencias de las celdas que indican las condiciones están mal expresadas. Fíjate en si son absolutas o relativas y actúa en consecuencia. 

Por otra parte, ¿qué necesitas hacer? En el mensaje indicas que quieres sumar. Sin embargo, en la fórmula del archivo usas una función para contar.

 

Le puedo compartir el libro de excel de google 

 

https://docs.google.com/spreadsheets/d/1Oy7zTSI9w2a0EQJf0piNs4QhrS2XFO8qfGS8kB7ZjZg/edit?usp=sharing

Necesito su ayuda, en incluir ademas de buscar por "Seguro de Auto" Tambien busque "Seguro de Mexico" en la hoja de excel que se llama  "Polizas x Dia".

Muchisimas Gracias,

 

Hola, cómo estás?

No es posible usar la función y CONTAR.SI.CONJUNTO con dos condiciones, usando como rango de criterios la misma columna, puesto que una celda solo puede contener un valor (o Seguros de auto o Seguros de México). El problema está en que para que funcione CONTAR.SI.CONJUNTO deben cumplirse ambas condiciones, lo cual no se puede.

La fórmula que te propongo es la siguiente:

=SI(O(IGUAL($A3,""), IGUAL(C$2, "")), "", CONTAR.SI.CONJUNTO('Lista de Seguros'!$D:$D,"Seguro de Auto",'Lista de Seguros'!$Y:$Y,C$2,'Lista de Seguros'!$H:$H,$C$1,'Lista de Seguros'!$B:$B,$A3)+CONTAR.SI.CONJUNTO('Lista de Seguros'!$D:$D,"Seguro de México",'Lista de Seguros'!$Y:$Y,C$2,'Lista de Seguros'!$H:$H,$C$1,'Lista de Seguros'!$B:$B,$A3))

He usado dos CONTAR.SI.CONJUNTO y he sumado sus resultados. También comprobarás que he hecho algunas correcciones en las referencias de las celdas para que puedas arrastrar la fórmula sin problemas.

Espero que te sirva.

Hola!

Hace 7 horas, Sergio dijo:

No es posible usar la función y CONTAR.SI.CONJUNTO con dos condiciones, usando como rango de criterios la misma columna

Es verdad, como lo indica Sergio

Pero con un pequeño truco combinando con SUMA o SUMAPRODUCTO [con esta ultima para que no sea matricial]

Puede quedar así:

=SUMAPRODUCTO(CONTAR.SI.CONJUNTO('Lista de Seguros'!$D:$D,{"Seguro de Auto","Seguro de México"},'Lista de Seguros'!$Y:$Y,C$2,'Lista de Seguros'!$H:$H,$C$1,'Lista de Seguros'!$B:$B,$A3))

 

Saludos 

Hola,

revisando las formulas en el calculo obtengo el valor 0, no me suma en el caso del dia 18 la agente rosalva deberia tener con las dos condiciones el resultado de 4.

Me podrian ayudar se los agradezco mucho

 

https://docs.google.com/spreadsheets/d/1Oy7zTSI9w2a0EQJf0piNs4QhrS2XFO8qfGS8kB7ZjZg/edit?usp=sharing

Por favor, prueba la fórmula que te ofrece Gerson.

Como te he comentado en un mensaje anterior, las condiciones introducidas en CONTAR.SI.CONJUNTO deben cumplirse las dos y por tanto no se pueden basar en la misma columna, puesto que en una celda solo tienes un valor.

Un saludo,

Hola a todos,

@JUL AYALA, no tengo claro si ya tienes resuelto tu tema, pero por si acaso, te subo un archivo, simplificado al máximo, sobre cómo enfocaría yo la búsqueda de resultados.

En las fórmulas de la hoja 'P' podrías añadir en el segundo argumento, de ser necesario, algún 3^er o 4º parámetro.

De la misma forma, el último argumento (ENTERO...............) te permite prescindir de cálculos auxiliares para evaluar la fecha prescindiendo de hh:mm:ss.

Saludos,

Ayuda (B).xlsx

En 25/5/2022 at 12:40 , Gerson Pineda dijo:

Hola!

Es verdad, como lo indica Sergio

Pero con un pequeño truco combinando con SUMA o SUMAPRODUCTO [con esta ultima para que no sea matricial]

Puede quedar así:

=SUMAPRODUCTO(CONTAR.SI.CONJUNTO('Lista de Seguros'!$D:$D,{"Seguro de Auto","Seguro de México"},'Lista de Seguros'!$Y:$Y,C$2,'Lista de Seguros'!$H:$H,$C$1,'Lista de Seguros'!$B:$B,$A3))

 

Saludos 

Buenas @Gerson Pineda, habría posibilidad de meter otra constante matricial en la segunda condición 'Lista de Seguros'!$Y:$Y,{X,Y}

Hace 48 minutos , Hbarreto dijo:

Buenas @Gerson Pineda, habría posibilidad de meter otra constante matricial en la segunda condición 'Lista de Seguros'!$Y:$Y,{X,Y}

Claro @Hbarreto, es la misma lógica, reemplaza la referencia, por constantes encerradas con llaves

 

@Gerson Pineda Serías tan amable de compartir un ejemplo 

Hace 2 horas, Hbarreto dijo:

@Gerson Pineda Serías tan amable de compartir un ejemplo 

He visto que el tema no lo iniciaste, pero 2 cosas, o subes un archivo de tu problema, partiendo que es similar al de @JUL AYALA 

Si es diferente tu escenario, entonces mejor crea un tema nuevo

¿Qué te parece?

Hace 1 hora, Gerson Pineda dijo:

He visto que el tema no lo iniciaste, pero 2 cosas, o subes un archivo de tu problema, partiendo que es similar al de @JUL AYALA 

Si es diferente tu escenario, entonces mejor crea un tema nuevo

¿Qué te parece?

ok haré eso, muchas gracias @Gerson Pineda