Extraer día de la semana

[Maku]

Buenas noches, ya he visto como extraer el día de la semana, el día o el mes de una celda en la que he introducido una fecha. Mi pregunta es como puedo hacer eso mismo, extraer el día de la semana (lunes, martes...) pero partiendo de los datos en celdas independientes (en una el número de día, en otra el mes y en otra el año.

Tengo un archivo de muestra en el que hace algo parecido, pero al cambiar el año no responde.

Gracias por la ayuda

Fecha.xlsx

Muestra.xlsx

Editado el el 22 de noviembre por Maku

[Israel Cassales]

Hola.

En base a lo que entendí podría ser de utilidad lo siguiente, como no sé su versión de Excel pero en 2013 sería algo así.

Para agrupar la fecha en un solo resultado:

=FECHA(A3, COINCIDIR(B3, {"ENERO","FEBRERO","MARZO","ABRIL","MAYO","JUNIO","JULIO","AGOSTO","SEPTIEMBRE","OCTUBRE","NOVIEMBRE","DICIEMBRE"}, 0), C3)

Luego de ese resultado tomar el día:

=ELEGIR(DIASEM(C5, 2), "Lunes", "Martes", "Miércoles", "Jueves", "Viernes", "Sábado", "Domingo")

O en una sola:

=ELEGIR(DIASEM(FECHA(A3, COINCIDIR(B3, {"ENERO","FEBRERO","MARZO","ABRIL","MAYO","JUNIO","JULIO","AGOSTO","SEPTIEMBRE","OCTUBRE","NOVIEMBRE","DICIEMBRE"}, 0), C3), 2), "Lunes", "Martes", "Miércoles", "Jueves", "Viernes", "Sábado", "Domingo")

Y en 365 podría ser algo así:

=LET(
   año, A3,
   mes, COINCIDIR(B3, {"ENERO", "FEBRERO", "MARZO", "ABRIL", "MAYO", "JUNIO", "JULIO", "AGOSTO", "SEPTIEMBRE", "OCTUBRE", "NOVIEMBRE", "DICIEMBRE"}, 0),
   día, C3,
   fecha, FECHA(año, mes, día),
   díaSemana, DIASEM(fecha, 2),
   ELEGIR(díaSemana, "Lunes", "Martes", "Miércoles", "Jueves", "Viernes", "Sábado", "Domingo")
)

Saludines

[Israel Cassales]

Podrías hacer algo parecido al libro de muestra pero hay que editar un poco los nombres y eso, así que mejor participaré con las fórmulas anteiores.

Saludines_2

Fecha - AYUDA EXCEL.xlsx

[Maku]

Tengo 2013, podré apañarme con las primeras.

¡Mil gracias!

[Israel Cassales]

Parece que le ha servido, concluyo mi participación en la consulta.

[Victor7]

Hola a ambos,

@Maku, no tengo claro si funcionará en versiones antiguas, pero prueba con:

=FECHA(A3;MES(B3&1);C3)

Si esa misma fórmula la introduces en una celda que tenga formato personalizado dddd, te ofrecerá el día de la semana a que corresponde.

Saludos,

[Maku]

Efectivamente, así también funciona Victor7

Ahora ya conozco dos modos diferentes de hacerlo, dependiendo de lo que necesite.

¡Gracias!

Ahora tengo otra duda que no se resolver pero, como es cuestión de buscar una celda, revisaré el foro y en su caso abriré un hilo diferente

Editado el el 23 de noviembre por Maku

[DiegoPC]

Hola a todos

También funcionaría concatenando

=TEXTO(C3&"/"&B3&"/"&A3,"dddd")

 

[njnsp]

Por aportar...

En el archivo muestra, cambiaria C5 por 

Cita

=FECHA(CalendarYear;1;January[[#Encabezados];[1]])

personalizaria el tipo de datos en "ddd" y arrastraria hasta AG5