Unir rangos de celdas

[Paco Garrido]

Buenos días, a ver si hay alguien que me pueda echar una mano:

Necesito una función en la que el resultado sea la unión de 3 rangos en una hoja de excel. He encontrado después de mucho navegar una solución para unir 2 rangos y no consigo implementarla para 3 o más.

= LET(

    m; FILAS(rango1);

    n; FILAS(rango2);

    k; SECUENCIA(m+n);

    SI(k<=m; INDICE(rango1;k); INDICE(rango2;k-m))

  )

agradecería la ayuda

(PD.: no me vale la función APILARV)

gracias

[Victor7]

Hola,

¿Por qué no subes un archivo para ver cómo y dónde están esos 3 rangos, y cómo y dónde quieres unirlos? ¿Vertical, horizontalmente, con/sin espacios,.......?

Mejor no dejar nada a la imaginación de quien pretenda ayudarte.

¿Y por qué no te vale la función =APILARV? ... Puede ser una excelente herramienta.

?

 

[John Jairo V]

Saludos @Paco Garrido

Imagino que lo de no usar APILARV es por tu Excel 2021.  Siendo así, esta es una opción ejemplo para 4 rangos (llamados _r1; _r2; _r3 y _r4):

=LET(
    m; FILAS(_r1);
    n; FILAS(_r2);
    o; FILAS(_r3);
    p; FILAS(_r4);
    s; SECUENCIA(m + n + o + p);
    SI.CONJUNTO(
        s > m + n + o; INDICE(_r4; s - m - n - o);
        s > m + n; INDICE(_r3; s - m - n);
        s > m; INDICE(_r2; s - m);
        1; INDICE(_r1; s)
    )
)

¡Bendiciones!

[Paco Garrido]

Perfecto !!! mil gracias