Hay forma de simplificar esta fórmula?

Si un valor es mayor o igual  que me traiga el resultado, o en su defecto, si es superior que me calcule por un porcentaje.- 

=SI.ERROR(SI(A2=A;"";SI(Y(F2>=17500;F2<20000);20000;SI(Y(F2>=20000;F2<32000);35000;SI(Y(F2>=32000;F2<40000);F2*2%;SI(Y(F2>=40000);F2*3%;0)))));"")

Aquí, le estoy pidiendo que se fije primero en la hoja PREMIO, si se cumple la primer condición que es a que rango pertenece, en este caso A, y si es, que se fije si es mayor o igual a 17500 y menor a 20000, en funcion de esto me arroja el resultado 17500... así con cada valor.

El tema es que no puedo hacer que me traiga el valor por cada opción. es decir al principio busca si es A, el tema es que tengo mas opciones que son By C 

Si es B  que revise el resultado y lo mismo si es C...  si anido los SI, tengo 6 lineas de formula, por eso consulto si, considerando la poca información que estoy dando, ya que no puedo subir el archivo y no me sale..

Hola,

Si lo he entendido bien, prueba con:

=ELEGIR(COINCIDIR(F2;{0;17,5;20;32;40}*1000);0;20000;35000;F2*2%;F2*3%)

Me despista un poco ese inicial =SI(A2=A;"".......

Si te refieres a que en la celda A2 se encuentre una A, deberás entrecomillarla, anteponiendo a la fórmula que te paso:

=SI(A2="A";""; ..............y a partir de aquí la fórmula.

Saludos,

Gracias por tu ayuda, el tema es que no me está buscando si la letra es A, B o C

Este es un ejemplo, que tengo desde la Celda A1 hasta G12

En premio fijo es donde pego  el calculo... 

Asignacion	Legajo	Nombre y Apellido	Usuario	PISO	RECUPERO	PREMIO FIJO
A			JUAN	$ 1.750.000	$        2.000.000
A			PEPE	$ 1.750.000	$        1.750.000
A			MARIO	$ 1.750.000	$        3.000.000
A			RAUL	$ 1.750.000	$        3.300.000
A			GUSTAVO	$ 1.750.000	$           685.330
B			VALERIA	$    400.000	$           400.000	$ 12.000,00
B			MARIEL	$    400.000	$           555.000	$ 16.650,00
B			CARLOS	$    400.000	$           490.000	$ 14.700,00
C			MARTIN	$    400.000	$           480.000	$ 14.400,00
C			MARIEL	$    400.000	$           555.000	$ 16.650,00
C			ROMINA	$    400.000	$           250.000	$ 7.500,00

De acá levanto los datos está en las celdas  i4:l17

	ESCALAS	Valor	Premio
A	Piso	$ 1.750.000	$ 20.000,00
A	segunda escala	$ 2.000.000	$ 35.000,00
A	tercer escala	$ 3.200.000	$ 50.750,00
A	cuarta escala	$ 3.200.000	2,00%
A	Quinta escala	$ 4.000.000	3,00%
B	Piso	$ 400.000	$6.000
B	segunda escala	$ 480.000	$9.600
B	tercer escala	$ 550.000	$13.750
B	cuarta escala	$ 550.000	2,50%
C	Piso	$ 465.000	$10.000
C	segunda escala	$ 500.000	$15.000
C	tercer escala	$ 550.000	$16.500
C	cuarta escala	$ 550.000	3,00%

Hola de nuevo,

Bien, la fórmula concreta que te pasé resolvía [creo] el problema concreto que planteaste en tu post inicial; es decir:

Hace 5 horas, Guada dijo:

Hay forma de simplificar esta fórmula?

Si un valor es mayor o igual  que me traiga el resultado, o en su defecto, si es superior que me calcule por un porcentaje.- 

=SI.ERROR(SI(A2=A;"";SI(Y(F2>=17500;F2<20000);20000;SI(Y(F2>=20000;F2<32000);35000;SI(Y(F2>=32000;F2<40000);F2*2%;SI(Y(F2>=40000);F2*3%;0)))));"")

La fórmula queda simplificada y se obtienen los valores requeridos (supongo).  Del resto de tu post (otras opciones, otras cantidades,...) no se puede hacer mucho sin datos concretos, de la misma forma que sin disponer de un archivo Excel resulta complicado perseguir metas más complejas.

Saludos,

Que tal, analizando la consulta propongo esta posible solución siguiendo estos pasos:

1. En la hoja "PREMIOS" seleccionar y nombrar los rangos de las 3 escalas:

     "Escala_A" --> H5:I9      "Escala_B" --> H10:I13        "Escala_C" --> H14:I17

2. Copiar y arrastrar desde la celda G2 la siguiente fórmula:

=SI.ERROR(BUSCARV(F2;INDIRECTO("Escala_"&A2);2;1)*F2^(COINCIDIR(F2;INDICE(INDIRECTO("Escala_"&A2);;1);1)>3);"-")

Espero le sea útil.

Gracias,  No tenía en claro el proceso "Indirecto" y coincidir... había probado con BuscarV pero me traía 1 valor unico y no me salía como calcular cuando llegaba a los porcentajes... 

Resuelto con tu respuesta, y respecto al archivo, no me dejan acá subir el archivo en la página, probé varias veces y me decía que solo podía subir una foto de la hoja