Exportar a PDF con Macros

[Edy Camacho]

Tengó la siguiente macro que me permite exportar a PDF en una ruta definida por mi:

Option Explicit
Sub CreaPDF()

Dim NombreArchivo, RutaArchivo, historico, separador As String

NombreArchivo = Cells(7, 3).Value
RutaArchivo = Cells(42, 2).Value
historico = Cells(3, 6).Value
separador = “-”

ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=RutaArchivo & NombreArchivo & separador & historico, _
Quality:=xlQualityStandard, IncludeDocProperties:=True, _
IgnorePrintAreas:=False, OpenAfterPublish:=False

End Sub

Esa macro me exporta a un pdf la planilla que tengo en una ruta definida. Lo que necesito hacer ahora es que la celda F7 que contiene una lista desplegable se ejecute sola hasta el final y vaya guardando los documentos en PDF como si los estuviera haciendo uno por uno. Me podrían ayudar.

[aaquino]

Que les cuesta leer las recomendaciones... Más el punto 2....

Si no puedes subir tu archivo como tal, sube una muestra, a ciegas NO SE PUEDE AYUDAR.

[Héctor Miguel]

Hace 1 hora, jcamacho1989 dijo:

... la siguiente macro... exportar a PDF ... Lo que necesito hacer ahora es que la celda F7 que contiene una lista desplegable se ejecute sola hasta el final y vaya guardando los documentos en PDF como si los estuviera haciendo uno por uno...

si la celda F7 "toma" datos a mostrar desde algún rango en alguna hoja (?), podrías englobar esa macro en un "For...Next" (del principio al fin de la lista)

si tuvieras algún "detalle en el tintero"... comentas lo que sigue pendiente ?

saludos,

hector.

[Edy Camacho]

Muchas aaquino y Héctor, he probado la opción que me mencionaste Héctor pero sin resultados, les muestro lo que tengo a manera de prueba para ver si pueden ayudarme.

 

Gracias.

ejemplo.xlsm

[Héctor Miguel]

Hace 3 horas, jcamacho1989 dijo:

he probado la opción que me mencionaste... pero sin resultados, les muestro lo que tengo a manera de prueba

la macro que tienes asignada al botón, cámbiala por lo siguiente:

Sub CreaPDF()
  Dim separador As String, origen As String, celda As Range, _
         NombreArchivo As String, RutaArchivo As String, historico As String ', contador As Integer
  separador = "-"
  origen = Mid(Cells(7, 6).Validation.Formula1, 2)
  For Each celda In Range(origen)
    Cells(7, 6).Value = celda
    NombreArchivo = Cells(7, 3).Value
    RutaArchivo = Cells(42, 2).Value
    historico = Cells(3, 6).Value
    ActiveSheet.ExportAsFixedFormat _
      Type:=xlTypePDF, Filename:=RutaArchivo & NombreArchivo & separador & historico, _
      Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
  Next
'  ActiveCell.Offset(7, 3).Select
End Sub

analízala antes de probarla, considerando que no contempla ninguna prevención/corrección de (posibles) errores, como: rutas no especificadas, celdas vacías en el rango de la lista para la validación, etc.

saludos,

hector.

[Edy Camacho]

Hector, probé lo que me dices, me funcionó excelente. Te lo agradezco inmensamente. Gracias.