Mensajes emergentes Excel

[Daniel_E]

Saludos!,

Estoy importando datos desde una pagina web hacia mi libro de excel, otras macros realizan otras operaciones con dichos datos,

El problema que tengo actualmente es que en algunas ocaciones el excel muestra un mensaje emergente y detiene todas las macros que se están ejecutando, hasta que el usuario presione "Aceptar" (Adjunto mensaje) 

Quisiera que el excel no muestre ningún mensaje y que las macros sigan ejecutándose, o que de alguna manera los acepte, (espero poder explicarme),

En internet encontre esta linea de comando ""  Application.DisplayAlerts = False  "" Pero no me funciona, o al menos el mensaje sigue saliendo, 

Mil Gracias,

Daniel,

[Gerson Pineda]

Hola @Wapurapura 

Usa lo que se denomina "controladores de error"

Por ejemplo

sub macro()

on error resume next

rem los codigos de tu macro van aqui

on error goto 0

end sub



sub macro2()

on error goto err:

rem los codigos de tu macro van aqui

err:

end sub

 

Saludos 

[Daniel_E]

Gracias por su pronta respuesta,

Pero el mensaje de error lo envía el excel no una macro como tal, los controladores de error como mencionas ya los estoy aplicando al código,

Saludos,

[Gerson Pineda]

Es posible que no los estés usando correctamente, corre la macro paso a paso, porque si el servidor no esta disponible esa linea es un error y para eso son estos controladores

 

Saludos 

[Daniel_E]

Bueno, yo actualizo los datos desde "Conexiones de Datos" no desde una macro, con la configuración siguiente:

+Habilitar actualización en segundo plano

+Actualizar cada 1 minuto

+Actualizar al abrir el archivo 

Si esto pudiese pasarse a una macro podría agregar el controlador de error, Gracias.

[AlbertoMs]

No te queda otra que utilizar código vba para automatizar la obtención de datos externos con el método QueryTables.

 

[Daniel_E]

Gracias, investigare como hacer la macro para obtener datos externos, 

Saludos,

 

[Daniel_E]

Bueno, de lo investigado obtengo esta macro para actualizar mis datos 

Sub Macro2()

    With ActiveSheet.QueryTables.Add(Connection:= _
        "URL;http://sitr.cnd.com.pa/m/pub/gen.html", Destination:=Range("$A$1"))
        .Name = "gen"
        .FieldNames = True
        .RowNumbers = False
        .FillAdjacentFormulas = False
        .PreserveFormatting = True
        .RefreshOnFileOpen = True
        .BackgroundQuery = True
        .RefreshStyle = xlOverwriteCells
        .SavePassword = False
        .SaveData = True
        .AdjustColumnWidth = True
        .RefreshPeriod = 1
        .WebSelectionType = xlEntirePage
        .WebFormatting = xlWebFormattingNone
        .WebPreFormattedTextToColumns = True
        .WebConsecutiveDelimitersAsOne = True
        .WebSingleBlockTextImport = False
        .WebDisableDateRecognition = False
        .WebDisableRedirections = False
        .Refresh BackgroundQuery:=False
    End With
End Sub

Ahora, en que parte coloco los controladores de error para que en caso de actualizar y no vea conexión a Internet siga el resto de las instrucciones,  (esta macro esta en un modulo aparte)

[AlbertoMs]

Aquí:

 

On error go to Error1

--- pega el código anterior aquí ---

 

exit sub

Error 1:

msgbox err.description

 

[Héctor Miguel]

hola, a todos !

Hace 12 minutos , Wapurapura dijo:

de lo investigado obtengo esta macro para actualizar mis datos 

la macro que expones CREA una tabla/consulta (nueva) cada vez que se ejecuta (con algunos otros imponderables) además de que establece en falso la actualización en segundo plano (es así como lo requieres ?)

otra (RE)pregunta sería; que tan imprescindible es actualizar los datos "cada minuto" ?

podrías no usar un refresco automático (cada minuto) y cambiarlo por un procedimiento que actualice confirmando primero si dicha pagina esta disponible (todo depende de la periodicidad con que se requiera -realmente- actualizar los datos ?)

saludos,

hector.

[Daniel_E]

Que tal Hector,

Si la macro contiene algunos errores agradezco tus comentarios para corregirlos ya que no soy experto en el tema,

Solo busco que los datos de la pagina web puedan actualizare constantemente optimizando el proceso (pero si debe ser 1 min) (No necesariamente hay que crear todo nuevo solo actualizar)

En teoría la pagina siempre esta disponible pero de algún modo justo cuando realiza la consulta envía el error de conexión a la pagina (No pasa siempre solo en algunas ocaciones) Si no le doy aceptar para el resto de los procesos. 

[Daniel_E]

Como hago para que la consulta actualice en una hoja especifica y no en la hoja activa, 

Gracias,

 

 With ActiveSheet.QueryTables.Add(Connection:= _
        "URL;http://sitr.cnd.com.pa/m/pub/gen.html", Destination:=Range("$A$1"))

 

[Héctor Miguel]

Hace 7 horas, Wapurapura dijo:

Como hago para que la consulta actualice en una hoja especifica y no en la hoja activa

1. Confirma que te vas a decidir por continuar con la creación de una tabla nueva cada vez que se ejecute esa macro (por el método QueryTables,Add)
2. En ese caso, deberás eliminar la tabla anterior (a reserva de que la tomes como origen de otros cálculos ?)
3. En su caso, comenta si te decides por conservar el método por "Conexiones de Datos", para lo que sugiero desactivar las actualizaciones automáticas y usar otro tipo de macros para dichas actualizaciones (?)

 

saludos,
hector.

[Daniel_E]

Buen Día,

Por lo que logro entender no es optimo utilizar (QueryTable.Add) ya que tendría que crear nuevas tablas a cada instante, (descartamos este método)

Si el método de (Conexión de Datos) es mas efectivo, lo único que requiero es que actualice en una hoja especifica siempre por ejemplo: la hoja llamada "Conexion1" Las actualizaciones podrían hacerse con otra macro,

Al final mis otras hojas llamadas (Datos1, Datos2) tomarían los "Datos Externos" de la hoja "Conexion1" para hacer los cálculos,

 

Espero haber respondido tu pregunta,

Daniel,

[Héctor Miguel]

Hace 11 horas, Wapurapura dijo:

Si el método de (Conexión de Datos) es mas efectivo... requiero... que actualice... siempre... la hoja llamada "Conexion1"

ok, deja la tabla creada desde "conexiones de datos" y en la configuración te aseguras de DESmarcar las opciones para:

• Habilitar actualización en segundo plano
• Actualizar cada 1 minuto
• Actualizar al abrir el archivo

y las actualizaciones se harán por macros con los siguientes procedimientos:

1) en el modulo del libro (ThisWorkbook)

Private Sub Workbook_Open()
  queryRefresh
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
  detenerQR
End Sub

y en un modulo de código estándar:

' procedimientos para refrescar tablas de datos cada "tiempo" comprobando disponibilidad de la web ' _
  R&D: Héctor Miguel Orozco Díaz | abril de 2016 '
Public tiempo As Date
Public Const cada As String = "0:01:00" ' <= se reprograma cada minuto '
Public Const web1 As String = "http://sitr.cnd.com.pa/m/pub/gen.html" ' <= la pagina a comprobar '
Sub queryRefresh()
  If sitioDisponible(web1) Then Worksheets("conexion1").QueryTables(1).Refresh ' BackgroundQuery:=True
  tiempo = Now + TimeValue(cada)
  Application.OnTime tiempo, "queryRefresh"
End Sub
Sub detenerQR()
  On Error Resume Next
  Application.OnTime tiempo, "queryRefresh", Schedule:=False
End Sub
Function sitioDisponible(url As String) As Boolean
' UDF para determinar si la pagina buscada esta disponible en la web ' _
  R&D: Héctor Miguel Orozco Díaz | abril de 2016 '
  On Error Resume Next
  With CreateObject("msxml2.serverxmlhttp")
    .Open "get", url, 0
    .Send ""
  End With
  sitioDisponible = Err.Number = 0
End Function

haz pruebas y comenta si surgen detalles no considerados

saludos,

hector.

[Daniel_E]

Bueno a funcionado a la perfección!,

Como siempre, gracias @Héctor Miguel por el valioso tiempo, @Gerson Pineda, @AlbertoMs por sus aportes,

Saludos,

Daniel,