Lista desplegable

[animal]

hola a tod@s, lo que estoy intentando hacer y no me sale, es que al introducir datos en una columna de la hoa "datos" lo reconozca la lista desplegable de la hoja 1, sin tener que estar validando continuamente, ni tener que asignar nombre a un rango con celdas vacias para seguir introduciendo datos.

Gracias

Libro1.rar

[Fleming]

Amplía el rango de CÁCERES al definir el nombre.

Acompaño archivo

Saludos

Libro1BIS.rar

[sama86]

Para lograr que la lista se actualice automaticamente al agregar mas nombres en la columna "caceres" se debe definir el rango como un rango dinamico. Para esto se debe definir el rango "caceres" con la siguiente fórmula:

=DESREF(DATOS!A1,0,0,CONTARA(DATOS!A:A),1)

Saludos desde Perú.

[animal]

Hola, el problema Fleming es que en la lista deplegable me salen tambien las celdas vacias del rango que no tiene datos.

Gracias.

--- Mensaje unido automáticamente ---

Hola sama86, me da error la formula podrias utilizar el adjunto?, y así comprobar la formula y si lo hago mal.

Gracias

[Toldeman]

Hola.

Revisa el adjunto, en el nombre definido esta la formula que te propuso sama que seguramente te diese error porque su separador de argumentos es la " , " y tu tendrás " ; "

Un saludo.

Ps: Fleming un placer compartir post contigo

1.xls

[Fleming]

No acabo de entenderlo del todo.

¿no se obtiene el mismo resultado con, por ejemplo, =DATOS!A:A ?

Un saludo

[ioyama]

Hola Fleming

En este caso sí.

Un saludo desde Vitoria

[Fleming]

Eso pensaba yo.

Un cordial saludo a los cuatro

[animal]

Hola, al final lo he conseguido pero con esta formula =DESREF(DATOS!$A$2;;;CONTARA(DATOS!$A:$A);1), no se porqué la formula de sama86 no funcionaba y la de Fleming me mostraba todas las celdas vacias, con la que he usado solo sale una celda vacia, aunque muestra los nombre desde el ultimo y no desde el primero.

Gracias por vuestra ayuda.

[Invitado Cacho R]

Hola! Animal.

Como para despejar cualquier tipo de duda que te haya quedado:

a) Bien dice Toldeman que la fórmula de sama no te funcionó:

- "... porque su separador de argumentos es la "," y tu tendrás ";" ..."

De modo que la versión sama86/Toldeman sería:

[COLOR=#FF8C00][B]= DESREF(DATOS!$A$1; 0; 0; [/B][/COLOR][COLOR=#ff8c00][B]CONTARA(DATOS!$A:$A)[/B][/COLOR][COLOR=#ff8c00][B]; 1)[/B][/COLOR][/CODE]

_________________________

c) Y te la explico: estás tratando de definir un rango (el que llamas CACERES). La siguiente parte de la fórmula:

[color=#ff8c00][b]= DESREF(DATOS!$A$1; 0; 0;[/b][/color]

indica que la celda superior izquierda del rango en cuestión (en este caso no hay izquierda ni derecha pues estamos analizando un rango "columna") es la celda A1.

Esta es la razón por la que la fórmula que tu muestras es más correcta:

[color=#ff8c00][b]= DESREF(DATOS!$A$2; 0; 0;[/b][/color]

ya que define a la celda A2 como la superior en lugar de la celda A1. Lo mismo pudiste conseguir así:

[color=#ff8c00][b]= DESREF(DATOS!$A$1; 1; 0;[/b][/color]

[color=#ff8c00][b]= DESREF(DATOS!$A$3; -1; 0;[/b][/color]

[color=#ff8c00][b]= DESREF(DATOS!$A$4; -2; 0;[/b][/color]

etc etc etc.

_________________________

d) Esta otra parte de la fórmula:

[color=#ff8c00][b]CONTARA(DATOS!$A:$A)[/b][/color]

define la cantidad de filas que contendrá el rango.

Como te darás cuenta, aquí se está contando -también- la fila 1 (la que contiene el título de la columna). Volviendo a tu fórmula, lo correcto sería:

[color=#FF8C00][b]CONTARA(DATOS!$A:$A) - 1

[/b][/color]_________________________

e) El [b][color=#ff8c00]1[/color][/b] final de la fórmula te indica que el rango establecido por el [b]DESREF[/b] será de una (1) columna.

_________________________

[u]En resumen[/u]: lo mejor para tí sería

[color=#ff8c00][b]= DESREF(DATOS!$A$2;;; CONTARA(DATOS!$A:$A) - 1; 1)[/b][/color]

(siempre pensando en la ubicación de los datos del libro que has subido)

_________________________

f) La fórmula que te ha mostrado Fleming:

[b]= DATOS!A:A[/b]

claramente "señala" a toda la columna A, en lugar de a las celdas de la columna A que tienen datos.

Por ello es que veías tantas filas vacías... Por decirlo de algún modo: no comprendió tu necesidad.

_________________________

Saludos para todos.

[kasaius]

Hola a todos:

Muy buena explicación Cacho R! Pero tengo un problema con el nombre dinámico. Utilizo =DESREF(Datos!$A$2;0;0;CONTARA(Datos!$A:$A)-1;1), pero sólo me reconoce los datos hasta la fila 64! No deberían de aparecerme todos los datos que ingreso en la columna A en la lista desplegable? Espro que podais echarme un cable en el asunto.

Un saludo.

[Invitado Cacho R]

Hola a todos:

Muy buena explicación Cacho R! Pero tengo un problema con el nombre dinámico. Utilizo =DESREF(Datos!$A$2;0;0;CONTARA(Datos!$A:$A)-1;1), pero sólo me reconoce los datos hasta la fila 64! No deberían de aparecerme todos los datos que ingreso en la columna A en la lista desplegable? Espro que podais echarme un cable en el asunto.

Un saludo.

No te puedo decir "ni que sí ni que no" pues como no has subido tu archivo de muestra, no estoy en condiciones de afirmar -a ciencia cierta- donde te encuentras obviando algún detalle de implementación.

[kasaius]

Hola de nuevo y perdona por la torpeza :shame: Pensé que quizás esto ya le había pasado a alguien, porque soy muy novato con el excel.

Te subo el ejemplo. Un saludo

Ejemplo Trabajo.xls

[ioyama]

Hola kasaius

Tienes filas en blanco que evidentemente CONTARA no cuenta pero que sí que ocupan espacio en el rango.

Ejemplo sencillo

A1= Hola

A2=

A3=Adiós

CONTARA(A1:A3)=2

pero hay 3 filas luego estás perdiendo una de cara a DESREF, es decir por cada fila en blanco perderás un dato en el rango dinámico.

Elimina esas filas y verás que la lista te devuelve todos los datos.

Un saludo desde Vitoria

[Invitado Cacho R]

Hola! kasaius.

A propósito de la más que adecuada observación que publicara ioyama, podrías intentar otra forma. O sea:

- En lugar de:

Lista

=DESREF(Ejercicios!$A$2;0;0;CONTARA(Ejercicios!$A:$A)-1;1)

- Intenta:

Lista

= INDIRECTO("Ejercicios!a2:a" & MAX(SI(Ejercicios!$A:$A<>""; FILA(Ejercicios!$A:$A))))

Saludos, Cacho R.

[kasaius]

Vaya peazo de cracks!! Muchas gracias por vuestras aclaraciones.

La segunda fórmula de Cacho R me viene perfecta, muchas gracias. Con la explicación de Ioyama, me ha quedado claro la función "CONTARA", ya que no sabía que por cada fila en blanco perdía un dato en el rango dinámico. Ya lo estaba arreglando con una chapucilla usando la función SI y la función ESBLANCO para que me contaran esas celdas en blanco como si tuviesen datos jaja Cuanto tengo que aprender!

Muchísimas gracias de nuevo a los dos. Un saludo.

[Invitado Cacho R]

Tema SOLUCIONADO, entonces...