Borrar filas cuando encuentre parámetro

[rafaelmartinez19682]

 

Hola a todos

Agradezco de antemano cualquier ayuda / gestión.

Tengo un listado de facturas donde con fórmula detecto si ha sido COBRADA o no.

Estoy buscando código que cuando encuentra la palabra COBRADA en la columna L,

me borre la fila.

Me he quedado en el IF, el Delete ya no sé como hacerlo.

Reitero las gracias

 

====================================

Sub BORRAR_COBRADAS()

Dim i  As Integer

For i = 2 To 8000

If Range("FACTURAS!L" & i) = "COBRADA" Then

Selection.EntireRow.Delete

End Sub ==================================

[JasallBcn]

Buenas , seria :

Sub BORRAR_COBRADAS()
 Dim i  As Integer
 For i = 2 To Range("A" & Rows.Count).End(xlUp).Row
  If Range("FACTURAS!L" & i) = "COBRADA" Then
   Range("FACTURAS!L" & i).EntireRow.Delete
  End If
 Next i
End Sub

saludos

[Israel Cassales]

Saludos totales,

Maestro @JasallBcn yo participaría variando en dos cosas, buscaría hasta la ultima fila con datos para hacer la eliminación de abajo hacia arriba, porque creo que si eliminas las filas de arriba hacia abajo, habría la posibilidad de saltarte algunas filas, porque las filas se reordenan cada vez que eliminas una ¿Qué opina?

Sub BORRAR_COBRADAS()
    Dim i As Long
    Dim lastRow As Long
       
    lastRow = Cells(Rows.Count, "L").End(xlUp).Row
    
    For i = lastRow To 2 Step -1 ' Recorre de abajo hacia arriba
        If Range("FACTURAS!L" & i).Value = "COBRADA" Then
            Rows(i).EntireRow.Delete
        End If
    Next i
End Sub

 

[Antoni]

Otra más:

Sub BORRAR_COBRADAS()
 Dim i As Long
 For i = Range("A" & Rows.Count).End(xlUp).Row To 2 Step -1
  If Range("L" & i) = "COBRADA" Then
   Rows(i).Delete
  End If
 Next
End Sub

[JasallBcn]

hace 2 horas, Israel Cassales dijo:

Maestro @JasallBcn yo participaría variando en dos cosas, buscaría hasta la ultima fila con datos para hacer la eliminación de abajo hacia arriba, porque creo que si eliminas las filas de arriba hacia abajo, habría la posibilidad de saltarte algunas filas, porque las filas se reordenan cada vez que eliminas una ¿Qué opina?

 Pues tienes toda la razón, @Israel Cassales  tu propuesta y la @Antoni son las correctas.

Escribí el código sin pensar en ese detalle.

Saludos

 

[JSDJSD]

Hola a todos, dejo otra más

Sub BorrarCobros()
    With Hoja1
        Set rango = .Range("A1").CurrentRegion
        rango.AutoFilter Field:=12, Criteria1:="COBRADA"
        .Range("A2:A" & .Cells(.Rows.Count, "A").End(xlUp).Row) _
               .SpecialCells(xlCellTypeVisible).EntireRow.Delete
        .AutoFilterMode = False
    End With
End Sub

Suponiendo que los datos los tienes en la Hoja1 (nombre interno)

[JSDJSD]

Sub BorrarCobros()
    With Sheets("Hoja1")
        Set rango = .Range("A1").CurrentRegion
        rango.AutoFilter Field:=12, Criteria1:="COBRADA"
        .Range("A2:A" & .Cells(.Rows.Count, "A").End(xlUp).Row) _
               .SpecialCells(xlCellTypeVisible).EntireRow.Delete
        .AutoFilterMode = False
    End With
End Sub

Esta sería la otra variante