Hola a todos,

  No consigo la formula que me cuente las celdas de una columna que contengan la letra "T" o la letra "N"

 Os agradecería me ayudarais

En base a lo explicado con esta fórmula debería ser suficiente

=CONTAR.SI(A1:A100, "*T*") + CONTAR.SI(A1:A100, "*N*")

Esta fórmula cuenta el número de celdas en el rango A1:A100 que contienen la letra “T” o “N”. Los asteriscos (*) alrededor de “T” y “N” son comodines que permiten a Excel buscar estas letras en cualquier parte de la celda.

Para próximas consultas es deseable que el libro de ejemplo lo proporcione usted.

 

Contar si contiene la letra T o la letra N - AYUDA EXCEL.xlsb

Editado el el 15 de diciembre1 año por Israel Cassales

Es perfecta. Muchísimas gracias por la ayuda

Hola a ambos,

Sólo una observación:  La fórmula (correcta) de @Israel Cassales, puede simplificarse así:

=SUMA(CONTAR.SI(A1:A100; {"*T*";"*N*"}))

que sería útil en el caso de que hubiere muchos caracteres a evaluar, ya que evitaría excesivas repeticiones del =CONTAR.SI.

Saludos,

¡Saludos a todos!

Si nos vamos a la consulta inicial:

En 14/12/2023 at 19:27 , GROGUITO dijo:

la formula que me cuente las celdas de una columna que contengan la letra "T" o la letra "N"

La idea es contar las celdas, no las "apariciones" de la letra T o la letra N.  En el caso que se expone, se está contando 8 donde hay 7 celdas, puesto que la celda A1 contiene tanto la letra T como la letra N, por lo que se cuenta doble con las fórmulas propuestas.

Una propuesta para realizar esto, sería, por ejemplo:

=CONTAR(1/MMULT(1-ESERR(HALLAR({"T"\"N"};A1:A100));{1;1}))

¡Bendiciones!

Saludos.

Importante e interesante la observación, aunque siendo un poco estrictos, en el ejemplo no está contando las apariciones porque sino como resultado devolvería 9 porque la palabra TOTAL contiene dos T.

Por esta causa toma nuevamente la importancia de que el consultante aporte el libro con sus ejemplos.

Gran fórmula la que compartió el Maestro @John Jairo V

En el caso de que fuera necesario como él recomienda, presentaría una menos avanzada:

=SUMAPRODUCTO((ESNUMERO(HALLAR("T", A1:A100)) + ESNUMERO(HALLAR("N", A1:A100)) > 0)*1)

Editado el el 18 de diciembre1 año por Israel Cassales

Contar si contiene la letra T o la letra N - AYUDA EXCEL.xlsb

Efectivamente (equivocación mía)... en sentido estricto la fórmula propuesta no "contaba las apariciones", sino que contaba si en la celda existía al menos una T o una N, pero si ambas aparecían, sumaba esa T y esa N como 2 (TN era la celda que se contaba doble, por ello reportaba 8).  ¡Gracias por la puntualización! ¡Bendiciones!

Hola de nuevo a ambos,

Pues sí, 😆 a veces, además de hablar de Excel, tenemos que rememorar la semántica... 😆 ......efectivamente, una cosa es la cantidad total de "T's" o "N's" que aparecen, y otra el número de celdas donde se cumple esa condición...

Bien, en cuanto a fórmulas, creo que también serviría:

=CONTAR(MMULT(SI.ERROR(HALLAR({"T"\"N"};A1:A100););{1;1})^0)

.....y otra, un poco más compleja, utilizable en M365 (no estoy seguro si en Excel-2021) :

=LET(a;SI.ERROR(HALLAR({"T"\"N"};A1:A100););SUMA(N(INDICE(a;;1)+INDICE(a;;2)<>0)))

Saludos,