Buenas tardes, tenia una duda sobre esta función ya que no sirve la función SUMAR.SI.CONJUNTO creo. En este caso me gustaría que se sumaran los datos de cierta columna X si en la columna Y pone A o B.

Entiendo que se podría hacer asi SUMAR.SI(H:H;"A";F:F) + SUMAR.SI(H:H;"B";F:F)

Pero si en vez de solo A y B hablaramos de 10 palabras, no existe alguna forma de compactar la funcion?

 

Gracias y un saludo!

Hola,

Puedes hacerlo así:

=SUMA(SUMAR.SI(H:H;{"A"\"B"};F:F))

Saludos,

........y, de la misma forma, si fuesen muchos los condicionantes a sumar, pueden incluirse en un rango para simplificar la fórmula, que quedaría así:

=SUMA(SUMAR.SI(H:H;C4:C8;F:F))

Observa el archivo adjunto...

SumarSiMúltiple.xlsx

Muchas gracias Victor! Cristalino.

Y otra duda que pensé que sabria manejar cuando supiera esto pero no lo consigo. Como sería lo mismo pero que sumara lo de la columna F cuando la H es diferente a A,B o C por ejemplo. Yo iluso de mi he probado:

=SUMA(SUMAR.SI(H:H;"<>{"A"\"B"\"C"}";F:F))

Pero no funciona.

Gracias y un saludo!

A grandes males, grandes remedios:

=SUMA(F:F)-SUMA(SUMAR.SI(H:H;{"A"\"B"\"C"};F:F))

 

¡Saludos @AvalonSant!

Lo que debes tener en cuenta es que al usar el concepto matricial, estás usando una función O intrínseca:  Es decir que, en el caso de la fórmula:

=SUMA(SUMAR.SI(H:H;{"A";"B"};F:F))

Estás sumando lo que sea A o B en la columna H.

Al cambiar el concepto de igual a diferente, necesitas cambiarlo a un concepto Y.  Es decir, que si quieres sumar todo lo que sea diferente de A y a la vez diferente de B, entonces, puedes usar:

=SUMAR.SI.CONJUNTO(F:F;H:H;"<>A";H:H;"<>B")

O, para hacerla de forma matricial, puedes usar "el concepto inverso" por ser más cómoda para varios criterios:

=SUMA(F:F)-SUMA(SUMAR.SI(H:H;{"A";"B"};F:F))

¡Bendiciones!