SUMAR AUTOMÁTICAMENTE CONFORME CAMBIA LA FECHA

[juanpablopez31]

Hola a todos, estoy buscando sumar los valores de una columna y que dicha suma se vaya actualizando automáticamente conforme se actualiza la fecha de "HOY". Es decir, deseo que la celda de SALDO ACTUAL se sume automáticamente conforme cambia la celda de FECHA ACTUAL

Adjunto archivo.  Muchas gracias por su ayuda

FECHA ACTUAL	2-abr
FECHA	DESCRIPCIÓN	INGRESO	EGRESO			SALDO TOTAL	$ 916,42
1-abr	Inicial	$ 2.023,54				SALDO ACTUAL	$ 206,52
1-abr	gasto		$         5,40
2-abr	gasto		$ 1.811,62
3-abr	gasto		$    160,00
4-abr	ingreso	$    500,00
5-abr	gasto		$    500,00
6-abr
7-abr
8-abr
9-abr
10-abr
11-abr	gasto		$    164,90
12-abr
13-abr
14-abr	ingreso	$ 1.498,00
15-abr	gasto		$              -
16-abr
17-abr	gasto		$    463,20

 

 

Gastos.xlsx

[Janlui]

Pon esta formula en H4

 

[Gerson Pineda]

Si tus datos son sobre miles, utilizando matrices, puede verse afectado el rendimiento 

Por lo que siendo así, te dejo una alternativa mas

=SUMAR.SI(A4:A21,"<="&B1,C4:C21)-SUMAR.SI(A4:A21,"<="&B1,D4:D21)

 

Saludos a ambos 

[juanpablopez31]

Muchas gracias por sus aportaciones, las dos han sido de gran ayuda

[Victor7]

Hola a todos,

Unas cuantas opciones más (algunas para M365) :

=SUMA(MMULT((A4:A34<=B1)*C4:D34;{1;-1}))
                                        
=LET(w;COINCIDIR(B1;A4:A34;);SUMA(DESREF(C4;;;w))-SUMA(DESREF(D4;;;w)))
                   
=ELEGIRFILAS(SCAN(;MAP(C4:C34;D4:D34;LAMBDA(i;e; i-e));LAMBDA(x;y;x+y));COINCIDIR(B1;A4:A34;))

Saludos,

[Gerson Pineda]

¡Hola a todos!

Me encanta más SUMAR.SI, pero ahí va otra propuesta de solución

=SUMA(C4:INDICE(C4:D21,COINCIDIR(B1,A4:A21,),)*{1,-1})