Buscar mínimo excepto cero de matriz SI

nanogama · el 23 de noviembre

Buenas a todos, mi nombre es Agustín y estoy trabajando en un proyecto en el que necesito encontrar el valor mínimo de una columna con dos criterios: que se corresponda a una fila con un determinado valor, y que sea mayor que cero. Tengo una de las columnas (Sector 1), que no tiene ningún cero en la condición, entonces no tuve problemas para obtener todos los minimos haciendo: =MIN(SI(A2:A20=K5;B2:B20)) y ejecutando con Ctrl + Shift + Enter para que sea una matriz.

Ahora, para los valores de la columna Sector 2, si hay filas con valor 0, y lo que no puedo es descartar esos ceros y que me tome el siguiente. Probé con SI(Y), y poniendo las dos condiciones, pero me devuelve 0. También probé con INDICE y COINCIDIR pero tuve el mismo resultado. Adjunto el archivo.

Aclaro, la condición 1 es buscar en la Columna A un cierto número, que me devuelva los valores que están en la Columna B y de esos valores encontrar el mínimo distinto de cero (condición 2)

Desde ya muchas gracias,

Saludos,

Agustin.

1er Entrenamiento Clase 1.xlsxFetching info...

Victor7 · el 23 de noviembre

Hola,

En cualquier celda de la hoja 'RAW', cambia la fórmula así:

{=MIN(SI((C2:C26>0)*(A2:A26=K5);C2:C26))}

Y para versiones Excel 2019 o superior, puede hacerse:

=MIN.SI.CONJUNTO(C2:C26;C2:C26;">0";A2:A26;K5)

Esta última fórmula no necesita introducirse matricialmente.

Saludos,

nanogama · el 23 de noviembre

Funciona perfecto la primera opción!

Muchas gracias!

Gerson Pineda · el 23 de noviembre

En 23/11/2022 at 15:02 , nanogama dijo:

Funciona perfecto la primera opción!

Muchas gracias!

Expand

Por si no tienes MIN.SI.CONJUNTO que aparece desde Excel 2019 o posterior

Te dejo otra opción con Agregar disponible a partir 2010

=AGREGAR(15,6,C$2:C$26/((C$2:C$26>0)*(A$2:A$26=$K5)),1)

nanogama · el 23 de noviembre

Muchas gracias Gerson!

Tengo otra duda, del mismo estilo. En el caso de mi archivo, la columna F tiene un formato de x;xx,xxx. Al utilizar las fórmulas no me reconoce los valores, entiendo que porque no reconoce el formato. Habría alguna forma de poder reconocerlos, incluso pasando a algún formato de sólo segundos en una celda auxiliar. El formato es minutos;segundos,décimas.