Buenas tardes

Espero estén bien.

Estoy intentando aplicar la formula sumar.si.conjunto pero me da como resultado 0. Adjunto ejemplo y explico. Cuando lo hago sin el criterio de la fecha me da un resultado, pero al intentar agregar el criterio de fecha, no me devuelve ningún valor, o en algunas celdas si lo suma y en otras no.

Consta de 2 Hojas: (1) Datos (2) Resultados. En esta ultima necesito aplicar la formula para obtener los datos deseados. 

"Compra" columna B de la hoja de resultados: (son las entradas, las cuales se deben sumar si cumplen con las siguientes condiciones: A- tiene la palabra WH/IN  B- Pertenece al mes del año que le corresponda. C- Tiene el CODIGO que le corresponde de la columna A.

"Venta" columna C de la hoja de resultados: (son las salidas, las cuales se deben sumar si cumplen con las siguientes condiciones: A- tiene la palabra WH/OUT  B- Pertenece al mes del año que le corresponda. C- Tiene el CODIGO que le corresponde de la columna A.

Cualquier duda, quedo a la orden.

Muchas gracias

Feliz día!

AYUDA EXCEL EJEMPLO.xlsx

Hola JOCAMI90

la formula tenía una falla

=SUMAR.SI.CONJUNTO(Datos!$D$3:$D$5000,Datos!$B$3:$B$5000,"*WH/"&B$3&"*",Datos!$C$3:$C$5000,$A4,Datos!$A$3:$A$5000,">="&$B$1,Datos!$A$3:$A$5000,"<="&FIN.MES($B$1,0))

considera que mi separador de argumentos es la coma (,), si el tuyo es otro, corriges.

esto solo funciona para las columnas B y C que pertenecen a Setiembre, deberás cambiar manualmente B1, por D1 en Octubre, esa situación se dá , debido a que utilizaste celdas combinadas,  lo que podrías hacer es descombinar  las celdas y  colocar las fechas en todas las columnas, en ese caso, la formula quedaría así:

=SUMAR.SI.CONJUNTO(Datos!$D$3:$D$5000,Datos!$B$3:$B$5000,"*WH/"&B$3&"*",Datos!$C$3:$C$5000,ESPACIOS($A4),Datos!$A$3:$A$5000,">="&B$1,Datos!$A$3:$A$5000,"<="&FIN.MES(B$1,0))

y podrías arrastrarla a la derecha y hacia abajo.. sin modificar nada. Lo de la función Espacios, queda a tu decisión, (según lo que te comento líneas abajo), no olvides que cuanto mas cálculos haga la formula, mas ralentizará tu archivo.

 

Además toma en cuenta lo siguiente:

En la columna A, de la hoja resultados, no se si todos, pero por lo menos, los que revisé, tienen un ESPACIO al final.

Para que un Texto coincida con otro, debe estar escrito EXACTAMENTE IGUAL que en la base de búsqueda.

podríamos agrandar la formula, para quitar los espacios, de esta forma

=SUMAR.SI.CONJUNTO(Datos!$D$3:$D$5000,Datos!$B$3:$B$5000,"*WH/"&B$3&"*",Datos!$C$3:$C$5000,ESPACIOS($A4),Datos!$A$3:$A$5000,">="&$B$1,Datos!$A$3:$A$5000,"<="&FIN.MES($B$1,0))

o podrias crear una columna auxiliar provisionar, colocas por ejemplo en k4

=ESPACIOS(A4)

Lo llevas hacia abajo y luego lo copias A VALORES en A.

========================

tienes otro inconveniente con los 

WH/IN/00012

WH/N/A/00003

WH/OUT/00058

WH/IN/00015 como ves, WH/IN y WH/N no son iguales, por lo que esa no se sumará, debes corregir en la base.

===================

Toma en cuenta que nunca deberías trabajar con Rangos de columnas completas, tipo A:A, B:B, si es el tema, que tienes todas las columnas llenas de datos (que lo dudo),  ese libro te dará muchos problemas, por la lentitud de los cálculos.. ya que tendrá que evaluar las cuchucientas mil filas.   Es mejor  que trabajes con rangos  amplios, dando un margen extra... (o también puedes convertir tu base en TABLA, en ese caso las formulas se autoajustan automáticamente.

Bueno, creo que son todas mis observaciones..

Por si acaso incluyo tu archivo.

saludos,

Silvia

 

AYUDA EXCEL EJEMPLO.xlsx

Muchas gracias Silvia

Me funciona a la perfeccion.

Gracias por los consejos.

No me había percatado de los espacios al final de los códigos.

Con relación al WH/IN y WH/N/A asi lo prefiero que no se sumen, el WH/N/A originalmente se llamaba WH/INT, pero reemplace esas palabras para por N/A para que no se incluyeran en la suma.

Tema resuelto!

Muchas gracias!

Estaba haciendo la hoja con la respuesta y despues ya me di cuenta que se contestó jejejje. Buena respuesta silvia. Abrazos a todos