Suma producto?

[BLKSNAKER]

Hola como estan. Que formula sugieren en Excel 2007 para obtener como resultado, la cantidad total de bananas y manzanas con antiguedad de 10 dias?

Muchas gracias...

Libro1.rar

[John Jairo V]

Hola @[uSER=105576]BLKSNAKER[/uSER]. Te dejo un archivo con 3 Opciones.

Espero haberte ayudado, Dios te bendiga!

Libro1 (4).rar

[BLKSNAKER]

Muchas gracias!! Necesito que el resultado lo arroje una misma formula, no tener que sumar por separado los resultados parciales. Pero por favor considera la particularidad de que no puedo hacer Sumar.si.conjunto(.....) + sumar.si.conjunto(....)

Necesito una formula completa que haga el trabajo.

Es posible?

[John Jairo V]

Claro que se puede!

Intenta con esta fórmula:

=SUMAPRODUCTO((($B$4:$B$13="MANZANA")+($B$4:$B$13="BANANA"))*($C$4:$C$13=10)*$D$4:$D$13)[/CODE]

Bendiciones!

[BLKSNAKER]

Necesito saber que esta mal de esta formula:

=SUMAPRODUCTO(($B$4:$B$13={"MANZANA";"BANANA"})*($C$4:$C$13={10;20})*$D$4:$D$13)

Con esa formula quiero que me sume las cantidades de todas las bananas y manzanas, con antiguedad de 10 y 20, pero no me da el resultado que debería.

[John Jairo V]

Para hacer lo que quieres, debes hacer esto:

=SUMAPRODUCTO((($B$4:$B$13="MANZANA")+($B$4:$B$13="BANANA"))*(($C$4:$C$13=10)+($C$4:$C$13=20))*$D$4:$D$13)[/CODE]

Dios te bendiga!

[Armando Montes]

Hola, una opcion:

=SUMAPRODUCTO((B4:B13={"MANZANA";"BANANA"})*((C4:C13=10)+(C4:C13=20))*D4:D13)[/CODE]

[John Jairo V]

Maestro @[uSER=136970]Armando Montes[/uSER]. Su fórmula funciona en la versión española de esta manera:

=SUMAPRODUCTO((B4:B13={"MANZANA"\"BANANA"})*((C4:C13=10)+(C4:C13=20))*D4:D13)[/CODE]

Esto es debido al formato de "columnas" diferente de acuerdo a la configuración regional.

En Inglés:

Filas --> ","

Columnas --> ";"

En Español:

Filas --> ";"

Columnas --> "\"

Bendiciones!

[BLKSNAKER]

Muchas gracias, por favor cerrar el tema.

TEMA SOLUCIONADO.

[Armando Montes]

Muchas gracias por avisar, mas vale tarde que nunca.

SOLUCIONADO