17 ejemplos con funciones de búsqueda y referencia

Cualquiera que haya utilizado Excel durante unos minutos se ha visto en la necesidad de buscar algún valor en el libro. Ya sea voluntariamente o de forma inconsciente, estoy seguro de que has utilizado alguna de las funciones que te propongo a continuación. Te pego alguno de los ejemplos más útiles.

Búsquedas habituales

Buscar un valor en una tabla y hacer que devuelva otros elementos de la misma fila y de la tercera columna

Ejemplo:

				
					=BUSCARV("Patricio";tabla_salarios;3;FALSO)
				

Resultado: 55.000 € Más información sobre BUSCARV

Buscar un valor en una tabla y hacer que devuelva otros elementos de la misma columna y de la tercera fila

Ejemplo:

				
					=BUSCARH("Patricio";tabla_salarios;3;FALSO)
				

Resultado: 55.000 € Más información sobre BUSCARH

¿En qué posición se encuentra la palabra ‘jardín’ dentro de la lista ‘Paisajes’?

Ejemplo:

				
					=COINCIDIR("jardín";Paisajes;0)
				

Resultado: 6 Más información sobre COINCIDIR

Hacer una búsqueda en una tabla de doble entrada

Ejemplo:

				
					=INDICE(C7:F11;COINCIDIR("valor1";B7:B11;0);COINCIDIR("valor2";C6:F6;0))
				

Resultado: 3 Más información sobre INDICE

Otros usos

Conocer el nombre o dirección del rango

Ejemplo:

				
					=DIRECCION(FILA([ref]);COLUMNA([ref]);4)&":"&DIRECCION(FILA([ref])+FILAS([ref])-1;COLUMNA([ref])+COLUMNAS([ref])-1;4)
				

Más información sobre DIRECCION Más información sobre FILA Más información sobre COLUMNA

Valores de texto aleatorios

Ejemplo:

				
					=ELEGIR(ALEATORIO.ENTRE(1;3);"valor1";"valor2";"valor3")
				

Más información sobre ELEGIR Más información sobre ALEATORIO.ENTRE

Búsqueda aproximada con varios criterios

Ejemplo:

				
					{=INDICE(D5:D10;COINCIDIR(G7;SI(B5:B10=G6;C5:C10);1))}
				

Fórmula matricial. Para introducirla presiona las teclas Ctrl + Mayús + Intro. Más información sobre INDICE Más información sobre COINCIDIR

Encontrar un dato en una tabla (permite búsquedas hacia la izquierda

Ejemplo:

				
					=INDICE(B5:E9;COINCIDIR(H4;B5:B9;FALSO);2)
				

Buscar diferenciando mayúsculas y minúsculas

Ejemplo:

				
					=INDICE(C5:C14;COINCIDIR(VERDADERO;IGUAL(E5;B5:B14);0))
				

Más información sobre VERDADERO Más información sobre IGUAL

Hallar el texto más largo de la columna

Ejemplo:

				
					=INDICE(rango;COINCIDIR(MAX(LARGO(rango));LARGO(rango);0))
				

Fórmula matricial. Para introducirla presiona las teclas Ctrl + Mayús + Intro. Más información sobre MAX Más información sobre LARGO

Hallar el texto más largo de la columna con criterios

Ejemplo:

				
					=INDICE(rango;COINCIDIR(MAX(LARGO(rango)*(rango_criterio=criterio));LARGO(rango)*(rango_criterio=criterio);0))
				

Fórmula matricial. Para introducirla presiona las teclas Ctrl + Mayús + Intro.

Obtener la referencia de celda del resultado de búsqueda

Ejemplo:

				
					=CELDA("direccion";INDICE(B5:D11;COINCIDIR(G6;B5:B11;0);2))
				

Más información sobre CELDA

Obtener el primer valor de una lista

Ejemplo:

				
					=BUSCARV("*";B5:B11;1;FALSO)
				

Obtener la última coincidencia

Ejemplo:

				
					=MAX(SI(criterio;FILA(rango)-MIN(FILA(rango))+1))
				

Hallar el primer error en una lista

Ejemplo:

				
					=COINCIDIR(VERDADERO;ESERROR(rango);0)
				

Más información sobre ESERROR

Búsqueda parcial

Ejemplo:

				
					=BUSCARV(valor_buscado&"*";matriz_de_busqueda;columna;FALSO)
				

Hallar la posición del valor máximo de una lista

Ejemplo:

				
					=COINCIDIR(MAX(rango);rango;0)