Función/formula días de anticipación entre un periodo fechas

[varcek96]

hola buena tarde!

solicito su apoyo con esta función ya que no la he podido desarrollar 

en la función me debe avisar en un periodo de 5 días antes, tomando en cuanta el día de hoy con la fecha de cita . es decir ya sean 5,4,3.. dias antes de la fecha de cita me debe arrojar un mensaje de cita cercana. 

adjunto archivo donde se explica a detalla y pone el ejemplo (son varias funciones en una sola, pero esta ultima no me ha podido salir)

espero me puedan apoyar con este trabajo

de antemano muchas gracias

Víctor

FECHA AGENDA CITA.xlsm

[Israel Cassales]

Hola.

No me lo tomes a mal pero trata de mejorar las descripciones para futuras consultas, lo menciono porque el orden de las ideas es importante en este caso y tu fórmula no es que no te salga, sino que tiene desordenados los eventos. El primer resultado que te devuelve es el primer argumento que pones en el IF, si pones un evento que se contrapone "en el tiempo como es este ejemplo" te devuelve la primera condición que se cumple.

En el caso de tu fórmula "Hoy Cita" no puede ir hasta el final por decirte algo o el caso del indicador mayor qué y menor qué.

Tu fórmula:

=SI(K6="concluida","",SI(($Q$5-I6)>=5,"no llego",SI(($Q$5>I6),"cita cercana",SI(($Q$5<I6),"en tiempo",SI(($Q$5=I6),"hoy cita")))))

 

Mi propuesta:

=SI(I6="","",SI(K6="CONCLUIDA","Concluida",SI(I6<HOY(),"No llego",SI(I6=HOY(),"Hoy Cita",SI(I6-HOY()<=5,"Cita Cercana",SI(I6-HOY()>=6,"En tiempo"))))))

 

Hice pruebas y cumple con lo que solicitas en la descripción del archivo considerando que la fecha de hoy es 10/03/2023, espero te sea de ayuda. Es la que esta en medio de las tuyas.

Saludines
 

[Oscar_MRF]

Que tal a todos, verificando la consulta me permito proponer una solución alternativa:

 

=SI.ERROR(BUSCAR(I6-Q5/(K6="");{-10;0;1;6};{"no llego";"hoy cita";"cita cercana";"en tiempo"});"")

 

Espero les sea útil.

[Israel Cassales]

mHola de nuevo a todos.

Me gusta cuando en una consulta se proponen diferentes opciones, es divertido. Igual me permití detallar lo que hace la propuesta de @Oscar_MRF como apoyo adicional si a algún lector se le complique "leer" qué es lo que hace.

hace 14 horas, Oscar_MRF dijo:

=SI.ERROR(BUSCAR(I6-Q5/(K6="");{-10;0;1;6};{"no llego";"hoy cita";"cita cercana";"en tiempo"});"")

La función BUSCAR busca el resultado de la operación I6-Q5 (la resta de los valores en las celdas I6 y Q5). En este caso las fechas.

Si K6 está vacía (""), la operación anterior se estaría dividiendo entre 0, lo que generaría un error. En caso contrario, el resultado de la operación anterior se deja tal cual.

La función BUSCAR busca el resultado de la operación anterior en el rango {-10;0;1;6}, que es el primer argumento.

Si la función BUSCAR encuentra un valor coincidente en el rango {-10;0;1;6}, devuelve el valor correspondiente en la misma posición en el rango {"no llego","hoy cita","cita cercana","en tiempo"} que se encuentra en el segundo argumento de la función.

Si la función BUSCAR no encuentra un valor coincidente en el rango {-10;0;1;6}, devolvería el valor de error #N/A.

La función SI.ERROR captura el valor de la función BUSCAR y si hay un error, devuelve una cadena de texto vacía (""). Si no hay un error, devuelve el resultado de la función BUSCAR.

Fórmula de bastante calidad  ? y poco usada entre usuarios regulares. Lo único que le agregaría (si me permiten) sería qué valor devolver cuando en el escenario de la consulta (K6) está CONCLUIDA porque así de momento devuelve "nada". Bastaría agregar esa condición al inicio.

=SI(K6="CONCLUIDA", "concluida", "")&SI.ERROR(BUSCAR(I6-Q5/(K6=""),{-10;0;1;6},{"No llego","Hoy cita","Cita cercana","En tiempo"}),"")

Saludos OSCAR, gusto coincidir contigo en una consulta.

@varcek96 Quedamos en espera de tus comentarios y bueno aprovechar que no a todas las consultas les dan múltiples opciones, igual y hasta proponen otras.

Saludines