Muy buenas tardes estimada comunidad

Me podrían ayudar con esta macro,

Tengo una macro que me genera un reporte de inventario en un archivo excel, el archivo tiene códigos y formulas para la descripción de cada código,

Ejemplo.

Código - Descripción

001            Zanahorias.

002             Cebollas.

003              Tomates.

004              #N/A.

La macro continua después de llenar los campos de "descripción por medio de formulas, lo que necesito es que, la macro me muestre un mensaje cuando no encuentre un código en la base de datos por ejemplo el código  #N/A cuando encuentre este valor que me de un mensaje que me diga "Por favor verificar los errores".  solo que me muestre la alerta, y si en un caso no se encuentran códigos con error que la macro continué normalmente ejecutando otro codigo.

Dejo este codigo en que estaba trabajando y que no me ha querido funcionar

Sub ERRORES()
Dim ulfila As Integer
Dim p As Integer
Dim i As Integer

ulfila = Worksheets("PTR").Cells(Rows.Count, "A").End(xlUp).Row

For p = 16 To 17
    For i = 2 To ulfila
     Worksheets("PTR").Cells(i, p).Select
        If IsError(ActiveCell) Then
        MsgBox "Por favor verifica los errores", vbInformation + vbOKOnly, "Informacion"
        Exit Sub
        Else
        Call IMOVTXT
        End If
    Next i
Next p

End Sub

Buenas, que formula es la que te tira el error #N/A ?? 

por el macro que pones debería de funcionarte , siempre que #N/A sea un error y no un literal.

saludos

Hola muchas gracias por tomarte el tiempo de revisar, 

Si, tampoco entiendo el porque no me funciona, pero al ejecutar no toma los errores y de una vez salta y llama otra macro que tengo , lo he probado de otra forma es que me genere un msgbox  sin que me llame la otra macro y me toca darle enter varias veces a ese msgbox hasta que encuentra el error 

Buenas, lo que quieres es que no se ejecute la macro IMOVTXT si hay errores, entonces según tu código seria  :

Sub ERRORES1()

Dim ulfila As Integer
Dim p As Integer
Dim i As Integer

With Worksheets("PTR")
ulfila = .Cells(Rows.Count, "A").End(xlUp).Row
 For p = 16 To 17
  For i = 2 To ulfila
   If IsError(.Cells(i, p)) Then
    MsgBox "Por favor verifica los errores, Fila:" & i & " Colum:" & p, vbInformation + vbOKOnly, "Informacion"
     Exit Sub
   End If
  Next i
 Next p
End With
Call IMOVTXT
End Sub

más corto, comprobando las columnas al mismo tiempo:

Sub ERRORES2()

Dim i%
With Worksheets("PTR")
  For i = 2 To .Cells(Rows.Count, "A").End(xlUp).Row
   If IsError(.Cells(i, 16)) Or IsError(.Cells(i, 17)) Then
    MsgBox "Por favor verifica los errores, Fila:" & i & " Colum:16/17", vbInformation + vbOKOnly, "Informacion"
     Exit Sub
   End If
  Next i
End With
Call IMOVTXT
End Sub

saludos

Hombre muchisimas gracias,  aprendi mucho con este ejercicio y no tener estos problemas de sintaxis.

Feliz día!

Saludos desde Colombia ?

Hola a ambos

@Giancarloch

Para que veas que Excel es versátil, dejo una solución sin utilizar un bucle

Utilizando mi preferido SpecialCells

    vce = Range("P:Q").SpecialCells(xlCellTypeFormulas, 16).Count
    If vce Then VBA.MsgBox "Se encontraron " & vce & _
    " errores, favor revisar", vbExclamation, "AyudaExcel"

Excel te mostrar una alerta, si hay errores

 

@Gerson Pineda

Muchas gracias por darme esta opcion, lo pondre en funcionamiento para optimizar mi codigo

Feliz dia!

Saludos desde Colombia ?