ComboBox carga muy lento

jose lopez contreras · April 24, 2019

Hola amigos encontré la siguiente instrucción para cargar un ComboBox, funciona bien con una base de datos pequeñas, pero al tener una base de datos grande (mas de 3000 datos) tarda mas de 50 segundos en cargar. Pregunto abra otra forma de realizarlo en menor tiempo, alguien podrá darme un ejemplo.

Sub cargarcombo1()
For n = 2 To Hoja12.Range("E" & Rows.Count).End(xlUp).Row 
ComboBox1 = Hoja12.Range("E" & n)
   If ComboBox1.ListIndex = -1 Then ComboBox1.AddItem ComboBox1
Next
ComboBox1 = ""
End Sub

Haplox · April 24, 2019

@jose lopez contreras , me da que ta has liado mucho...?

Sub cargacombo1()

n = Range("E" & Rows.Count).End(xlUp).Row
ComboBox1.RowSource = Range("E2:E" & n).Address

End Sub

Dr Hyde · April 24, 2019

puedes usar una matriz de datos y la propiedad combobox1,list

Sub cargar_combo()
filas = Range("e1").CurrentRegion.Rows.Count
matriz = Range("e1").Resize(filas, 1)
ComboBox1.List = matriz
End Sub

jose lopez contreras · April 24, 2019

Hace 10 minutos , Haplox dijo:
@jose lopez contreras , me da que ta has liado mucho...?
Sub cargacombo1()

n = Range("E" & Rows.Count).End(xlUp).Row
ComboBox1.RowSource = Range("E2:E" & n).Address

End Sub

@Haplox gracias por tu pronta respuesta, pero fijate que solo me carga E1 es decir el titulo de la columna, que estara pasando

Haplox · April 24, 2019

Hace 4 minutos , jose lopez contreras dijo:

que estara pasando

Pues el único problema puede ser la estructura de los datos en esa columna (?) ¿Es un combo en un userform o en una hoja?

jose lopez contreras · April 24, 2019

Hace 8 minutos , Dr Hyde dijo:

puedes usar una matriz de datos y la propiedad combobox1,list

Sub cargar_combo()
filas = Range("e1").CurrentRegion.Rows.Count
matriz = Range("e1").Resize(filas, 1)
ComboBox1.List = matriz
End Sub

@Dr Hyde gracias por tu aportación , pero fíjate que me carga toda la columna después del encabezado es decir no filtra la palabras repetidas por ejemplo tengo la palabra "VENTA" 1000 veces y en ComboBox aparecen las 1000 veces, con la instrucción que subí si filtra pero tarda demasiado

jose lopez contreras · April 24, 2019

Hace 1 minuto , Haplox dijo:

Pues el único problema puede ser la estructura de los datos en esa columna (?) ¿Es un combo en un userform o en una hoja?

en un userform

Antoni · April 24, 2019

Esta macro carga valores únicos ordenados:

Sub CargarCombo1()
With Hoja12
   Application.ScreenUpdating = False
   .Columns("E").Copy .Columns(Columns.Count)
   .Cells(1, Columns.Count).Delete
   .Columns(Columns.Count).RemoveDuplicates Array(1)
   .Columns(Columns.Count).Sort key1:=.Cells(1, Columns.Count)
   ComboBox1.List = Range(Cells(1, Columns.Count), Cells(Rows.Count, Columns.Count).End(xlUp)).Value
   .Columns(Columns.Count).Clear
End With

Haplox · April 24, 2019

Hace 2 minutos , jose lopez contreras dijo:

no filtra la palabras repetidas por ejemplo tengo la palabra "VENTA" 1000 veces y en ComboBox aparecen las 1000 vece

Esto hay que decirlo desde el principio ?

Haplox · April 24, 2019

Otra forma

Sub cargacombo1()
Dim datos As New Collection
Dim item

n = Range("A" & Rows.Count).End(xlUp).Row

For i = 2 To n
    On Error Resume Next
    datos.Add Cells(i, "A"), CStr(Cells(i, "A"))
Next i

For Each item In datos
    ComboBox1.AddItem item
Next item

End Sub

jose lopez contreras · April 24, 2019

Hace 23 minutos , Antoni dijo:

Esta macro carga valores únicos ordenados:


Sub CargarCombo1()
With Hoja12
   Application.ScreenUpdating = False
   .Columns("E").Copy .Columns(Columns.Count)
   .Cells(1, Columns.Count).Delete
   .Columns(Columns.Count).RemoveDuplicates Array(1)
   .Columns(Columns.Count).Sort key1:=.Cells(1, Columns.Count)
   ComboBox1.List = Range(Cells(1, Columns.Count), Cells(Rows.Count, Columns.Count).End(xlUp)).Value
   .Columns(Columns.Count).Clear
End With

@Antoni muchas gracias por tu aportación, solo tuve que seleccionar la hoja12 y funciono quedando así.

Sub CargarCombo1()
Worksheets("Salidas").Select 'Seleccionar Hoja12
With Hoja12
   Application.ScreenUpdating = False
   .Columns("E").Copy .Columns(Columns.Count)
   .Cells(1, Columns.Count).Delete
   .Columns(Columns.Count).RemoveDuplicates Array(1)
   .Columns(Columns.Count).Sort key1:=.Cells(1, Columns.Count)
   ComboBox1.List = Range(Cells(1, Columns.Count), Cells(Rows.Count, Columns.Count).End(xlUp)).Value
   .Columns(Columns.Count).Clear
End With
End Sub

Antoni · April 24, 2019

Y a las demás personas que han intervenido ¿Que? :angry:

jose lopez contreras · April 24, 2019

Hace 22 minutos , Haplox dijo:

Otra forma


Sub cargacombo1()
Dim datos As New Collection
Dim item

n = Range("A" & Rows.Count).End(xlUp).Row

For i = 2 To n
    On Error Resume Next
    datos.Add Cells(i, "A"), CStr(Cells(i, "A"))
Next i

For Each item In datos
    ComboBox1.AddItem item
Next item

End Sub

@Haplox igualmente muchas gracias también funciono, solo tuve que seleccionar la Hoja 12 y cambiar la columna A por la E queda dando así

Sub cargarcombo1()
Worksheets("Salidas").Select 'Seleccionar Hoja12
Dim datos As New Collection
Dim item

n = Range("E" & Rows.Count).End(xlUp).Row

For i = 2 To n
    On Error Resume Next
    datos.Add Cells(i, "E"), CStr(Cells(i, "E"))
Next i

For Each item In datos
    ComboBox1.AddItem item
Next item
End Sub

Dr Hyde · April 24, 2019

una forma mas corta seria esta, como no mencionas si en tu hoja hay mas informacion hace una copia de tu informacion en la hoja2, elimina los duplicados y hace la carga al combobox

Sub cargar_combo()
Range("e2").CurrentRegion.Copy

With Sheets("hoja2").Range("a1")
.PasteSpecial
.CurrentRegion.RemoveDuplicates Columns:=1
matriz = .CurrentRegion
End With

ComboBox1.List = matriz
Sheets("hoja2").Cells.Clear
End Sub

jose lopez contreras · April 24, 2019

Hace 9 minutos , Dr Hyde dijo:

una forma mas corta seria esta, como no mencionas si en tu hoja hay mas informacion hace una copia de tu informacion en la hoja2, elimina los duplicados y hace la carga al combobox

Sub cargar_combo()
Range("e2").CurrentRegion.Copy

With Sheets("hoja2").Range("a1")
.PasteSpecial
.CurrentRegion.RemoveDuplicates Columns:=1
matriz = .CurrentRegion
End With

ComboBox1.List = matriz
Sheets("hoja2").Cells.Clear
End Sub

@Dr HydeIgualmente también funciono, como tengo 3 userform donde utilizo este código pondré uno en cada caso para tener los tres datos. Mil gracias a los tres maestros del VBA por su apoyo.