Suma de celdas de varios libros contenidos en una carpeta

[EDGAR S. H.]

hola a todos.

bueno mi consulta es la siguiente tengo 24 libros de Excel cada uno pertenece a cada quincena de mes es decir 1ra quincena de enero, 2da quincena de enero y así sucesivamente por mes, quisiera sumar celdas en especifico de cada libro en otro libro que se llama totales. cada libro tiene el mismo formato.

en el libro totales, quiero sumar la celda D18, F18, H18, J18, L18, N18 de todos los libros correspondientes a cada quincena de mes, sin que se habrán estos libros, todos los libros están en una carpeta que se llama total, la ruta es la siguiente:
C:\Users\sherrera\DOCS\REPORTES DE BITACORA\2016\TOTAL

otra cosa, que cada vez que agregue un libro en esta carpeta se sumen sus datos en el libro de totales.

espero pudieran apoyarme
de antemano agradezco su interes

TOTAL.xlsx

[Antoni]

Esta macro debería funcionar.

Sub Totalizar()
Dim FSO As Object, FS As Object, FF As Object, Archivo As Object
Dim D18 As Double, F18 As Double, H18 As Double
Dim J18 As Double, L18 As Double, N18 As Double
Set FSO = CreateObject("Scripting.FileSystemObject")
Carpeta = "C:\Users\sherrera\DOCS\REPORTES DE BITACORA\2016\TOTAL"
Set FS = FSO.GetFolder(Carpeta)
Set FF = FS.Files
Estado = Application.StatusBar
For Each Archivo In FF
   If Archivo.Name Like "*.xlsx" Then
      If Not Archivo.Name = "TOTAL.xlsm" Then
         Application.StatusBar = Archivo.Name
         Workbooks.Open Archivo
         D18 = D18 + ActiveSheet.Range("D18")
         F18 = F18 + ActiveSheet.Range("F18")
         H18 = H18 + ActiveSheet.Range("H18")
         J18 = J18 + ActiveSheet.Range("J18")
         L18 = L18 + ActiveSheet.Range("L18")
         N18 = N18 + ActiveSheet.Range("N18")
         ActiveWorkbook.Close
      End If
   End If
Next
ActiveSheet.Range("C5") = D18
ActiveSheet.Range("E5") = F18
ActiveSheet.Range("G5") = H18
ActiveSheet.Range("I5") = J18
ActiveSheet.Range("K5") = L18
ActiveSheet.Range("M5") = N18
Application.StatusBar = Estado
End Sub

 

[EDGAR S. H.]

Muchísimas gracias Macro Antonio ya agregue la macro y funciona muchas gracias te agradezco tu tiempo y apoyo