Guardar userform como pdf

[daniela lazcano]

Hola a tod@s!!

Necesito me ayuden por favor, necesito guardar el formulario activo en formato pdf. Lo he intentado a través de Me.PrintForm, pero lo envía a la impresora predeterminada en mi equipo. Busqué en la web y encontré en esta página algo como lo que necesito, pero me arroja error:

Pendiente - Guardar como pdf un un userform

Espero alguien pueda ayudarme, gracias de antemano,

Saludos!!

[Héctor Miguel]

(cuando menos...)

transcribe el error que obtienes (numero y texto) y cual es la línea que lo causa

y confirma que tienes instalado el complemento para exportar a PDF

saludos,

hector.

[LeandroA]

Bueno tal como dice Hector, yo supongo que es porque te faltan las declaraciones APIS proba pegar este codigo en un userform y dale click deberia guardar el pdf junto al documento de excel.

#If VBA7 And Win64 Then

    Private Declare PtrSafe Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

#Else

    Private Declare  Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

#End If


Const KEYEVENTF_EXTENDEDKEY = &H1

Const KEYEVENTF_KEYUP = &H2

Const VK_SNAPSHOT = &H2C

Const VK_MENU = &H12


Private Sub UserForm_Click()

       Dim pdfName As String

    ' ------------ Alt+PrtScn

    keybd_event VK_MENU, 0, KEYEVENTF_EXTENDEDKEY, 0

    keybd_event VK_SNAPSHOT, 0, KEYEVENTF_EXTENDEDKEY, 0

    keybd_event VK_SNAPSHOT, 0, KEYEVENTF_EXTENDEDKEY + KEYEVENTF_KEYUP, 0

    keybd_event VK_MENU, 0, KEYEVENTF_EXTENDEDKEY + KEYEVENTF_KEYUP, 0


    DoEvents 'Otherwise, all of screen would be pasted as if PrtScn rather than Alt+PrtScn was used for the copy.


    ThisWorkbook.Worksheets.Add After:=Worksheets(Worksheets.Count)

    Range("A1").Select

    ActiveSheet.Paste

    pdfName = ActiveWorkbook.Path & "\" & "ITEM.pdf"


    ActiveSheet.ExportAsFixedFormat _

    Type:=xlTypePDF, _

    Filename:=pdfName, _

    Quality:=xlQualityStandard, _

    IncludeDocProperties:=False, _

    IgnorePrintAreas:=False, _

    OpenAfterPublish:=False

    Application.DisplayAlerts = False

    Worksheets(Worksheets.Count).Delete

    Application.DisplayAlerts = True

End Sub[/CODE]

[daniela lazcano]

Héctor, gracias por responder. El problema es que con el Me.PrintForm a veces se muestra el cuadro de diálogo de impresión y me permite guardarlo como pdf, pero en otras oportunidades, lo envía directamente a la impresora física. Yo entiendo que esto tiene que ver con la impresora que uno tenga como predeterminada, pero justamente eso es lo que quiero evitar, porque el archivo en el que estoy trabajando, va a ser utilizado en distintos equipos, por distintas personas, y no todos sabrán que deben seleccionar antes el programa para imprimir a pdf.

Eso, supuestamente no debería pasar con el código que encontré, lo probé y me aparecía que había que cambiarlo a la versión actual, yo no soy experta y no sabía qué hacer, pero lo volví a probar después y al parecer hace algo, pero no puedo ver qué. No me muestra ningún archivo.

[daniela lazcano]

Ahhhhhh chicos!!!! mil gracias!!! eso era lo que no sabía, porque probé el código y al parecer funcionaba, pero no sabía si guardaba algo, ni mucho menos dónde, ahora que LeAndro me dice que se guarda junto al archivo, lo revisé y ahí está!!!, son grandes!! me han solucionado un tremendo problema. No soy experta, pero hago mi mayor esfuerzo por que me resulten los proyectos.

Gracias totales!!!

Un abrazo gigante desde Chile

[daniela lazcano]

El único problema ahora, es que guarda el form en pdf, pero lo corta y lo guarda en dos hojas. Cómo se podría evitar esto? Gracias chicos!!

[LeandroA]

El único problema ahora, es que guarda el form en pdf, pero lo corta y lo guarda en dos hojas. Cómo se podría evitar esto? Gracias chicos!!

si miras el código inserta una nueva hoja mediante macros vos podes configurar esa nueva hoja

ahi lo que hice fue ponerla en horizontal y ajustar el escalado (impresion) en una hoja, tambien podes jugar con los margenes etc etc.

#If VBA7 And Win64 Then

    Private Declare PtrSafe Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

#Else

    Private Declare  Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

#End If


Const KEYEVENTF_EXTENDEDKEY = &H1

Const KEYEVENTF_KEYUP = &H2

Const VK_SNAPSHOT = &H2C

Const VK_MENU = &H12


Private Sub UserForm_Click()

       Dim pdfName As String

    ' ------------ Alt+PrtScn

    keybd_event VK_MENU, 0, KEYEVENTF_EXTENDEDKEY, 0

    keybd_event VK_SNAPSHOT, 0, KEYEVENTF_EXTENDEDKEY, 0

    keybd_event VK_SNAPSHOT, 0, KEYEVENTF_EXTENDEDKEY + KEYEVENTF_KEYUP, 0

    keybd_event VK_MENU, 0, KEYEVENTF_EXTENDEDKEY + KEYEVENTF_KEYUP, 0


    DoEvents 'Otherwise, all of screen would be pasted as if PrtScn rather than Alt+PrtScn was used for the copy.


    ThisWorkbook.Worksheets.Add After:=Worksheets(Worksheets.Count)


    With ActiveSheet.PageSetup

        '.LeftMargin = Application.InchesToPoints(0)

        '.RightMargin = Application.InchesToPoints(0)

        '.TopMargin = Application.InchesToPoints(0)

        '.BottomMargin = Application.InchesToPoints(0)

        '.HeaderMargin = Application.InchesToPoints(0)

        '.FooterMargin = Application.InchesToPoints(0.31496062992126)

        .Orientation = xlLandscape

        .Zoom = False

        .FitToPagesWide = 1

        .FitToPagesTall = 1

    End With


    Range("A1").Select

    DoEvents

    ActiveSheet.Paste

    pdfName = ActiveWorkbook.Path & "\" & "ITEM.pdf"


    ActiveSheet.ExportAsFixedFormat _

    Type:=xlTypePDF, _

    Filename:=pdfName, _

    Quality:=xlQualityStandard, _

    IncludeDocProperties:=True, _

    IgnorePrintAreas:=False, _

    OpenAfterPublish:=True

    Application.DisplayAlerts = False

    Worksheets(Worksheets.Count).Delete

    Application.DisplayAlerts = True

End Sub

[/CODE]

[daniela lazcano]

LeandroA, funciona de maravillas!!! muchas, muchas gracias. Doy por cerrado el tema. Gracias a ti y a Héctor por su ayuda.

Un abrazo