Descomposición de un número en factores primos

Antoni · el 7 de febrero

Hola:

Me he tomado la libertad de subir la solución de esta consulta como aporte:

https://www.ayudaexcel.com/foro/macros-programacion-vba-10/pendiente-potencias-formato-real-por-macro-udf-20916/

Los méritos corresponden a jrgces, autor de la descomposición, a shadowjuan, por haberlo dado a conocer, y a mjrofra que aporta la función que lo expresa con superíndices, yo he hecho de mero escribano.

Saludos

Descomponer en factores primos.xls

jrgces · el 24 de febrero

Hola, no participo en este foro por falta de tiempo, aunque estoy dado de alta como usuario desde hace bastante y lo miro de vez en cuando.

Quería decir que soy el autor del código VBA que va en el libro de este aporte para calcular la descomposición factorial de un entero. El enlace del mensaje que dio origen a esto (https://www.ayudaexcel.com/foro/macros-programacion-vba-10/pendiente-potencias-formato-real-por-macro-udf-20916/) tiene un enlace a mi página web (VBA)

Pero lo que quería no era "reivindicar" mi autoría (esto me da un poco igual, si no quisiese que la gente utilizase código escrito por mí no lo pondría en la web). Lo que sí quería es avisar de que el código lo modifiqué hace algún tiempo porque fallaba para los primoriales > 2310 (el primorial de 11).

Así, por ejemplo, para el 30030 (el primorial de 13) dirá que su descomposición factorial es 2*3*5*7*143 cuando debería ser 2*3*5*7*11*13. O el siguiente primorial, el 510510 (el primorial de 17), dirá que su descomposición en factores primos es 2*3*5*7*11*221 cuando debería ser 2*3*5*7*11*13*17. Y así con todos los demás primoriales (al menos los que probé antes de ver que tenía que corregir el código).

El código que estáis utilizando parece estar cogido de mi página web antes de que lo modificase (cuestión de "proxys", supongo, y todas esas cosas de la red de las que no tengo ni idea). A mí me aparece ya actualizado, pero por si sigue apareciéndoos la "versión antigua" pongo la actual, que hasta donde yo sé funciona sin problemas, con el ruego de que modifiquéis el código del libro que va en este aporte que, repito, hasta donde yo sé funciona ya sin problemas:

Option Base 1

Public Function DescFact(ByVal dNúmero As Double) As String

'Sintaxis: =DescFact(celda o número)

'Nota: el entero más alto que puede procesar esta función es (en teoría) el límite de la _

precisión numérica máxima de Excel (999.999.999.999.999), pero los cálculos necesarios _

para números tan grandes pueden llevar bastante tiempo.

If dNúmero > 999999999999999# Then

DescFact = "El número más alto que puede procesar la función DescFact es 999.999.999.999.999"

Exit Function

End If

If Int(dNúmero) <> dNúmero Then

DescFact = "El número a procesar debe ser un entero."

Exit Function

End If

'Si el número pasado como argumento a la función es primo, terminar

If EsPrimo(dNúmero) Then

DescFact = "=" & CStr(dNúmero)

Exit Function

End If

'Variables

Dim mtrN() As Double, mtrE() As Byte

Dim dTope As Double, dProcesando As Double, dDivisor As Double

Dim n As Double

'Inicializaciones

DescFact = "="

dProcesando = dNúmero

dTope = 1

dDivisor = 7

'Antes de empezar el bucle principal, se evalua si el número es divisible por 2, 3 y 5 _

para luego poder entrar directamente en el ciclo 7 - 9 - 1 - 3 (los números terminados en 5 _

siempre son divisibles por 5, por lo que no hay que procesarlos, lo que ahorrará un 20% de _

cálculos, aproximadamente)

If Residuo(dProcesando, 2) = 0 Then

ReDim mtrN(dTope): ReDim mtrE(dTope)

mtrN(dTope) = 2

While Residuo(dProcesando, 2) = 0

mtrE(dTope) = mtrE(dTope) + 1

dProcesando = dProcesando / 2

Wend

dTope = dTope + 1

End If

If Residuo(dProcesando, 3) = 0 Then

ReDim Preserve mtrN(dTope): ReDim Preserve mtrE(dTope)

mtrN(dTope) = 3

While Residuo(dProcesando, 3) = 0

mtrE(dTope) = mtrE(dTope) + 1

dProcesando = dProcesando / 3

Wend

dTope = dTope + 1

End If

If Residuo(dProcesando, 5) = 0 Then

ReDim Preserve mtrN(dTope): ReDim Preserve mtrE(dTope)

mtrN(dTope) = 5

While Residuo(dProcesando, 5) = 0

mtrE(dTope) = mtrE(dTope) + 1

dProcesando = dProcesando / 5

Wend

dTope = dTope + 1

End If

'Si dProcesando = 1, terminar

If dProcesando = 1 Then GoTo Listar

'Si dProcesando es primo, terminar

If EsPrimo(dProcesando) Then

If dTope = 1 Then

ReDim mtrN(dTope): ReDim mtrE(dTope)

Else

ReDim Preserve mtrN(dTope): ReDim Preserve mtrE(dTope)

End If

mtrN(dTope) = dProcesando: mtrE(dTope) = 1

GoTo Listar

End If

'Bucle principal

While dProcesando > 1

If Residuo(dProcesando, dDivisor) = 0 Then

If EsPrimo(dDivisor) Then

While Residuo(dProcesando, dDivisor) = 0

ReDim Preserve mtrN(dTope): ReDim Preserve mtrE(dTope)

mtrN(dTope) = dDivisor: mtrE(dTope) = mtrE(dTope) + 1

dProcesando = dProcesando / dDivisor

Wend

dTope = dTope + 1

End If

If dProcesando = 1 Then GoTo Listar

'Si dProcesando es primo, terminar

If EsPrimo(dProcesando) Then

ReDim Preserve mtrN(dTope): ReDim Preserve mtrE(dTope)

mtrN(dTope) = dProcesando: mtrE(dTope) = 1

GoTo Listar

End If

dDivisor = dDivisor + IIf(Right(CStr(dDivisor), 1) = 3, 4, 2)

Wend

Listar:

For n = LBound(mtrN) To UBound(mtrN)

DescFact = DescFact & CStr(mtrN(n)) & IIf(mtrE(n) = 1, "", "^" & CStr(mtrE(n))) & "*"

Next n

DescFact = Replace(Left(DescFact, Len(DescFact) - 1), "0^0*", "")

End Function

Public Function EsPrimo(ByVal dNúmero As Double) As Boolean

'Sintaxis: =EsPrimo(celda o número)

'Nota: el entero más alto que puede procesar esta función es (en teoría) el límite de la _

precisión numérica máxima de Excel (999.999.999.999.999)

If (Residuo(dNúmero, 2) = 0 And dNúmero <> 2) Or _

(Residuo(dNúmero, 3) = 0 And dNúmero <> 3) Or _

(Residuo(dNúmero, 5) = 0 And dNúmero <> 5) Then _

Exit Function

Dim dDivisor As Double

dDivisor = 7

While dDivisor <= Sqr(dNúmero) + 1

If Residuo(dNúmero, dDivisor) = 0 Then Exit Function

dDivisor = dDivisor + IIf(Right(CStr(dDivisor), 1) = 3, 4, 2)

Wend

EsPrimo = True

End Function

Private Function Residuo(ByVal dNumerador As Double, ByVal dDenominador As Double) As Double

'Debido a que el límite con el que puede trabajar la función Mod de VBA es el del tipo de datos _

Long (2.147.483.647), es necesario calcular los restos "a mano".

Residuo = dNumerador - dDenominador * Int(dNumerador / dDenominador)

End Function

Un saludo.

José Ramón García

ioyama · el 24 de febrero

Hola José Ramón

Gracias por la aclaración

Un saludo desde Vitoria

pegones1 · el 28 de junio

Incluyo la fórmula actualizada de José Ramón (jrgces) para resolver problemas de descomposición como:

[TABLE=width: 293]

[TR]

[TD=align: right]999999[/TD]

[TD=colspan: 2]=[/TD]

[TD]3³ · 7 · 11 · 481[/TD]

[/TR]

[TR]

[TD=align: right]481[/TD]

[TD=colspan: 2]=[/TD]

[TD]13 · 37[/TD]

[/TR]

[/TABLE]

Con un 2º argumento se puede elegir entre el formato con superíndices o con el operador "^".

Public Function DescFact(ByVal dNúmero As Double, Optional ByVal dTipo As Integer = 0) As String

    'Sintaxis: =DescFact(celda o número, optional tipo)

    '

    'Entradas:  dNúmero - Número compuesto a descomponer en factores primos.

    '           dTipo - Tipo de salida de la descomposición factorial:

    '                   0 - Superíndice (ej.: 2²); 1 - Operador "^" (ej.: =2^2)

    '

    'Nota: el entero más alto que puede procesar esta función es (en teoría) el límite de la _

     precisión numérica máxima de Excel (999.999.999.999.999), pero los cálculos necesarios _

     para números tan grandes pueden llevar bastante tiempo.

...

End Function

[/CODE]

He probado que el máximo número a descomponer, con variables del tipo Double, es de 15 cifras significativas, como dijo José Ramón:

[TABLE=width: 492]

[TR]

[TD=class: xl67, width: 224] 999.999.999.999.999[/TD]

[TD=class: xl68, width: 268]=3³ · 31 · 37 · 41 · 271 · 2906161[/TD]

[/TR]

[/TABLE]

El mayor número primo con 15 cifras es: 999.999.999.999.989

P.D.: Macro Antonio, lo he subido porque me aburría un poco. :topsy_turvy:

En el siguiente tema he publicado una solución sin macros para valores hasta:

2.251.799.999.999 = 11 * 204709090909

[DBOX]https://www.ayudaexcel.com/foro/ideas-aportes-64/calcular-factores-primos-30089/[/DBOX]