Estimados, junto con saludar, estaba buscando una forma contar primera aparición de data para un determinado campo, en este caso, contabilizar Lanzamientos de un determinado fármaco.

Antes lo hacía sacando tablas dinámicas y de ahí usando coincidir e indices, pero creo que existe una fórmula que me solucionar ésto, sin usar la tabla dinámica.

Principio Activo	Concentración	ene-23	feb-23	mar-23	abr-23	may-23	jun-23
Paracetamol	60	1.000	1.000	2.000	2.000	2.000	2.000
Paracetamol	120	0	2.500	2.500	2.500	2.500	2.500
Fexofenadina	120	0	800	1.000	1.200	1.200	1.200
Omeprazol	40	500	800	800	800	800	800
Aripiprazol	10	750	1.000	1.200	1.200	1.200	1.200
Aripiprazol	30	0	0	0	0	2.000	2.500
Losartán	50	0	0	3.000	3.000	3.000	3.000
Losartán	100	0	0	2.500	2.500	2.500	2.500
Losartán	200	0	0	0	0	0	0
Ibuprofeno	400	0	0	0	0	0	400
Ibuprofeno	600	0	0	0	0	0	1.250
Ibuprofeno	800	0	0	0	0	0	2.000
Carvedilol	6,25	0	0	0	0	0	8.000
	Lanzamientos	3	1	1	0	0	2

 

En la tabla anterior, tengo 7 principios activos con sus respectivas concentraciones, y a la derecha las unidades vendidas. Se puede apreciar que en enero 2023, hay 3 lanzamientos porque aparecieron en el mercado por primera vez Paracetamol, Omeprazol y Aripiprazol (independiente de su concentración), en febrero 2023 hubo 1 lanzamiento por Fexofenadina, marzo 2023 por Losartán y finalmente junio 2023 con dos lanzamientos los cuales son Ibuprofeno y Carvedilol. 

Se podrá con solamente fórmulas, tener el número de lanzamientos que se detalla en la fila de abajo?

De antemano, muchísimas gracias.

Saludos!

Duda Lanzamiento.xlsx

Hola @Matías86, sé que no es la forma más elegante de resolver el problema, pero por ahora funciona. Revisa el archivo adjunto.

Duda Lanzamiento - slp.xlsx

Saludos totales

Es una gran idea @simplifikndo y lamento parecer entrometido en su aporte, me gustan las recomendaciones que hace y por eso con pena de mi parte y sin intención de modificar el total de su idea con el rango auxiliar, vi que en la parte del conteo usa esta fórmula:

=SI(CONTAR.SI(U$1:U$7,">"&0)>CONTAR.SI(T$1:T$7,">"&0),CONTAR.SI(U$1:U$7,">"&0)-CONTAR.SI(T$1:T$7,">"&0),0)

Usando su mismo rango tal vez le podría interesar algo así:

=SUMAPRODUCTO((U1:U7>0)*(T1:T7=0))

Una disculpa por la intromisión estimado @Matías86 

Duda Lanzamiento - slp.xlsx

Jaja tranquilo, @Israel Cassales, no es una intromisión. Siempre es bueno aprender a resolver los mismos problemas de diferentes maneras.

Muchas gracias estimados, siempre serán bienvenidas la optimización de soluciones propuestas.

Están muy buenas las fórmulas, dado que ya no tengo que depender de tablas dinámicas y su actualización para sacar el resultado.

Saludos!

Hola a todos,

Otra posibilidad, con fórmula única M365, podría ser (no necesita cálculos ni rangos auxiliares):

=LET(z;LAMBDA(a;CONTARA(UNICOS(FILTRAR(A2:A14;a>0))));y;C2:C14;APILARH(CONTARA(FILTRAR(y;y>0));EXCLUIR(BYCOL(C2:P14;z)-BYCOL(B2:O14;z);;1)))

Al tratarse de una fórmula de matriz derramada, hay que asegurarse de borrar el rango D16:xxx16.  De otra forma, aparecerá error #¡DESBORDAMIENTO!

Saludos,

Editado el el 18 de agosto1 año por Victor7

En 18/8/2024 at 2:49 , Victor7 dijo:

Hola a todos,

Otra posibilidad, con fórmula única M365, podría ser (no necesita cálculos ni rangos auxiliares):

=LET(z;LAMBDA(a;CONTARA(UNICOS(FILTRAR(A2:A14;a>0))));y;C2:C14;APILARH(CONTARA(FILTRAR(y;y>0));EXCLUIR(BYCOL(C2:P14;z)-BYCOL(B2:O14;z);;1)))

Al tratarse de una fórmula de matriz derramada, hay que asegurarse de borrar el rango D16:xxx16.  De otra forma, aparecerá error #¡DESBORDAMIENTO!

Saludos,

Excelente! 😍

Gracias a todos por sus aportes,  todos me fueron de gran ayuda.

 

Saludos!