Combinar datos de dos hojas en una con macro en el mismo libro

[daren]

Buenas tardes estaba intentando combinar los datos de dos hojas con la misma estructura de columnas y celdas dentro de una hoja diferente, pero existen tanto datos numéricos como de texto, además de celdas vacías por que es un excel que se va rellenando progresivamente.
Son dos hojas Seguimiento1 y Seguimiento 2 las dos tienen datos iguales y diferentes dado que seguimiento 2 es una actualización del 1. Quisiera poder combinar los datos tanto de Seguimiento1 como de Seguimiento2 en otra hoja, he probado varias formas pero solo consigo que aparezcan los datos de Seguimiento1 en la nueva hoja y no una fusión entre los 2.
En el ejemplo pongo datos en sitios diferentes en cada hoja intentando que en la nueva hoja al fusionar los dos se rellenen las celdas vacías con los campos de ambas. Gracias de antemano.

 

 

[JSDJSD]

Sube tu archivo y lo intentamos, deja una muestra de como debe quedar la fusión de las misma

 

[daren]

Buenas tardes adjunto Excel e imágenes para indicar a lo que me refiero con la fusión: Gracias de antemano.

Marque los datos que puse de ejemplo tanto Seguimiento1 como en seguimiento2 en amarillo, así como en la hoja resultado los datos que debería mostrar una vez realizada la fusion.

 

Prueba fusion.xlsx

[JSDJSD]

Las filas en blanco las quieres conservar o solamente las que tienen datos ? cuando digo las filas en blanco me refiero a las que tienen datos solamente en la columna A

[JSDJSD]

Quieres mantener el formato de tabla dinámica o te da igual como rango de datos ?

[daren]

Si quiero mantener las celdas en blanco y el formato porfavor. Es que conforme envían seguimientos van rellenando esas celdas hasta llegar final de año. Tengo las hojas completas de Excel no se si te harían falta, lo que pase fue recortado a modo de ejemplo.

Este es el archivo original con los datos de personas cambiados pero para que veas su estructura original.

Seguimientos.xlsx

Editado el el 19 de marzo por daren

[JSDJSD]

A ver si te apañas con esto

[JSDJSD]

Prueba fusion.xlsm

[daren]

hace 18 horas, JSDJSD dijo:

Prueba fusion.xlsm 68.2 kB · 1 descarga

Buenas de nuevo JSD me han dicho que lo que quieren es totalmente diferente, quieren que si los seguimientos están separados por trimestres, en la hoja de fusión muestren los datos en ese orden primero los de seguimiento1, luego2 y luego 3 aunque los datos estén situados en las mismas celdas en cada seguimiento, que los vaya poniendo debajo primero seguimiento1, luego los datos de seguimiento2 y luego los de seguimiento3. Y en el caso de que los datos sobrepasen a las filas asignadas a ese cliente y persona que genere mas filas con los datos asociados a los dos y rellene las demás celdas con los datos ejecutados. Eso seria posible? He probado mil macros diferentes y no hay manera, solo consigo que aparezcan los datos de seguimiento1.

Te adjunto Excel con explicaciones en la hoja fusión si pudieras ayudarme por favor, la macro que contiene el Excel es una de tantas que probé y no funcionaron:

 

 

Seguimientos - copia.xlsm

[JSDJSD]

Prueba y comenta

[JSDJSD]

Private Sub CommandButton1_Click()
    Hoja1.Range("A2").Resize(Hoja1.Rows.Count - 1).Offset(0, 0).Delete
    For Each hoja In Sheets
        If hoja.Name Like "Seguimiento" & "*" Then
            ufh2 = Hoja1.Range("E" & Rows.Count).End(xlUp).Row + 1
            With Sheets(hoja.Name).Range("A1").CurrentRegion
                .AutoFilter 5, Criteria1:="<>"
                .Offset(1).Resize(.Rows.Count - 1, .Columns.Count).SpecialCells(xlCellTypeVisible).Copy Hoja1.Range("A" & ufh2)
                .AutoFilter
            End With
        End If
    Next
End Sub

 

Seguimientos - copia.xlsm

[daren]

hace 3 horas, JSDJSD dijo:

Private Sub CommandButton1_Click()
    Hoja1.Range("A2").Resize(Hoja1.Rows.Count - 1).Offset(0, 0).Delete
    For Each hoja In Sheets
        If hoja.Name Like "Seguimiento" & "*" Then
            ufh2 = Hoja1.Range("E" & Rows.Count).End(xlUp).Row + 1
            With Sheets(hoja.Name).Range("A1").CurrentRegion
                .AutoFilter 5, Criteria1:="<>"
                .Offset(1).Resize(.Rows.Count - 1, .Columns.Count).SpecialCells(xlCellTypeVisible).Copy Hoja1.Range("A" & ufh2)
                .AutoFilter
            End With
        End If
    Next
End Sub

 

Seguimientos - copia.xlsm 69.64 kB · 1 descarga

Buenas de nuevo funciona correctamente como me indicaste pero te podía hacer una consulta?.  Tengo el Excel con la macro que crea la hoja fusión y cuando se ejecuta la macro se actualizan los datos de esa hoja, lo que viene siendo la macro en si no hace lo que me solicitaron pero la tuya si, habría alguna forma de fusionar ambas macros? Es que no me dejan en un principio poner un botón y tendría que ser desde alt+f8. En este Excel tengo la macro que te comente en modulo1 de vba y en modulo 2 esta tu macro del botón. Mi idea si puede ser es que cuando se ejecute genere la hoja fusión, realice la combinación de hojas como me indicaste tu y cada vez que se ejecute se actualice esa hoja, no se si seria posible, también me dijeron que si los datos al fusionar todas las hojas rebasaban las filas que había creadas en blanco asociadas al cliente y persona si podía autogenerar mas con el mismo formato, no se si me explico :

Lo rojo seria lo que seria en base a las filas anteriores y lo azul lo nuevo que se ejecutaría cogiendo los datos de las hojas de seguimiento: Gracias un saludo.

Realmente serian cuatro hojas de seguimiento una por cada 3 meses pero no puedo subir el archivo aquí por capacidad, las hojas de seguimiento2 y seguimiento3 una copia de seguimiento1 con datos cambiados.

Seguimientos - copia.xlsm

 

Editado el el 21 de marzo por daren

[JSDJSD]

Mañana te lo miro

[JSDJSD]

Cambia tu macro del modulo1 por esta

Sub FUSION(): Application.DisplayAlerts = False
    Dim hoja As Worksheet
    Dim cabecera As Boolean
    Dim ufh2 As Long
    
    On Error Resume Next: Sheets("FUSION").Delete: On Error GoTo 0
    
    ActiveWorkbook.Sheets.Add After:=Worksheets(Worksheets.Count)
    ActiveSheet.Name = "FUSION"
    Sheets("FUSION").Range("A2").Resize(Sheets("FUSION").Rows.Count - 1).Offset(0, 0).Delete
    
    cabecera = False
    For Each hoja In Sheets
        If hoja.Name Like "Seguimiento" & "*" Then
            
            ufh2 = Sheets("FUSION").Range("E" & Sheets("FUSION").Rows.Count).End(xlUp).Row + 1
            If Not cabecera Then
                hoja.Range("A1:E1").Copy Destination:=Sheets("FUSION").Range("A1")
                cabecera = True
            End If
            With hoja.Range("A1").CurrentRegion
                .AutoFilter 5, Criteria1:="<>"
                .Offset(1).Resize(.Rows.Count - 1, .Columns.Count).SpecialCells(xlCellTypeVisible).Copy Sheets("FUSION").Range("A" & ufh2)
                .AutoFilter
            End With
        End If
    Next
    Sheets("FUSION").Range("A:E").Columns.AutoFit
    MsgBox "Los datos se han actualizado correctamente en la hoja 'FUSION'."
End Sub

Prueba y comenta

[JSDJSD]

Ejecuta la macro con Ctrl+f

Seguimientos - copia (1).xlsm

[JSDJSD]

Por cierto esta línea puedes eliminarla de la macro, no es necesaria

Sheets("FUSION").Range("A2").Resize(Sheets("FUSION").Rows.Count - 1).Offset(0, 0).Delete

[daren]

hace 15 horas, JSDJSD dijo:

Por cierto esta línea puedes eliminarla de la macro, no es necesaria

Sheets("FUSION").Range("A2").Resize(Sheets("FUSION").Rows.Count - 1).Offset(0, 0).Delete

Buenas una duda JSD cuando me llevo la macro al Excel original e intento ejecutarla me da error en esta linea, los nombres de las hojas son iguales:

Si necesitas el Excel original  pesa 312kb no te lo podría pasar por aquí y creo que no esta habilitado el facilitar url en plan Google Drive pero no lo se seguro.

[JSDJSD]

Sub FUSION(): Application.ScreenUpdating = False
    Application.DisplayAlerts = False
    Dim hoja As Worksheet
    Dim cabecera As Boolean
    Dim ufh2 As Long
    Dim tbl As ListObject
    Dim rng As Range
    Dim uf As Long
            Dim uc As Long
    On Error Resume Next: Sheets("FUSION").Delete: On Error GoTo 0

    ActiveWorkbook.Sheets.Add After:=Worksheets(Worksheets.Count)
    ActiveSheet.Name = "FUSION"

    cabecera = False
    For Each hoja In Sheets
        If hoja.Name Like "Seguimiento" & "*" & 24 Then
            If hoja.ListObjects.Count = 0 Then
            Else
                Set tbl = hoja.ListObjects(1)
                Set rng = tbl.Range
                tbl.Unlist
            End If
            ufh2 = Sheets("FUSION").Range("E" & Sheets("FUSION").Rows.Count).End(xlUp).Row + 1
            If Not cabecera Then
                hoja.Range("A1:E1").Copy Destination:=Sheets("FUSION").Range("A1")
                cabecera = True
            End If
            
            With hoja.Range("A1").CurrentRegion
                .AutoFilter 4, Criteria1:="<>"
                .Offset(1).Resize(.Rows.Count - 1, .Columns.Count).SpecialCells(xlCellTypeVisible).Copy Sheets("FUSION").Range("A" & ufh2)
                .AutoFilter
            End With
            
            uf = hoja.Cells(hoja.Rows.Count, "A").End(xlUp).Row
            uc = hoja.Cells(1, hoja.Columns.Count).End(xlToLeft).Column
            Set rng = hoja.Range("A1").Resize(uf, uc)
            Set tbl = hoja.ListObjects.Add(xlSrcRange, rng, , xlYes)
            tbl.TableStyle = "TableStyleMedium2"
        End If
    Next
    Sheets("FUSION").Range("A:E").Columns.AutoFit
    MsgBox "Los datos se han actualizado correctamente en la hoja 'FUSION'."
End Sub

Ponlo en el modulo1 y prueba.  El problema que tenias es que en el fichero anterior la macro se ejecutaba sobre un rango de datos y en tu archivo original tienes tablas dinámicas

[JSDJSD]

Sería interesante añadir un formulario para poder seleccionar las hojas de seguimiento de las que quieres hacer el informe, ya que si en tu archivo tienes de varios años por ejemplo de 2023 y 2024 el informe te lo hará de todas las hojas que comiencen por la palabra Seguimiento independientemente si son de 2023 o 2024 con el formulario se solucionaría tal problemilla. Ahora mismo lo tienes para que seleccione solamente los del año 2024. En caso de que te aprueben dicha solución dímelo y te lo paso.

[JSDJSD]

La próxima abres un tema nuevo

[daren]

hace 27 minutos , JSDJSD dijo:

La próxima abres un tema nuevo

Muchísimas gracias funciona perfecto me has salvado la vida . Pues no lo había pensado pero estaría muy bien lo del formulario, para no saturar este lo creo en otro tema mas adelante si no, muchas gracias. Le pongo al titulo del tema algún nombre en especifico para que sepas que se refiere a este?

[JSDJSD]

No, pon lo que tú veas