Hola buenas días,

Mi consulta trata sobre introducir una variable para un rango de celdas.

El codigo es el siguiente

Sub Macro1()
Dim tablaRef As Range
Dim UltimaFila As Long
Dim UltimaColumna As Long

'Recogemos valores para las variables de UltimaFila y UltimaColumna
    UltimaFila = Sheets(Hoja1).Range("C3").End(xlDown).Row
    UltimaColumna = Sheets(Hoja1).Range("C3").End(xlToRight).Column
    
    Set tablaRef = Sheets("Hoja1").Range(Cells(2, 1), Cells(UltimaFila, UltimaColumna))
    
	tablaTarifasRef.Select

End Sub

 

Los resultados de las variables UltimaFila = 205 y UltimaColumna = 24

El problema viene al intentar dar a la variable tablaRef su rango, me salta el error 1004 en tiempo de ejecución. Error definido por la aplicación y el objeto.

En cambio si utilizo el siguiente ejemplo si me lo permite, pero no me sirve porque quiero definir tanto la ultima fila como la última columna. 

Set tablaRef = Sheets("Hoja1").Range("A2:X" & UltimaFila)

Es por el objeto Cells? Me podéis aclarar el porque de ese error?

Muchas gracias por adelantado!!

Sub Macro1()
    Dim tablaRef As Range
    Dim UltimaFila As Long
    Dim UltimaColumna As Long

    ' Recogemos valores para las variables de UltimaFila y UltimaColumna
    With Sheets("Hoja1")
        UltimaFila = .Cells(.Rows.Count, "C").End(xlUp).Row
        UltimaColumna = .Cells(3, .Columns.Count).End(xlToLeft).Column
        Set tablaRef = .Range(.Cells(3, 3), .Cells(UltimaFila, UltimaColumna))
    End With
    
    ' Seleccionamos la tabla de referencias
    tablaRef.Select
End Sub

No lo he probado, prueba y comenta

hace 3 horas, JSDJSD dijo:

Sub Macro1()
    Dim tablaRef As Range
    Dim UltimaFila As Long
    Dim UltimaColumna As Long

    ' Recogemos valores para las variables de UltimaFila y UltimaColumna
    With Sheets("Hoja1")
        UltimaFila = .Cells(.Rows.Count, "C").End(xlUp).Row
        UltimaColumna = .Cells(3, .Columns.Count).End(xlToLeft).Column
        Set tablaRef = .Range(.Cells(3, 3), .Cells(UltimaFila, UltimaColumna))
    End With
    
    ' Seleccionamos la tabla de referencias
    tablaRef.Select
End Sub

No lo he probado, prueba y comenta

Genial, me funcionó, mil gracias!!