Buenas Noches a todos!!!

Pidiendo de su ayuda, tengo una carpeta varios archivos que tienen informacion, yo quiero generar un reporte en donde me abra cada archivo de excel y me copie toda la informacion a un archivo de excel,  solo que ese reporte  quiero tenerlo en una solo hoja, es decir que vayan pegando uno abajo del otro como lista. se podra?

Anexo archivos

Gracias!!!

 

Archivos.zip

Sub Consolidar(): Application.ScreenUpdating = False
    
    Dim Ruta As String
    Dim Nombre As String
    Dim Libro As Workbook
    Dim Hoja As Worksheet
    Dim uf As Long
    Dim consolidarhoja As Worksheet
    Dim consolidarlinea As Long
    
    Ruta = "C:\Users\JSD\Desktop\Archivos" '<<Aquí debes poner la ruta en la cual tienes los archivos
    Set consolidarhoja = ThisWorkbook.Worksheets("sheet1")
    consolidarlinea = 2

    Nombre = Dir(Ruta & "\*.xlsx")
    Do While Nombre <> ""
        Set Libro = Workbooks.Open(Ruta & "\" & Nombre)

        For Each Hoja In Libro.Worksheets
            uf = consolidarhoja.Cells(Rows.Count, 1).End(xlUp).Row
            Hoja.UsedRange.Offset(1, 0).Copy consolidarhoja.Cells(uf + 1, 1)
            consolidarlinea = consolidarlinea + Hoja.UsedRange.Rows.Count
        Next Hoja

        Libro.Close SaveChanges:=False
        Nombre = Dir()
    Loop
End Sub

 

El archivo

Archivos.rar

Si asi es como lo queria!!!

solo una pregunta antes  de que termine la macro, me podria mandar un mensage de cuantos archivos proceso

Gracias!!!

Sub Consolidar(): Application.ScreenUpdating = False
    Dim Ruta As String
    Dim Nombre As String
    Dim Libro As Workbook
    Dim Hoja As Worksheet
    Dim uf As Long
    Dim consolidarhoja As Worksheet
    Dim consolidarlinea As Long
    Dim mensaje As String
    Dim cant_libros As Integer
    Dim cant_lineas As Long
    
    Ruta = "C:\Users\JSD\Desktop\Archivos" '<<Aquí debes poner la ruta en la cual tienes los archivos
    Set consolidarhoja = ThisWorkbook.Worksheets("sheet1")
    consolidarlinea = 2
    cant_libros = 0
    
    Nombre = Dir(Ruta & "\*.xlsx")
    Do While Nombre <> ""
        Set Libro = Workbooks.Open(Ruta & "\" & Nombre)
        cant_libros = cant_libros + 1
        mensaje = mensaje & "- " & Nombre & vbCrLf
    
        For Each Hoja In Libro.Worksheets
            uf = consolidarhoja.Cells(Rows.Count, 1).End(xlUp).Row
            Hoja.UsedRange.Offset(1, 0).Copy consolidarhoja.Cells(uf + 1, 1)
            cant_lineas = Hoja.UsedRange.Rows.Count - 1 ' Restamos 1 para no contar los encabezados
            consolidarlinea = consolidarlinea + cant_lineas
            mensaje = mensaje & "  - " & Hoja.Name & ": " & cant_lineas & " líneas" & vbCrLf
        Next Hoja
    
        Libro.Close SaveChanges:=False
        Nombre = Dir()
    Loop
    
    mensaje = "Se han examinado " & cant_libros & " libros:" & vbCrLf & mensaje
    mensaje = mensaje & vbCrLf & "La cantidad de líneas totales de todos los libros es: " & consolidarlinea - (cant_libros - 1)
    MsgBox mensaje, vbInformation, "Resultados de la consolidación"
End Sub

 

Archivos.rar

Genial!!!

si asi mero, Mil Gracias!!!

Doy por finalizada la pregunta

En 6/5/2023 at 16:49 , smart27 dijo:

Doy por finalizada la pregunta

Estimados @Abraham Valencia @Gerson Pineda

Yo sigo con esa duda, si el maestro @JSDJSD ha logrado ayudar satisfactoriamente a @smart27  ¿no debería el consultante poder dar por solucionado el tema, marcarlo como otros que sí se ven finalizados? ¿Es desconocimiento por parte del consultante o es complicado hacerlo?  Tal vez Smart27 pudiera compartir desde su perspectiva algo que sea coincidente con los demás participantes. ¿Valdría la pena reforzar ese punto en las bienvenidas o ya se ha intentado sin éxito?

Saludos cordiales.