Hola compañeros,

Tengo un módulo de login que me mantiene ocultas las hojas del libro, siempre y cuando el usuario no se haya identificado previamente.

El caso es que cuando abro el libro en otro equipo (evento Workbook_Open > Abrir FormularioDeAcceso), me aparece el típico mensaje de "Habilitar las macros".

El problema es que YO NO QUIERO QUE EL USUARIO PUEDA VISUALIZAR EL CONTENIDO DE ESAS HOJAS SI NO ESTÁ LOGUEADO.

Y claro... Simplemente, con cerrar el mensaje de habilitar las macros y un click derecho "Mostrar hojas" es suficiente para visualizar el contenido de las hojas, sin necesidad de tener que loguearse.

Por eso mi pregunta es: ¿Sabéis si existe alguna manera (macro o lo que sea) tal que si un usuario no ha habilitado previamente las macros, entonces cierre el libro (Application.Quit sin guardar)?

Gracias.

• Añade una hoja, por ejemplo Aviso.
• Pon en esa hoja una leyenda con algo parecido a esto "DEBE HABILITAR LAS MACROS PARA ACCEDER"
• Cuando guardes el archivo, en el procedimiento Workbook_BeforeSave, oculta todas las hojas como VeryHidden y visualiza la hoja Aviso.
• Una vez logeado, oculta la hoja Aviso y visualiza las demás.

Por supuesto, el proyecto VBA y la hoja Aviso deben estar protegidos.

Efectivamente, @Antoni. Esa es lo solución que he logrado encontrar.

Al parecer (y según he podido leer por Internet), lo que comentas se trata de un pequeño truco muy utilizado entre la comunidad de programadores de VBA.

Por mi parte, desconocía por completo de la propiedad "xlVeryHidden".

Este es mi código (por si a alguien le interesa):

Private Sub Workbook_BeforeClose(Cancel As Boolean)

Application.ScreenUpdating = False

   ' Limpiamos los errores anteriores (por si acaso)...
   Err.Clear

   ' Tratamos los errores de la aplicación ofimática...
   On Error GoTo error

   ' Declaramos las variables de ámbito local...
   Dim libroActual As Workbook, hojaActual As Worksheet

   ' Recorremos todos los libros abiertos...
   For Each libroActual In Workbooks
      ' Recorremos todas las hojas del libro abierto...
      For Each hojaActual In libroActual.Worksheets
         With hojaActual
            ' Si la hoja actual es el menu de inicio, entonces...
            If .Name = "MENU" Then
               ' Mostramos la hoja...
               .Visible = xlSheetVisible
            ' En caso contrario...
            Else
               ' Ocultamos la hoja...
               .Visible = xlVeryHidden
            End If
         End With
      Next hojaActual
   Next libroActual

salir:
   ' Y salimos del procedimiento...
   Exit Sub
error:
   ' Mostramos por pantalla el tipo de error y la descripción del mismo...
   MsgBox Prompt:="Upps, parece que hubo un error... Por favor, póngase en contacto " & _
                  "directamente con su programador informático." & vbCr & vbCr & _
                  "El error producido es [" & Err.Number & "] - " & Err.Description & _
                  " en el evento Workbook_BeforeClose del libro " & ActiveWorkbook.Name & ".", _
          Buttons:=vbCritical, _
          Title:="                                               AVISO IMPORTANTE"
   ' Sacamos el error fuera de la pila de errores...
   Resume salir

End Sub

Un saludo.

Hola @paikerr

Tu pregunta me pareció muy interesante y dije: "Ahora podré ayudarlo" pero luego veo la magnífica respuesta de @Antoni y no queda más que aclarar, sus explicaciones son óptimas.

Solo aclarar un par de términos...

xlVeryHidden no es una propiedad, la propiedad se llama Visible y xlVeryHidden es el valor que le asignas a la propiedad Visible.

En el fondo la propiedad Visible puede tener tres valores: 0 (Invisible), -1 (Visible) y 2 ("Muy" invisible) pero a veces recordar qué significa cada valor es algo difícil (de recordar y luego de leer) entonces para ello tienes las CONSTANTES. Las constantes de Excel empiezan con "xl" y las de VBA empiezan por "vb"

Muchas gracias @DiegoPC por tomarte un tiempo en responderme y corregir mis comentarios.

Gracias por el aporte. Saludos.