Asignar nombre a un boton

[Denys]

Buenas, tengo el siguiente código:

Private Sub CommandButton106_Click()
Hoja2.Select
Hoja2.Range("B1").Select
While ActiveCell.Offset(0, 6) <> Empty
    ActiveCell.Offset(1, 0).Select
    boton = ActiveCell.Offset(0, 6)   <======= En ésta linea de código obtengo el nombre de un botón que se encuentra digitado en una celda. (Ejemplo: "CommandButton6") y es almacenado en la variable boton, tal como se muestra.
    If Hoja1.txtcodigo.Text = ActiveCell Then
        boton.BackColor = &HFF&   <======= Aquí está el problema, cuando quiero hacer referencia a ese nombre como un botón, no lo reconoce (Ejemplo: CommandButton6.Backcolor=&HFF&)
    Else
        boton.BackColor = &HE0E0E0
    End If
Wend
End Sub

Incluso he tratado de crear otra variable declarada como Botón y asignándole como Name la otra variable, pero aun nada....debo estar declarando mal alguna de esa variables o tal vez falte algo...gracias por sus aportes.

 

[Antoni]

VBA no permite referirse a un control ActiveX cuyo nombre este en una variable tipo string.

Entiendo que los botones están en la hoja, si los cambias a botones del tipo control de formulario, si podrías hacerlo.

También se puede intentar con un módulo de clase.

Sube tu archivo con todas las macros e intentaré buscarte una solución.

[Denys]

Buenas tardes, gracias por la pronta respuesta, aqui le adjunto el archivo esperando pueda darme una solución...muy agradecido.

 

UBICACION DE INSUMOS Y EMBALAJES - copia.rar

[Antoni]

Prueba así:

Private Sub CommandButton106_Click()
On Error Resume Next
Dim Boton As Object
Application.ScreenUpdating = False
'--
Hoja2.Select
Hoja2.Range("B1").Select
'--
While ActiveCell.Offset(0, 6) <> Empty
    ActiveCell.Offset(1, 0).Select
    Set Boton = Sheets("Croquis").OLEObjects(ActiveCell.Offset(0, 6).Value).Object
    If Hoja1.txtcodigo.Text = ActiveCell.Value Then
        Boton.BackColor = vbRed '&HFF&
    Else
        Boton.BackColor = &HE0E0E0
    End If
Wend
Sheets("Croquis").Select
End Sub

 

[Denys]

Buenas, hice tu recomendación pero al des habilitar la linea de código "On Error resume Next", me sale un mensaje de error,

y si la habilito, no se ejecuta nada....

[Denys]

Mi estimado mil disculpas, la macro funciona perfectamente, solo que tengo un inconveniente, solo reconoce el valor cuando esta en la segunda fila de cada botón de referencia:

* Aquí NO lo reconoce:

*Aquí SI lo reconoce:

Y sucede lo mismo para todos los botones.

[Antoni]

Así no debería haber problemas:

Private Sub CommandButton106_Click()
On Error Resume Next
Dim Boton As Object
Application.ScreenUpdating = False
'--
For x = 2 To Hoja2.Range("B" & Rows.Count).End(xlUp).Row
   Set Boton = Hoja1.OLEObjects(Hoja2.Range("H" & x).Value).Object
   If Hoja1.txtcodigo.Text = Hoja2.Range("B" & x) Then
      Boton.BackColor = vbRed '&HFF&
   Else
      Boton.BackColor = &HE0E0E0
   End If
Next
End Sub

 

[Denys]

Mi estimado mil disculpas, la macro funciona perfectamente, solo que tengo un inconveniente, solo reconoce el valor cuando esta en la segunda fila de cada botón de referencia:

* Aquí NO lo reconoce:

*Aquí SI lo reconoce:

Y sucede lo mismo para todos los botones.

Cuando el valor se encuentra en la fila superior del mismo botón de referencia, simplemente no cambia de color el botón en la otra hoja, sin embargo cuando el valor esta en la fila inferior del mismo botón de referencia, si lo hace.

[Antoni]

A la tercera va la vencida:

Private Sub CommandButton106_Click(): On Error Resume Next
Dim Boton As Object
Application.ScreenUpdating = False
For x = 2 To Hoja2.Range("H" & Rows.Count).End(xlUp).Row
   Set Boton = Hoja1.OLEObjects(Hoja2.Range("H" & x).Value).Object
   Boton.BackColor = &HE0E0E0
Next
For x = 2 To Hoja2.Range("B" & Rows.Count).End(xlUp).Row
   Set Boton = Hoja1.OLEObjects(Hoja2.Range("H" & x).Value).Object
   If Hoja1.txtcodigo.Text = Hoja2.Range("B" & x) Then
      Boton.BackColor = vbRed '&HFF&
   End If
Next
End Sub

 

[Denys]

FUNCIONA PERFECTAMENTE....gracias por tu tiempo, excelente tu lógica... eres un capo....

doy este tema como.....CERRADO.