Salto de página cada cierta cantidad de filas

[jik]

Hola. Necesito hacer una macro para que se inserten saltos de página cada una determinada cantidad de filas en un libro que tiene unas 10.000 filas aproximadamente. 

Gracias

[AlexanderS]

Hola @jik, para que te podamos ayudar adecuadamente debes explicar mejor tu problema y adjuntar un archivo excel de ejemplo con lo que esperas de resultado.

Te dejo una idea para que puedas adaptarlo a tu archivo.

Sub insertar_filas()

For i = 1 To 10000 Step 4

Cells(i, 1).EntireRow.Insert Shift:=xlDown

Next

End Sub

saludos.

[jik]

Hola. Muchas gracias.

No tengo un archivo pero lo que necesito es algo para uso general.

Lo que tú me has enviado inserta filas. Yo necesito insertas saltos de página cada una cierta cantidad de filas. Por ejemplo: insertar un salto de página cada 40 filas.

Saludos.

[AlexanderS]

@jik, prueba así.

Sub insertar_filas()

For i = 40 To 1000 Step 40

ActiveWindow.SelectedSheets.HPageBreaks.Add Before:=Range("A" & i + 1)

Next

End Sub

El archivo es por normas del foro, puedes armar un pequeño ejemplo con solo datos ficticios, tómalo en cuenta para futuras consultas.

Saludos.

[jik]

Hola de nuevo. La macro me daba un error en la segunda línea pero la corregí cambiando por número de fila.

Sub insertar_filas()

Application.ActiveSheet.ResetAllPageBreaks

For i = 40 To 1000 Step 40

ActiveWindow.SelectedSheets.HPageBreaks.Add Before:=Rows(i + 1)

NextDemo.xlsx

End Sub

 

Ahora tengo una complicación adicional que es que tengo que insertar el salto de página cada 40 filas VISIBLES. Con esto quiero decir que si por ejemplo, hay fila ocultas, éstas no se consideren para la  cuenta de líneas del salto de página.

Adjunto el archivo donde he ocultado las filas de 10 a 20 y 70 a 80.

Para que funcione como yo quiero, el salto de página debería ir en la línea 51 (1 + 40 filas + 10 filas ocultas)

El siguiente salto sería de la 52 a la 102 porque también hay 10 ocultas y así sucesivamente.

Aclaro que el número de fila ocultas no es fijo (en mi ejemplo fueron 10 las 2 veces pero podría 5 una vez, 20 otra vez, etc).

 

[AlexanderS]

@jik, basado en tu ejemplo, con esta modificación debería funcionar sin importar donde o cuantas celdas ocultas tengas.

Sub insertar_filas()
Dim x#, celda As Range

Application.ActiveSheet.ResetAllPageBreaks

For Each celda In Range("A1", Range("A1").End(xlDown)).SpecialCells(xlCellTypeVisible)
    x = x + 1
    If x = 40 Then
        x = 0
        ActiveWindow.SelectedSheets.HPageBreaks.Add Before:=Rows(celda.Row + 1)
    End If
Next

End Sub

Comentas, saludos.

[jik]

Hola. No funciona. NO hace nada más que borrar los saltos de página existente. 

[AlexanderS]

A mi me funciona sin problema, prueba el adjunto.

Demo.xlsm

[jik]

Pues a mi no me funciona. Ya lo probé y sólo borra los saltos de página.

No faltará un "Else" o algo así?

Donde termina esta fórmula? Necesitaría darle un fin en, por ejemplo, la fila 10.000

Gracias

[AlexanderS]

Imagino que en el archivo donde lo probaste tienes filas en blanco antes del primer salto de linea, creo que ese es el error.

Hace 8 minutos , jik dijo:

No faltará un "Else" o algo así?

No es necesario solo estoy contando 40 lineas de lo contrario simplemente no hace nada.

 

Hace 9 minutos , jik dijo:

Donde termina esta fórmula? Necesitaría darle un fin en, por ejemplo, la fila 10.000

Le indico en esta linea Range("A1", Range("A1").End(xlDown)).SpecialCells(xlCellTypeVisible) que apartir de la celda A1 se vaya a la ultima celda con datos, por eso si tienes alguna celda vacía por ejemplo en la fila 12 hasta ahí llega ciclo for. 

Prueba ahora con esta modificación, no es necesario indicar la cantidad de filas ya que encontrara la ultima fila de la columna A con datos, esto es conveniente si tus datos van a crecer aun mas.

Sub insertar_filas()
Dim x#, celda As Range

Application.ActiveSheet.ResetAllPageBreaks

For Each celda In Range("A1", Range("A" & Cells.Rows.Count).End(xlUp)).SpecialCells(xlCellTypeVisible)
    x = x + 1
    If x = 40 Then
        x = 0
        ActiveWindow.SelectedSheets.HPageBreaks.Add Before:=Rows(celda.Row + 1)
    End If
Next

End Sub

De igual manera y por aquello puedes usar esta linea también 

For Each celda In Range("A1:A10000").SpecialCells(xlCellTypeVisible)

Saludos.