Buscar la última fecha

Maverick_14 · el 15 de marzo

Hola a todos, escribi una macro para que cuando apieto un boton en un textbox me tenga que aparecer la ultima fecha ingresada, pero no funciona, lo dejo por si alguien me puede dar una mano y decirme que estoy haciendo mal. yo creo q es xq deberia transformar las fechas a otro tipo de dato para comparar o compar los años, los meses y los dias por separado. Muchas gracias!

Prueba Visual.rar

Maverick_14 · el 15 de marzo

Con ultima fecha me refiero a la más actual, creo q eso no se entendio bien. O sea, si yo ingreso 01/01/1999 y 05/09/2005 quiero que me muestre esta última.

logroastur · el 15 de marzo

Buenas utiliza

Private Sub CommandButton1_Click()
    Dim i As Long
    Dim c As Long
    'ABRIMOS PROPIEDADES DE LA HOJA
    With Worksheets("BASE")
        'COMPROBAMOS QUE EN ALGUNO ENCABEZADO DE COLUMNA EXISTA " FECHA "
        c = WorksheetFunction.CountIf(.Rows("1:1"), "Fecha")
        'SI NO HAY NINGUNO
        If c = 0 Then
            'LANZAMOS ALERTA
            MsgBox "No esiste columna alguna con los parametros solicitados", vbExclamation, ""
            'ABORTAMOS PROCESO
            Exit Sub
        End If
        'HALLAMOS LA POSICIÓN DE LA COLUMNA DONDE ESTA EL ENCABEZADO DE COLUMNA  " FECHA "
        c = WorksheetFunction.Match("Fecha", .Rows("1:1"), 0)
        'CALCULAMOS EL VALOR MAS ALTO
        i = WorksheetFunction.Max(.Columns(c))
        'SI EL VALOR ES 0
        If i = 0 Then
            'COLOCAMOS ALERTA
            FECHA.Value = "SIN DATOS"
        Else
            'COLOCAMOS LA FECHA EN FORMATO DD/MM/YY
            FECHA.Value = Format(CDate(i), "dd/mm/yy")
        End If
    End With
End Sub

Un saludo