es sobre el ejemplo que me habias subido me funciono en la seccion uno pero en esta seccion, no ahi les envio el archivo, te lo agradeceria nuevamente jm123

SECCION DOS.rar

Buenas puedes usar

Sub ShowDatos()
    Dim d As Variant
    Dim t As String
    Dim r As Range
    Dim i As Long
    On Error GoTo error
    'CREAR DOS SEPARADORES
    d = Chr(32) & Chr(32)
    'CARGAR EL TEXTO DEL SHAPE
    t = Hoja1.Shapes(Application.Caller).TextFrame.Characters.Text
    'SUSTITUIR LOS VALORES DE SEPARADORES DE LETRAS
    t = Replace(t, d, Chr(32))
    'CREAR UNA BUSQUEA HASTA QUE NO EXISTEN UN SEPARADR DE LERAS AL INICIO
    Do
        If Left(t, 1) = Chr(32) Then
            t = Right(t, Len(t) - 1)
        Else
            Exit Do
        End If
    Loop
    'SEPARAR EN UN ARRAY
    d = Split(t, " ")
    'BUSCAR EL NÚMERO DEL 1º ARRAY
    i = LBound(d)
    'SUSTITUIR LOS VALORES DE SEPARADORES DE LETRAS Y DE SALTOS DE LINEA
    t = Replace(Replace(d(i), Chr(32), ""), Chr(10), "")
    'CREAMOS UNA BUSQUEDA EN EL DAT DE LA COLUMNA A EN HOJA 2
    Set r = Hoja2.Range("A:A").Find(t)
    'COMPROBAMOS SI HAY UN VALOR DE BUSQUEDA
    If r Is Nothing Then
        MsgBox "No encontrado", vbExclamation, ""
        Exit Sub
    End If
    'TOMAMOS EL NÚMERO DE FILA
    i = r.Row
    'LANZAMOS MENSAJE DE COLUMNA B EN HOJA 2
    MsgBox Hoja2.Range("B" & i), vbInformation, ""
    Exit Sub
error:
    'LANZAMOS MENSJE DE ERROR
    MsgBox Err.Description, vbCritical, Err.Number
End Sub

Un saludo

trabajo de maravilla el codigo nuevamente muchas gracias logroastur y saludos desde Reynosa Tamaulipas