Comparar texto de dos columnas

Jose21 · el 20 de noviembre

Hola a Tod@s, este es mi primer mensaje.

Necesito comparar textos de dos columnas (A y y que el Resultado aparezca en la columna C

Comparar las columnas A - B y Si hay algun texto de la columna A = B , que en la Columna C solo aparezcan los textos de la Columna A pero no los de la B.

adjunto hoja con el ejemplo.

Muchas Gracias

Saludos

Compara1.xls

German · el 20 de noviembre

Hola Jose, echa un vistazo al adjunto a ver si es lo que necesitas, luego comentas algo, ok?

Saludos, Germán.

Compara1.rar

ioyama · el 20 de noviembre

Hola Jose21

Bienvenido al foro

En el adjunto tienes una opción con funciones matriciales.

Escribes la función, seleccionas todo el rango donde va a ir la función, incluida la celda que la contiene.

Entras en modo edición (F2 o seleccionas la función en la barra de fórmulas)

Pulsas Control+Mayúsculas+Intro

Es interesante definir los rangos de las listas mediante nombres, facilitas la escritura de la función.

El condicional y la función ESERROR son para evitar la aparición de errores en las celdas sin datos. Si prefieres puedes simplificar la función y usar el formato condicional para que no se vean dichos errores.

Un saludo desde Vitoria

ValoresDistintos_io_121120.zip

Jose21 · el 20 de noviembre

Hola German. Se prodria hacer que los textos de la columna C aparezcan en celdas seguidas y no separadas?

Gracias

Saludos

- - - - - Mensaje combinado - - - - -

Hola ioyama, Excelente es justo lo que necesito. Me podrias explicar la funcion que utilizaste.

Muchas Gracias

Saludos

ioyama · el 20 de noviembre

Hola Jose21

Explicar

=SI(ESERROR(INDICE($A$2:$A$6;K.ESIMO.MENOR(SI(ESNOD(COINCIDIR($A$2:$A$6;$B$2:$B$6;0));COINCIDIR($A$2:$A$6;$A$2:$A$6;0);"");FILA(INDIRECTO("1:"&FILAS($A$2:$A$6))))));"";INDICE($A$2:$A$6;K.ESIMO.MENOR(SI(ESNOD(COINCIDIR($A$2:$A$6;$B$2:$B$6;0));COINCIDIR($A$2:$A$6;$A$2:$A$6;0);"");FILA(INDIRECTO("1:"&FILAS($A$2:$A$6))))))

al estilo Jack (por partes)

la base es

INDICE($A$2:$A$6;K.ESIMO.MENOR(SI(ESNOD(COINCIDIR($A$2:$A$6;$B$2:$B$6;0));COINCIDIR($A$2:$A$6;$A$2:$A$6;0);"");FILA(INDIRECTO("1:"&FILAS($A$2:$A$6)))))

SI y ESERROR son para evitar que aparezcan errores en las celdas en las que va la función pero no devuelve un dato, así las dejamos en blanco.

Estamos usando la función INDICE , tal que según la ayuda de Excel

Devuelve el valor de un elemento de una tabla o matriz seleccionado por los índices de número de fila y de columna.

INDICE(matriz; núm_fila; [núm_columna])

a fin de que nos devuelva los datos de compra ($A$2:$A$6)

el parámetro [núm_columna] lo obviamos puesto que la columna es única

con K.ESIMO.MENOR obtenemos el número de fila, tal que según la ayuda de excel

Devuelve el k-ésimo menor valor de un conjunto de datos. Utilice esta función para devolver valores con una posición relativa específica dentro de un conjunto de datos.

K.ESIMO.MENOR(matriz;k)

Matriz es una matriz o un rango de datos numéricos cuyo k-ésimo menor valor desea determinar.

K es la posición, dentro de la matriz o del rango de datos, de los datos que se van a devolver, determinada a partir del menor de los valores.

K.ESIMO.MENOR(SI(ESNOD(COINCIDIR($A$2:$A$6;$B$2:$B$6;0));COINCIDIR($A$2:$A$6;$A$2:$A$6;0);"");FILA(INDIRECTO("1:"&FILAS($A$2:$A$6))))

la matriz la obtenemos con

SI(ESNOD(COINCIDIR($A$2:$A$6;$B$2:$B$6;0));COINCIDIR($A$2:$A$6;$A$2:$A$6;0);"")

ESNOD

Verifica si se refiere al valor de error #N/A (el valor no está disponible) y devuelve VERDADERO o FALSO

luego SI

Cuando ESNOD(COINCIDIR($A$2:$A$6;$B$2:$B$6;0)) sea VERDADERO nos devolverá COINCIDIR($A$2:$A$6;$A$2:$A$6;0), o lo que es lo mismo el posicionamiento del dato en la lista, en caso de FALSO nos devuelve "" (osea nada)

Así obtenemos una lista númerica para los valores coincidentes que no están en la segunda lista

K.ESIMO.MENOR se encarga de recuperar esos valores posicionados según K

El valor de k viene dado por FILA(INDIRECTO("1:"&FILAS($A$2:$A$6))), es decir una matriz que va de 1 hasta el número de filas del rango.

La explicación quizás no sea clara, pero las matriciales de inicio son un poco complicadas de entender.

Un saludo desde Vitoria