Estimados Expertos:

Quería consultar su ayuda sobre combobox aplicado en una hoja excel (sin colocarla en un formulario).  Al adicionar los valores para este combobox realizo un filtrado para eliminar valores repetidos.  Logro eliminar los valores repetidos, pero como adiciono un comando Clear al inicio para borrar los datos de filtrado y no se me acumule, entonces al final se borra el item seleccionado. Les paso mi fichero por si alguien ha tratado de realiza anteriormente este proceso:

Private Sub Combobox1_DropButtonClick()

    Dim sd As New Collection
    Dim celda As Range
    Dim dato
    Dim r As Range
    Dim UF As Integer
    On Error Resume Next
    Worksheets("CONSOLIDADO").Activate
    Range("S2").Select
    CMBPlanta.Clear
    With Worksheets("BASE")
        UF = .Range("S" & Rows.Count).End(xlUp).Row
        Set r = .Range("S2:S" & UF)
        For Each celda In r
            sd.Add celda.value, CStr(celda.value)
        Next celda
        For Each dato In sd
            Combobox1.AddItem dato
        Next dato
    End With

End Sub

Cunado realizo este combobox en un formulario no me genera mayor problema, pero quería saber si  colcando el combobox directo a la hoja de excel puede funcionar.Muchas gracias por su ayuda.

Hola,

Pues el código que ha compartido (en mi opinión) se ve bien en su estructura, tal vez el problema de que se borre el ítem se deba a la forma en que se está limpiando el ComboBox.

Por qué no guarda el ítem seleccionando una variable selectedItem. Así después de limpiar y volver a llenar el ComboBox, restaura el ítem seleccionado.

Algo así:

Private Sub Combobox1_DropButtonClick()
    Dim sd As New Collection
    Dim celda As Range
    Dim dato
    Dim r As Range
    Dim UF As Integer
    Dim selectedItem As String
    On Error Resume Next
    Worksheets("CONSOLIDADO").Activate
    Range("S2").Select
    ' Guarda el ítem seleccionado
    selectedItem = Combobox1.Value
    ' Limpia el ComboBox
    Combobox1.Clear
    With Worksheets("BASE")
        UF = .Range("S" & Rows.Count).End(xlUp).Row
        Set r = .Range("S2:S" & UF)
        For Each celda In r
            sd.Add celda.Value, CStr(celda.Value)
        Next celda
        For Each dato In sd
            Combobox1.AddItem dato
        Next dato
    End With
    ' Restaura el ítem seleccionado
    Combobox1.Value = selectedItem
End Sub

 

Editado el el 17 de septiembre17 sep por Israel Cassales

Muchas gracias por su pronta repuesta Israel. Ese era el detalle  👍

Me da gusto que le haya servido, concluyo mi participación en la consulta.