Hola a tod@os,

 

Estoy con un proyecto para mi trabajo, se trata de una plantilla que relleno con una serie de datos, ya he creado los botones de :

guardar: Crea un clon en una hoja nueva con el nombre de serie que se ha especificado, a la vez genera una fila en una tabla con parte de la información que se introduce, (precio, fecha, serie, cliente..)

limpiar: Limpia los datos para una nueva inserción

imprimir: imprime la plantilla con los datos

pdf: crea un pdf de la plantilla con los datos y el nombre de la serie

eliminar: elimina el clon de hoja y la fila correspondiente en la tabla

modificar: Aquí estoy estancado, he creado una sentencia pero solo consigo que me modifique  la celda de la ultima fila de la tabla, necesito ayuda para que estando en la hoja clon correspondiente al modificar algunos datos se reflejen en la correspondiente celda de la tabla,

el dato  (un precio) lo copia siempre de una celda concreta de la hoja activa G34

la serie  la saca de la celda G4 de la hoja activa

este cambio debe verse reflejarse en una columna (F) concreta de la hoja 16 "tabla" y en la fila que corresponda con el numero de serie que está en la columna B de la tabla, 

 

En mi cabeza parece sencillo, es un copiar pegar pero no doy con la tecla, es por ello que os pido ayuda.

 

Sub Modificar()

Range ("G34").Copy                                      copia la celda g34 de la celda activa

WorkSheets. ....Hoja16..........................  .Range............................................       aqui es donde no se si voy bien ,  como hago para que sepa en que celda de la hoja16 debe pegar?

Application.Cutcopymode = False       quita la info del portapapeles

End Sub

 

 

 

 

 

En base a lo explicado y ha falta de un libro de muestra que evite ambigüedades, creo entender el problema que tienes con la macro de VBA, y para que la macro identifique correctamente la fila en la “tabla” basada en el número de serie y actualice la celda correspondiente, podrías utilizar el siguiente código:

Sub Modificar()
    Dim ws As Worksheet
    Set ws = ThisWorkbook.Sheets("tabla") ' Ajusta al nombre de tu hoja de tabla
    Dim serie As String
    Dim rangoTabla As Range
    Dim celda As Range

    serie = ThisWorkbook.Sheets("HojaClon").Range("G4").Value ' Ajusta al nombre de tu hoja clon
    Set rangoTabla = ws.Range("B:B").Find(What:=serie, LookIn:=xlValues, LookAt:=xlWhole)

    If Not rangoTabla Is Nothing Then
        ws.Cells(rangoTabla.Row, "F").Value = ThisWorkbook.Sheets("HojaClon").Range("G34").Value ' Ajusta la columna si es necesario
    Else
        MsgBox "Número de serie no encontrado."
    End If

    Application.CutCopyMode = False
End Sub

Este código busca el número de serie en la columna B de la  “tabla” y, si lo encuentra, actualiza la celda en la columna F de la misma fila con el valor de la celda G34 de la hoja clon.

Es con lo que podría participar en este tema esperando sea de ayuda, en caso contrario aún podría pasar algún Maestro que aporte algo diferente o entienda mejor el tema.

Saludines

 

gracias por tu tiempo,  

si creo una hoja clon que se llame "3" y en tu código sustituyo "hojaclon" por "3" el código funciona bien, coloca el valor de la celda G34 en la columna F correspondiente

pero cada vez que creo una "hoja clon" se le asigna un nombre diferente  y por ello necesito que coja el valor de la celda G34 de la hoja activa (que tendrá un nombre x),  no puedo sustituir "hojaclon" de tu  código por una hoja concreta porque cambia el nombre cada vez que creo una.

he probado con Activesheet pero no tengo claras las variables

 

 

Entonces un ejemplo de cómo puedes usar ActiveSheet junto con las variables para modificar los datos sería algo parecido a esto:

Sub Modificar()
    Dim wsTabla As Worksheet
    Set wsTabla = ThisWorkbook.Sheets("tabla") ' Ajusta al nombre de tu hoja de tabla
    Dim serie As String
    Dim rangoTabla As Range
    Dim celda As Range

    ' Obtiene la serie de la hoja activa
    serie = ActiveSheet.Range("G4").Value
    
    ' Busca la serie en la columna B de la hoja "tabla"
    Set rangoTabla = wsTabla.Range("B:B").Find(What:=serie, LookIn:=xlValues, LookAt:=xlWhole)

    ' Si encuentra la serie, actualiza la celda en la columna F con el valor de G34 de la hoja activa
    If Not rangoTabla Is Nothing Then
        wsTabla.Cells(rangoTabla.Row, "F").Value = ActiveSheet.Range("G34").Value
    Else
        MsgBox "Número de serie no encontrado."
    End If

    Application.CutCopyMode = False
End Sub

En la macro, ActiveSheet se utiliza para referirse a la hoja que está activa en el momento en que se ejecuta la macro. La variable serie almacena el valor de la celda G4 de la hoja activa, y luego se busca este valor en la columna B de la hoja “tabla”. Si se encuentra una coincidencia, se actualiza la celda en la columna F de la misma fila con el valor de la celda G34 de la hoja activa.

Es perfecto, muchas gracias.

tengo que implementar bastante código todavía en el proyecto, de momento iré intentándolo por mi cuenta leyendo mucho, si me vuelvo a encallar preguntaré por aquí.

Agradezco tu ayuda