Hola, tengo el siguiente código asignado a un Botón de "Eliminar" dentro de un Formulario en Excel, quisiera agregarle la parte de confirmación, donde me pregunte "Confirma eliminar el registro"  Si - No, y ahí me perdí un poco, agradecería mucho su ayuda.

------------

Private Sub BT_Eliminar_Click()
Me.BT_Agregar.Enabled = True

Dim FILA As Object
Dim Linea As Integer
Dim NumeroFila As String

NumeroFila = Me.TextRolPatente

Set FILA = Sheets("Basedatos").Range("B:B").Find(NumeroFila, LOOKAT:=xlWhole)

Linea = FILA.Row

Range("B" & Linea).EntireRow.Delete

MsgBox "El registro fue eliminado"

Me.TextRolPatente = Empty
Me.TextRut = Empty
Me.TextNombre = Empty
Me.TextFantasia = Empty
Me.TextDireccion = Empty
Me.ComboClasificacion = Empty
Me.ComboSubClasificacion = Empty
Me.ComboLetra = Empty
Me.ComboCodigo = Empty
Me.TextValorutm = Empty
Me.TextEstado = Empty
Me.TextPatCom = Empty
Me.TextNombreArrendador = Empty
Me.TextRutArrendador = Empty
Me.TextNombreCesionario = Empty
Me.TextRutCesionario = Empty
Me.TextObservaciones = Empty
Me.TextObsAnterior = Empty
Me.TextJuntaVecinos = Empty
Me.TextIniact = Empty

Me.OptionArrendadaSi = False
Me.OptionArrendadaNo = False
Me.OptionCesionSi = False
Me.OptionCesionNo = False

Me.TextRolPatente.SetFocus

End Sub

---------------

Private Sub BT_Eliminar_Click()
    Dim respuesta As VbMsgBoxResult
    respuesta = MsgBox("¿Confirma eliminar el registro?", vbQuestion + vbYesNo, "Confirmar eliminación")
    
    If respuesta = vbNo Then
        Exit Sub ' Salir del procedimiento si el usuario elige "No"
    End If

    Me.BT_Agregar.Enabled = True

    Dim FILA As Object
    Dim Linea As Integer
    Dim NumeroFila As String

    NumeroFila = Me.TextRolPatente

    Set FILA = Sheets("Basedatos").Range("B:B").Find(NumeroFila, LOOKAT:=xlWhole)

    If Not FILA Is Nothing Then
        Linea = FILA.Row
        Sheets("Basedatos").Rows(Linea).Delete
        MsgBox "El registro fue eliminado"
    Else
        MsgBox "Registro no encontrado", vbExclamation, "Error"
    End If

    Me.TextRolPatente = Empty
    Me.TextRut = Empty
    Me.TextNombre = Empty
    Me.TextFantasia = Empty
    Me.TextDireccion = Empty
    Me.ComboClasificacion = Empty
    Me.ComboSubClasificacion = Empty
    Me.ComboLetra = Empty
    Me.ComboCodigo = Empty
    Me.TextValorutm = Empty
    Me.TextEstado = Empty
    Me.TextPatCom = Empty
    Me.TextNombreArrendador = Empty
    Me.TextRutArrendador = Empty
    Me.TextNombreCesionario = Empty
    Me.TextRutCesionario = Empty
    Me.TextObservaciones = Empty
    Me.TextObsAnterior = Empty
    Me.TextJuntaVecinos = Empty
    Me.TextIniact = Empty

    Me.OptionArrendadaSi = False
    Me.OptionArrendadaNo = False
    Me.OptionCesionSi = False
    Me.OptionCesionNo = False

    Me.TextRolPatente.SetFocus
End Sub

Prueba y comenta

Editado el el 10 de octubre1 año por JSDJSD

Funciono perfecto, muchas gracias por la ayuda.