SELECCIONAR UN RANGO DE DATOS EN DONDE LOS DATOS QUE COINCIDAN

[jesuspg]

Buenas tardes,

Tengo el siguiente problema, y no sé cómo afrontarlo:

 

Me gustaría almacenar en una variable objeto de tipo Range todas aquellas celdas de la misma columna que coincidan con el mismo nombre de la ciudad.

Por ejemplo, quiero almacenar dentro de una variable range todos las celdas de la columna ciudad que contengan el nombre ALMERIA, en este ejemplo sería RANGE(B2:B3).

Dim rango as Range
Set rango = RANGE(B2:B3)

En el siguiente ejemplo, sería con CADIZ...

rango = RANGE(B4:B7)

Y así sucesivamente hasta llegar al final de la tabla.

Tengamos en cuenta que los datos están ordenados, de no ser así sería más complicado...

Esto lo hago para tener actualizado el administrador de nombres de mi tabla.

 

Si se os ocurre alguna idea más simple, os lo agradecería enormemente.

 

Adjunto el fichero de pruebas.

Ciudades.xlsm

 

Saludos.

[Abraham Valencia]

Hola

Si mal no te entendí esto te servirá:

Sub Prueba()

Dim mifila As Range, mirango As Range

For Each mifila In [CIUDADES].Rows
    
    If mifila.Columns(2).Value = "CADIZ" Then
        If mirango Is Nothing Then
            Set mirango = mifila.Columns(2)
        Else
             Set mirango = Union(mirango, mifila.Columns(2))
        End If
    End If

Next

Hoja1.Names.Add "CADIZ", RefersTo:="='CIUDADES'!" & mirango.Address


End Sub

Comentas

[jesuspg]

Hace 3 horas, Abraham Valencia dijo:

Hola

Si mal no te entendí esto te servirá:

Sub Prueba()

Dim mifila As Range, mirango As Range

For Each mifila In [CIUDADES].Rows
    
    If mifila.Columns(2).Value = "CADIZ" Then
        If mirango Is Nothing Then
            Set mirango = mifila.Columns(2)
        Else
             Set mirango = Union(mirango, mifila.Columns(2))
        End If
    End If

Next

Hoja1.Names.Add "CADIZ", RefersTo:="='CIUDADES'!" & mirango.Address


End Sub

Comentas

Eso me puede valer.

'Union' es precisamente lo que estaba buscando.

 

Mil gracias, @Abraham Valencia.

[jesuspg]

Option Base 1
Sub Prueba()

Dim ciudad As Variant
ciudad = Array("SEVILLA", "CADIZ", "JAEN", "HUELVA", "ALMERIA", "GRANADA")

Dim mifila As Range, mirango As Range
Dim contador As Byte

For contador = 1 To UBound(ciudad)
   For Each mifila In [ciudades].Rows
      If mifila.Columns(2).Value = ciudad(contador) Then
         If mirango Is Nothing Then
            Set mirango = mifila.Columns(2)
         Else
            Set mirango = Union(mirango, mifila.Columns(2))
         End If
      End If
   Next mifila
   ThisWorkbook.Sheets("CIUDADES").Names.Add ciudad(contador), RefersTo:="='CIUDADES'!" & mirango.Address
   Set mirango = Nothing
Next contador


End Sub

Esta es la solución que estaba buscando...

[Abraham Valencia]

Excelente, muy buena adaptación. Por cierto, eliminaré el otro mensaje relacionado ¿Está bien? Saludos.

[jesuspg]

En 27/8/2022 at 16:15 , Abraham Valencia dijo:

Excelente, muy buena adaptación. Por cierto, eliminaré el otro mensaje relacionado ¿Está bien? Saludos.

Si. Ok. Sin problema.