Necesito ayuda, quisiera saber como insertar una imagen desde un sitio web en un cuadro de imagen del UserForm, he intentado de todo y no logro hacerlo, intente con este código que lo inserta en la hoja de excel y funciona de maravilla, pero no logro hacer que se incruste en un UserForm, he intentando modificarlo pero no funciona, AUXILIO!!!

Private Sub UserForm_Initialize()

    Dim URL As String
    URL = "https://petsbioforestal.es/wp-content/uploads/2020/05/porque-mi-conejo-estornuda.jpg"
    Range("C5").Select
    Hoja1.Pictures.Insert(URL).Select
    

'End Sub
 

Tambien probe con un WebBroser y si unfiona muy bien pero no logro adecuar el contenido al tamaño de mi ventada del WebBRoser, espero me puedan ayudar, saludos.

    WebBrowser2.Navigate "https://petsbioforestal.es/wp-content/uploads/2020/05/porque-mi-conejo-estornuda.jpg"

Alguien que me ayude por favor ??

En un formulario coloca un control "Image" y pega este código completo:

 

Option Explicit

Private Declare PtrSafe Function URLDownloadToFile Lib "urlmon" Alias "URLDownloadToFileA" _
    (ByVal pCaller As LongPtr, ByVal szURL As String, ByVal szFileName As String, ByVal dwReserved As Long, ByVal lpfnCB As LongPtr) As Long
Private Declare PtrSafe Function DeleteUrlCacheEntry Lib "Wininet.dll" Alias "DeleteUrlCacheEntryA" _
    (ByVal lpszUrlName As String) As Long
Private Const BINDF_GETNEWESTVERSION As Long = &H10


Private Sub CommandButton1_Click()

End Sub

Private Sub UserForm_Initialize()

    Dim imageURL As String
    Dim fileName As String
        
    imageURL = "https://petsbioforestal.es/wp-content/uploads/2020/05/porque-mi-conejo-estornuda.jpg"
    fileName = Environ("temp") & "" & Mid(imageURL, InStrRev(imageURL, "/") + 1)
    
    If DownloadFile(imageURL, fileName) Then
        Image1.Picture = LoadPicture(fileName)
    Else
        MsgBox "Error downloading " & imageURL
    End If
    
End Sub


Private Function DownloadFile(URL As String, LocalFileName As String) As Boolean
    
    Dim RetVal As Long
    
    DeleteUrlCacheEntry URL
    RetVal = URLDownloadToFile(0, URL, LocalFileName, BINDF_GETNEWESTVERSION, 0)
    DownloadFile = (RetVal = 0)

End Function

PD: Este código no es mío lo tome de aqui https://www.mrexcel.com/board/threads/load-url-image-into-userform.1060189/

Saludos.