Buenos días, estoy intentanto hacer un filtro avanzado en vba y no consigo que funcione. Estuve viendo un ejemplo que solucionaba Antoni pero ni así...

Os paso el código para ver si podeis darme un poco de ayuda.

Lo que me gustaría conseguir es un autofiltro  avanzado donde pueda filtra las filas entre dos fechas que yo introduzca con un "inputbox"

 Sub filtrarfecha()
    Dim FechaIni As date,

    Dim FechaFin As date
    
    FechaIni = InputBox("Ponga fecha inicio")
    FechaFin = InputBox("Ponga fecha fin")
   
    ActiveSheet.Range("a5:a13").AutoFilter field:=1, _
        Criteria1:=">=" & FechaIni, _
        Operator:=xlAnd, _
        Criteria2:="<=" & FechaFin
        
        ActiveSheet.AutoFilter.ApplyFilter
End Sub

 

Gracias por adelantado

Editado el el 28 de enero4 años por NAB_20

Sube tu archivo con datos para poderprobar.

Hola NAB_20,  te dejo una opción , abre el formulario, introduce fecha inicio y fecha fin y pulsa enter.

Antoni un saludo también para ti.

Prueba v1.xlsm

Hace 16 horas, Antoni dijo:

Sube tu archivo con datos para poderprobar.

PruebaFiltro.xlsm Antoni es una tabla sencilla que he creado para familiarizarme con lo que quiero hacer,

Saludos  y muchas gracias Antoni

 

JSDJSD Gracias por tu  ejemplo, podrías si no es mucha molestia explicar el código?

Simplemente te reemplace esta  línea ListBoxLista.Clear  por ListBoxLista.RowSource = "", el resto del código es tuyo, de todos modos si necesitas una explicación del mismo te subo tu código comentariado.

** Cuando se usa RowSource para cargar ListBox no se puede borrar este con Clear, si no que tienes que usar la propiedad RowSource="" para borrarlo.

Private Sub BtnBuscar_Click()

    Dim fin As Long, i As Long, n As Long
    Dim sCadena_seccion As String
    
    Set FILTRAR = ActiveWorkbook.Worksheets("Listado")
       
    
    With FILTRAR
        fin = Application.CountA(.Range("A:A"))
        If TxtBuscador = "" Then
            Me.ListBoxLista.RowSource = ("A2:G") & FILTRAR.Range("A" & Rows.Count).End(xlUp).Row
            Exit Sub
        End If
        
        For i = 2 To fin
            sCadena_seccion = .Cells(i, 1).Value
            If UCase(sCadena_seccion) Like "*" & UCase(TxtBuscador.Value) & "*" Then
                ListBoxLista.RowSource = ""
                
                Me.ListBoxLista.AddItem
                Me.ListBoxLista.List(n, 0) = .Cells(i, 1).Value
                Me.ListBoxLista.List(n, 1) = .Cells(i, 2).Value
                Me.ListBoxLista.List(n, 2) = .Cells(i, 3).Value
                Me.ListBoxLista.List(n, 3) = .Cells(i, 4).Value
                Me.ListBoxLista.List(n, 4) = .Cells(i, 5).Value
                Me.ListBoxLista.List(n, 5) = .Cells(i, 6).Value
                Me.ListBoxLista.List(n, 6) = .Cells(i, 7).Value
                n = n + 1
            End If
        Next
        Me.ListBoxLista.ColumnWidths = "30pt;150pt;150pt;50pt;50pt;60pt;60pt"
    End With
End Sub

 

Perdón esto no tenía que ponerlo aquí.

Hace 1 hora, JSDJSD dijo:

Perdón esto no tenía que ponerlo aquí.

ok JSDJSD, cuando puedas coméntame tu código porfa que me cuesta seguirlo.

El código que yo adjunté hace que se filtre todo y desaparecen los datos. No acabo de ver donde está el problema...Alguna idea?

Otra consulta, si el  formato de fecha que yo tengo en la tabla es "dd/mm/aaa hh:mm:ss" si meto en el inputbox la fecha formato "dd/mm/aaaa" filtrará correctamente?

 

Gracias por participar en el hilo.

Este si es el tuyo

Private Sub TextBox2_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)

    If KeyCode = 13 Then  ' Si pulsamos Enter  en textbox2 se ejecuta la macro
    
        date1 = TextBox1: Date2 = TextBox2 ' Asignamos  a las variales su valor
        
        With Sheets("Hoja1").Range("A1").CurrentRegion  ' Seleccionamos todo rango desde A1
        'Filtramos en la columna 1 según condicion por dos criterios en este caso >= y <=
        .AutoFilter 1, Criteria1:=">=" & CDbl(CDate(date1)), Operator:=xlAnd, Criteria2:="<=" & CDbl(CDate(Date2))
        Hoja3.Range("A1").CurrentRegion.Delete 'Borramos el contenido de la hoja3
        .SpecialCells(12).Copy Hoja3.Range("A1") 'Copiamos a partir del A1 las filas visibles del filtrado
        Me.ListBox1.RowSource = Hoja3.Range("A1"). _
        CurrentRegion.Offset(0).Address(, , , 1) ' Cargamos los datos en listbox
        .AutoFilter ' Quitamos filtro
        End With
    
    End If
    
End Sub

 

Tu macro con algún arreglillo ya funciona:

Sub filtrarfecha(): On Error GoTo ErrorFechas
    Dim FechaIni As Long
    Dim FechaFin As Long
    
    FechaIni = CLng(CDate(InputBox("Ponga fecha inicio")))
    FechaFin = CLng(CDate(InputBox("Ponga fecha fin")))
   
    ActiveSheet.Range("a5:a13").AutoFilter field:=1, _
        Criteria1:=">=" & FechaIni, _
        Operator:=xlAnd, _
        Criteria2:="<=" & FechaFin
        
   Exit Sub
ErrorFechas:
   MsgBox "Filtro cancelado por error en fechas introducidas", vbCritical
End Sub

 

He probado el código y funciona muy bien Antoni, quiero testearlo más para adaptarlo a más cosillas que quiero hacer.

JSDJSD me ha parecido muy interesante tu código, muchas gracias, me abre la mente para futuros códigos.

Muchas Gracias por la participación a  los dos, JSDJSD y Antoni.