Tengo una macro para combina celdas como yo necesito, pero esta macro solo esta definido con unos rangos de celdas pero yo necesito que cuando yo escoja cualquier rango de celdas de las columnas seleccionadas me combine, mejor dicho que me recorra como lo hace la macro crado(como guia la macro que esta grabado). Ajunto el archivo

Muchas gracias por si ayuda.

Prueba Macro .xlsm

Si lo que quieres es seleccionar un número de filas y que se combinen las celdas de la columnas C, F, I, J, K, L y M, respectivamente, selecciona las filas y ejecuta la macro CombinarFilas, si por el contrario lo que quieres es combinar rangos concretos, selecciona el  rango/rangos y ejecuta la macro CombinarColumnas. Las macros admiten selección múltiple.

Sub CombinarFilas()
Dim Área As Range
Application.ScreenUpdating = False
Application.DisplayAlerts = False
For Each Área In Selection.Areas
   With Área
      If .Rows.Count > 1 Then
         Combinar Range("C" & .Row).Resize(.Rows.Count)
         Combinar Range("F" & .Row).Resize(.Rows.Count)
         Combinar Range("I" & .Row).Resize(.Rows.Count)
         Combinar Range("J" & .Row).Resize(.Rows.Count)
         Combinar Range("K" & .Row).Resize(.Rows.Count)
         Combinar Range("L" & .Row).Resize(.Rows.Count)
         Combinar Range("M" & .Row).Resize(.Rows.Count)
      End If
   End With
Next
End Sub
'---------------------------------------
Sub CombinarColumnas()
Dim Área As Range
Application.ScreenUpdating = False
Application.DisplayAlerts = False
For Each Área In Selection.Areas
   With Área
      If .Rows.Count > 1 Then
         Combinar Área(1, 1).Resize(.Rows.Count)
      End If
   End With
Next
End Sub
'-----------------------------------
Private Sub Combinar(Rango As Range)
   With Rango
      .UnMerge
      .Merge
      .HorizontalAlignment = xlCenter
      .VerticalAlignment = xlCenter
   End With
End Sub
'-----------------------------------

 

Antoni, excelente codigo eres un genio