dejar solo lo numerico

[jotaeme]

Estimados

Junto con saludar, expongo mi problema. No quiero hacer una rutina en vba, sino mas bien intentar con una formula o un anidamiento de ellas. Tengo una columna con valores de telefonos de usuarios pero no esta limpia, es decir no contienen necesariamente solo digitos, algunas por ejemplo:  9/9445844HIJA

Como puedo dejar esa celda como 99445844 ???

 

Gracias de antemano

[John Jairo V]

¡Hola, @jotaeme!

Si tienes el texto en A3, puedes usar algo como la siguiente fórmula matricial (debes introducirla con Ctrl + Shift + Enter en vez de solo Enter, si no tienes la versión Microsoft 365):

=SUMA(SI.ERROR(EXTRAE(A3;AGREGAR(14;6;SI(--EXTRAE(A3;FILA($1:$99);1);FILA($1:$99));FILA($1:$99));1)*10^(FILA($1:$15)-1);))

Pero si tienes Excel 2019, puedes usar esta fórmula más corta:

=--CONCAT(SI.ERROR(--EXTRAE(A3;FILA($1:$99);1);""))

Nota: Mi separador de argumentos es ";".  Si no es el tuyo, cámbialo por "," o por el que maneje tu sistema.

¡Bendiciones!

[GabrielRaigosa]

Otra opcion la puede encontar en:

https://www.extendoffice.com/documents/excel/1622-excel-extract-number-from-string.html

 

 

[jotaeme]

En 19/6/2020 at 20:30 , John Jairo V dijo:

=SUMA(SI.ERROR(EXTRAE(A3;AGREGAR(14;6;SI(--EXTRAE(A3;FILA($1:$99);1);FILA($1:$99));FILA($1:$99));1)*10^(FILA($1:$15)-1);))

Estimado, me funciona casi perfecto... ocurre que cuando la celda tiene el valor 83490087 me quita los ceros...es decir deja 834987

que modifico en tu formula??

[jotaeme]

Gracias Gabriel, no consigo hacerla funcionar

[John Jairo V]

Tienes razón... con un pequeño ajuste se arregla:

Cámbiala por ésta:

=SUMA(SI.ERROR(EXTRAE(A3;AGREGAR(14;6;SI(ESNUMERO(--EXTRAE(A3;FILA($1:$99);1));FILA($1:$99));FILA($1:$99));1)*10^(FILA($1:$15)-1);))

Otra opción adicional:

=VNA(-0,9;SI.ERROR(--EXTRAE(A3;1+LARGO(A3)-FILA(A1:INDICE(A:A;LARGO(A3)));1);""))/10

¡Bendiciones!

[jotaeme]

Hace 15 horas, John Jairo V dijo:

Tienes razón... con un pequeño ajuste se arregla:

Cámbiala por ésta:

=SUMA(SI.ERROR(EXTRAE(A3;AGREGAR(14;6;SI(ESNUMERO(--EXTRAE(A3;FILA($1:$99);1));FILA($1:$99));FILA($1:$99));1)*10^(FILA($1:$15)-1);))

Otra opción adicional:

=VNA(-0,9;SI.ERROR(--EXTRAE(A3;1+LARGO(A3)-FILA(A1:INDICE(A:A;LARGO(A3)));1);""))/10

¡Bendiciones!

Estimado John Jairo, usé la primera que indicas en tu pronta respuesta, y funciona de maravillas

 

Agradecido por tu gentileza y tiempo dedicado

Saludos

 

Juan Manuel