Cuando una macro no encuentra un nombre como hacer para que siga ejecutando

[GILDARDO GONZALO LUNA GARC]

Tengo un problema a la hora de ejecutar mi macro en ocasiones no existe un nombre en mi reporte, y en ese momento la macro se detiene, como hacer para que no se detenga se que tengo que agregar unas lineas con la palabra "Falce" pero no se se donde adicionarla 

Este es el inicio de mi macro, que debo hacer para que en caso de que no encuentre "ACTIVO A CORTO PLAZO" siga en ejecución la macro ya que si no tengo en mi reporte la frase "ACTIVO A CORTO PLAZO" se detiene y me manda un error

 

        Cells.Find(What:="ACTIVO A CORTO PLAZO", After:=ActiveCell, LookIn:= _
        xlFormulas, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:= _
        xlNext, MatchCase:=False, SearchFormat:=False).Activate
    Selection.Font.Bold = True
 

O puede ser esta otra Macro

 

        Cells.Find(What:="ACTIVO A CORTO PLAZO", After:=ActiveCell, LookIn:= _
        xlFormulas, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:= _
        xlNext, MatchCase:=False, SearchFormat:=False).Activate
    Selection.Font.Bold = True
 

 

 

 

Gracias 

[GILDARDO GONZALO LUNA GARC]

agrego que me da este error

Se ha producido el error 438 en tiempo de ejecución:

El objeto no admite esta propiedad o método

[Antoni]

set celda = Cells.Find(What:="ACTIVO A CORTO PLAZO", After:=ActiveCell, LookIn:= _
        xlFormulas, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:= _
        xlNext, MatchCase:=False, SearchFormat:=False)
if not celda is nothing then celda.Font.Bold = True

 

[GILDARDO GONZALO LUNA GARC]

Hace 6 horas, Antoni dijo:

set celda = Cells.Find(What:="ACTIVO A CORTO PLAZO", After:=ActiveCell, LookIn:= _
        xlFormulas, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:= _
        xlNext, MatchCase:=False, SearchFormat:=False)
if not celda is nothing then celda.Font.Bold = True

 

Gracias Antoni, Ahora me da un error 13 en Tiempo de ejecución

No coinciden los tipos  

[Antoni]

Sin archivo no hay nada que hacer.

[GILDARDO GONZALO LUNA GARC]

Estado de variaciones .xlsm

ESTADO_VARIACIONES_POSICION_FINANCIERA.CSV

[GILDARDO GONZALO LUNA GARC]

Te mando la Macro y el reporte 

 

Saludos 

 

Gildardo Luna 

[Antoni]

Hace 20 horas, GILDARDO GONZALO LUNA GARC dijo:

Te mando la Macro y el reporte 

Saludos 

Gildardo Luna 

El archivo .xlsm está vacío. No hay macros ni datos. ¿?

[GILDARDO GONZALO LUNA GARC]

Al ejecutar la Macro me da un error 91

Se ha producido un Error “91 en tiempo de Ejecución:

Variable de Objeto o Bloque With no Establecido

 

El Error se Genera porque en el Reporte no encuentra la palabra "ACTIVO A LARGO PLAZO"

La pregunta es que instrucción le tengo que dar para que al querer ejecutar esta parte de la macro cuando no encuentre el nombre no genere el error  y siga ejecutando el resto de la macro

Cells.Find(What:="ACTIVO A LARGO PLAZO", After:=ActiveCell, LookIn:= _
xlFormulas, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:= _
xlNext, MatchCase:=False, SearchFormat:=False).Activate
Selection.Font.Bold = True

Se anexa un archivo con el reporte en dos situaciones una cuando lo ejecuta correctamente y el segundo donde se genera el error 

hice unas macros para copiar el archivo origina que es al que se le da formato con unas instrucciones en la primer pestaña 

Agradezco de Antemano el Apoyo 

Saludos

Gildardo Luna 

Estado de Cambios.xlsm

[qwerty123]

Hola.

Antes de "Cells.Find..."  escribe:  "On Error Resume Next" para evitar que se detenga por el error.

Prueba el siguiente código. Lo he retocado un poco porque con el original, supongo que lo obtendrías de la grabadora de macros, me estaba perdiendo.

 

Private Sub NuevoCambioEstado()
Dim rTotal As Range
Dim sCab1(1 To 11) As String
Dim iCab As Integer
Dim lFila As Long

    With Range("B1:B5")
        .Copy
        With .Offset(, 1)
            .PasteSpecial xlPasteAll
            .HorizontalAlignment = xlCenter
            .VerticalAlignment = xlBottom
            With .Font
                .Size = 12
                .Bold = True
            End With
            For lFila = 1 To .Rows.Count
                .Cells(lFila, 1) = Trim(.Cells(lFila, 1))
            Next
            .Resize(, 5).Merge True
        End With
    End With
    Columns("B:B").Clear
    
    With Columns("C:C")
        .ColumnWidth = 60
        .IndentLevel = 1
    End With
    
    With Columns("D:G")
        .ColumnWidth = 15
        .NumberFormat = "#,##0"
    End With
    
    With Range("C8:G8")
        .BorderAround LineStyle:=xlDouble, Weight:=xlThick
        .Borders(xlInsideVertical).LineStyle = xlContinuous
        .VerticalAlignment = xlCenter
        .HorizontalAlignment = xlCenter
        .WrapText = True
        With .Interior
            .Pattern = xlSolid
            .PatternColorIndex = xlAutomatic
            .ThemeColor = xlThemeColorAccent1
            .TintAndShade = 0.799981688894314
            .PatternTintAndShade = 0
        End With
        .Font.Bold = True
    End With
    
    With Range([C10], Cells(Rows.Count, 3).End(xlUp)).Resize(, 5)
        .BorderAround LineStyle:=xlDouble, Weight:=xlThick
        .Borders(xlInsideHorizontal).LineStyle = xlContinuous
        .Borders(xlInsideVertical).LineStyle = xlContinuous
        For lFila = 1 To .Rows.Count
            .Cells(lFila, 1) = Trim(.Cells(lFila, 1))
        Next
    
        sCab1(1) = "ACTIVO A CORTO PLAZO"
        sCab1(2) = "ACTIVO A LARGO PLAZO"
        sCab1(3) = "PASIVO A CORTO PLAZO"
        sCab1(4) = "CAPITAL"
        
        sCab1(5) = "TOTAL ACTIVO A CORTO PLAZO :"
        sCab1(6) = "TOTAL ACTIVO A LARGO PLAZO :"
        sCab1(7) = "TOTAL PASIVO A CORTO PLAZO :"
        
        sCab1(8) = "TOTAL ACTIVO :"
        sCab1(9) = "TOTAL PASIVO :"
        sCab1(10) = "TOTAL CAPITAL :"
        sCab1(11) = "TOTAL PASIVO + CAPITAL :"
        
        For iCab = 1 To UBound(sCab1)
            Set rTotal = Nothing
            On Error Resume Next
            Set rTotal = .Cells.Find(What:=sCab1(iCab), LookAt:=xlWhole)
            On Error GoTo 0
            If Not rTotal Is Nothing Then
                With rTotal.Resize(, 5)
                    .Font.Bold = True
                    If iCab > 4 Then
                        .BorderAround LineStyle:=xlDouble, Weight:=xlThick
                        With .Interior
                            .Pattern = xlSolid
                            .PatternColorIndex = xlAutomatic
                            .ThemeColor = xlThemeColorAccent1
                            .TintAndShade = 0.799981688894314
                            .PatternTintAndShade = 0
                        End With
                        .IndentLevel = 2 - (iCab > 7)
                    End If
                End With
            End If
        Next
    End With

    MsgBox "Estado de Cambios Generado", vbInformation, "TERMINADO"

End Sub

Un saludo.

[GILDARDO GONZALO LUNA GARC]

Eres un Genio aprendí mucho con la macro que hiciste 

Funciono a la perfección la macro

Agradezco mucho tu apoyo