Mensaje si no se guarda en un tiempo determinado

[tonivilaa]

Buenos días a todos y feliz año. 

Quería saber si se os acurre alguna forma de ejecutar un mensaje de recordatorio en la aplicación si no se guarda el archivo en un tiempo determinado. 

Muchas gracias!

Saludos

[Antoni]

Por la tarde, si puedo, te apaño algo.

[tonivilaa]

Muchas gracias @Antoni !!!

[Antoni]

En Thisworkbook:

Private Sub Workbook_Open()
Application.MacroOptions Macro:="ArrancarParar", ShortcutKey:="a"
ArrancarParar
End Sub

en un módulo:

'
Const Tiempo As Long = 10 'Tiempo en segundos para el aviso <======================================
'
Public Hora As Date, Empezar As Boolean, Avisar As Date, Arrancado As Boolean

Sub ArrancarReloj()
If Empezar = False Then
   Empezar = True
   Avisar = Now + Tiempo / 84400
End If
If Not Now < Avisar Then
   Empezar = False
   If MsgBox("¿Deseas guardar el archivo?", vbQuestion + vbYesNo, "Tiempo sin guardar excedido") = vbYes Then
      ActiveWorkbook.Save
   End If
End If
Application.StatusBar = "Control de guardado activado. Ctrl+a para desactivarlo. Guardar en: " & _
                        Format(Avisar - Now, "hh:mm:ss")
Hora = Now + TimeValue("00:00:01")
Application.OnTime Hora, "ArrancarReloj", SCHEDULE:=True
End Sub

Sub PararReloj(): On Error Resume Next
Empezar = False
Application.OnTime Hora, "ArrancarReloj", SCHEDULE:=False
End Sub

Sub ArrancarParar()
If Arrancado = False Then
   Arrancado = True
   ArrancarReloj
Else
   Arrancado = False
   PararReloj
   MsgBox "Control de guardado desactivado. Ctrl+a para volverlo a activar.", vbInformation
   Application.StatusBar = False
End If
End Sub

Ctrl+a para arrancar/parar el control de guardado.

Con el control de guardado activado, aparece el tiempo restante hasta el aviso de guardado en la barra de estado de Excel.

El ejemplo está programado a 10 segundos, solo tienes que modificar la constante Tiempo en el Módulo1 y ajustarla a tus necesidades.

Control de guardado.xlsm

[tonivilaa]

Buenas tardes @Antoni,

Muchísimas por tu ayuda de nuevo!

Un abrazo