Autoajuste de ejes de un gráfico según valores máximos y mínimos de unas celdas

[fsaneus]

Hola a todos,

Como sabéis los gráficos de Excel tienen la posibilidad de autoajustar sus ejes X e Y de manera automática en las opciones de gráfico, pero por alguna extraña razón, cuando el rango de los datos de origen es superior a un valor determinado, el valor mínimo de los ejes te lo deja en 0, y no autoajusta adecuadamente la gráfica. Así, tratando de resolver este problema he creado el siguiente código:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

Dim objCht As ChartObject

For Each objCht In ActiveSheet.ChartObjects

With objCht.Chart

' Valores para el eje (Y)

With .Axes(xlValue)

.MaximumScale = Sheets("Calibración").Range("Chart1MaxY").Value

.MinimumScale = Sheets("Calibración").Range("Chart1MinY").Value

'.MajorUnit = Sheets("Calibración").Range("CalUnitY").Value

End With

' Valores para el eje (X)

With .Axes(xlCategory)

.MaximumScale = Sheets("Calibración").Range("Chart1MaxX").Value

.MinimumScale = Sheets("Calibración").Range("Chart1MinX").Value

'.MajorUnit = Sheets("Calibración").Range("CalUnitY").Value

End With

End With

Next objCht

End Sub

El código funciona perfectamente autoajustando los ejes de las gráficas si se modifican los datos primarios de la gráfica Chart1, si no fuera porque, como veréis en el ejemplo, actúa sobre todas las gráficas de la hoja activa. Así, cuando en la misma hoja hay varias gráficas, todas ellas se autoajustan en base a los mismos valores máximo y mínimo que se le han especificado, en este caso, los correspondientes a la gráfica Chart1: Chart1MaxY, Chart1MinY y Chart1MaxX y Chart1MinX.

Mi problema, y por lo que escribo en el foro, es porque no sé cómo indicar en el código que para cada gráfica (Chart1 y Chart2) quiero que los valores de autoajuste de X y de Y sean diferentes, es decir, quiero que para la gráfica Chart1 coja los que hay en el código (Chart1MaxY, Chart1MinY y Chart1MaxX y Chart1MinX) y para Chart2 los suyos (Chart2MaxY, Chart2MinY y Chart2MaxX y Chart2MinX). Para facilitar la comprensión del caso, adjunto un archivo de ejemplo donde lo explico:

"Ejmplo autoajuste ejes.xlsm"

https://www.dropbox.com/s/gfuc7w7hod0t1gl/Ejmplo%20autoajuste%20ejes.xlsm

Agradezco de antemano cualquier comentario o ayuda que podáis prestarme.

Un saludo,

[temporaconsultores]

Prueba a poner esto en la ventana de código de la hoja donde están los gráficos, seleccionando el evento Activate (y sustituyendo los rangos A1, A2, B1 y B2 por las celdas donde tengas los valores min y max de los ejes):

ActiveSheet.ChartObjects("Chart1").Activate

ActiveChart.Axes(xlValue).Select

ActiveChart.Axes(xlValue).MinimumScale = Range(A1)

ActiveChart.Axes(xlValue).MaximumScale = Range(A2)

ActiveSheet.ChartObjects("Chart2").Activate

ActiveChart.Axes(xlValue).Select

ActiveChart.Axes(xlValue).MinimumScale = Range(B1)

ActiveChart.Axes(xlValue).MaximumScale = Range(B2)

Saludos

[fsaneus]

¡Hola temporaconsultores! Muchas gracias por la rápida respuesta. He estado haciendo pruebas con lo que me habéis propuesto pero quizás no he escrito bien el código porque me da error:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

ActiveSheet.ChartObjects("Chart1").Activate

ActiveChart.Axes(xlValue).Select

ActiveChart.Axes(xlValue).MinimumScale = Range("Chart1MinY")

ActiveChart.Axes(xlValue).MaximumScale = Range("Chart1MaxY")

ActiveChart.Axes(xlCategory).Select

ActiveChart.Axes(xlCategory).MinimumScale = Range("Chart1MinX")

ActiveChart.Axes(xlCategory).MaximumScale = Range("Chart1MaxX")

ActiveSheet.ChartObjects("Chart2").Activate

ActiveChart.Axes(xlValue).Select

ActiveChart.Axes(xlValue).MinimumScale = Range("Chart2MinY")

ActiveChart.Axes(xlValue).MaximumScale = Range("Chart2MaxY")

ActiveChart.Axes(xlCategory).Select

ActiveChart.Axes(xlCategory).MinimumScale = Range("Chart2MinX")

ActiveChart.Axes(xlCategory).MaximumScale = Range("Chart2MaxX")

End Sub

¿Qué he hecho mal?

Un saludo y muchas gracias por la ayuda.

[fsaneus]

Finalmente, lo he resuelto con un Select Case, gracias a JuanC, un chico de otro foro. El código va de lujo:

Private Sub Worksheet_Change(ByVal Target As Range)

Dim objCht As ChartObject

For Each objCht In ActiveSheet.ChartObjects

With objCht.Chart

Select Case .Name

Case "Calibración Gráfico 2"

' Valores para el eje (Y) Chart1

With .Axes(xlValue)

.MaximumScale = Sheets("Calibración").Range("Chart1MaxY").Value

.MinimumScale = Sheets("Calibración").Range("Chart1MinY").Value

.MajorUnit = Sheets("Calibración").Range("Chart1UnitY").Value

End With

' Valores para el eje (X) Chart1

With .Axes(xlCategory)

.MaximumScale = Sheets("Calibración").Range("Chart1MaxX").Value

.MinimumScale = Sheets("Calibración").Range("Chart1MinX").Value

.MajorUnit = Sheets("Calibración").Range("Chart1UnitX").Value

End With

Case "Calibración Gráfico 3"

' Valores para el eje (Y) Chart2

With .Axes(xlValue)

.MaximumScale = Sheets("Calibración").Range("Chart2MaxY").Value

.MinimumScale = Sheets("Calibración").Range("Chart2MinY").Value

.MajorUnit = Sheets("Calibración").Range("Chart2UnitY").Value

End With

' Valores para el eje (X) Chart2

With .Axes(xlCategory)

.MaximumScale = Sheets("Calibración").Range("Chart2MaxX").Value

.MinimumScale = Sheets("Calibración").Range("Chart2MinX").Value

.MajorUnit = Sheets("Calibración").Range("Chart2UnitX").Value

End With

End Select

End With

Next objCht

End Sub

Un saludo y gracias a todos,