Buenos dias

pues es lo que necesito si alguien me puede ayudar, una macro que al ejecutarla me ordene una base de datos y me bloquee las celdas que contienen datos.

anexo libro

Gracias anticipadas

Saludos

Formato Pagos.xls

Salexis, te envío textual el código de la macro (no he podido subirte el archivo, tengo problemas de conexión)

Sub ordenar()

    Dim N_datos As Long

    'Des-protegemos la hoja
    ActiveSheet.Unprotect Password:="prueba"

    'Primero establecemos la cantidad de datos a ordenar
    If Range("B2") = "" Then
        N_datos = 0
    Else
        If Range("C2") = "" Then
            N_datos = 1
        Else
            N_datos = Range("B2").End(xlDown).Row - 1
                'La instrucción Range("B2").End(xldown) recorre desde la celda B2
                'hacia abajo, hasta la última celda no vacía consecutiva que encuentre.
                'Por tanto, obtiene la cantidad total de datos de la tabla.
                'Se resta 1 porque los datos empiezan en la fila 2, si llega por ejemplo
                'hasta la fila 6, significa que hay 5 datos.
        End If
    End If

    'Ahora ordenamos en forma ascendente, especificando el rango de datos adecuado,
    'según la columna B
    Range("A2:" & "D" & N_datos + 1).Sort _
        Key1:=Range("B2"), Order1:=xlAscending, Header:=xlNo, _
        MatchCase:=False, Orientation:=xlSortColumns, _
        DataOption1:=xlSortNormal

    'Ahora protegemos cada celda del mismo rango.
    'Recuerda que debes proteger la hoja al final, para que tenga validez la protección
    'de las celdas
    For Each celda In Range("A2:" & "D" & N_datos + 1)
        If celda <> "" Then
            celda.Locked = True
        Else
            celda.Locked = False
        End If
    Next

    'Re-protegemos la hoja
    ActiveSheet.Protect Password:="prueba"
End Sub
[/CODE]

Te explico un poco: El problema es la selección del rango de datos para ordenar. Como dices, la columna A puede tener celdas vacías, así como la C y D. Pero entiendo que la columna B siempre tendrá todos sus campos completos, por lo tanto de ahí vamos extraer la cantidad de datos, con la instrucción:
[code]
N_datos = Range("B2").End(xlDown).Row - 1

luego fijamos el rango de ordenamiento con:

Range("A2:" & "D" & N_datos + 1)

Para entenderla, supón que N_Datos=5, entonces la instrucción anterior se interpreta como Range("A2: A6"), justo lo que queremos.

Por último, protegemos solo las celdas que "contienen valores", o según entiendo, las que no son vacías. Para ello, manipulamos la propiedad .Locked de cada celda del rango, estableciéndola a True o False según el caso.

Para que la protección tenga lugar es necesario que protejas la hoja con la contraseña deseada, para lo cual usamos Activesheet.Protect

Nota que al inicio del código hay de desproteger la hoja, de otro modo no sería posible ordenar los datos.

es exactamente lo que necesitaba, muchas gracias