Hola, estoy haciendo una macro en la que tengo que crear un gráfico donde como parte del titulo agrego la fecha de creación, sin embargo al agregar la fecha queda todo del mismo tamaño y quería hacer que la fecha incluida en el titulo apareciera mas pequeña (ej. tamaño 10) y el resto del titulo apareciera mas grande (ej. tamaño 14).

A continuación dejo el código donde agrego el gráfico.

With ActiveChart
          .ApplyChartTemplate (ActiveWorkbook.Path & "\series_barra.crtx")
          .HasTitle = True
          .ChartTitle.Characters.Text = titulo & Chr(13) & "(" & CStr(Date) & ")"
          .Axes(xlCategory, xlPrimary).HasTitle = True
         .Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = Range("J3")
         .Axes(xlCategory, xlPrimary).AxisTitle.Font.Size = 14
         .Axes(xlValue, xlPrimary).HasTitle = True
         .Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "Concentración"
         .Axes(xlValue, xlPrimary).AxisTitle.Font.Size = 14
         .Legend.Width = 60
End With[/PHP]

Espero me puedan ayudar

Intenta adaptar este código a tus necesidades.....

Selection.Characters.Text = "yop" [COLOR=#0000ff]'suponiendo que ese es el título que quieres seleccionar/modificar[/COLOR]

    Selection.AutoScaleFont = False

With Selection.Characters(Start:=3, Length:=1).Font [COLOR=#0000ff]'con esto cambiarías la "p"[/COLOR]

        .Name = "Arial"

        .FontStyle = "Negrita"

        .Size = 12

        .Strikethrough = False

        .Superscript = False

        .Subscript = False

        .OutlineFont = False

        .Shadow = False

        .Underline = xlUnderlineStyleNone

        .ColorIndex = xlAutomatic

    End With

[/CODE]

Espero que te sirva.

Un saludo,

Tese

Hola! kenoro (y tese). Podrías, por ejemplo:

a) Definir una variable entera:

Dim lenDate As Integer

Y reemplazar la línea:

.ChartTitle.Characters.Text = titulo & Chr(13) & "(" & CStr(Date) & ")"

por lo siguiente:

    With .ChartTitle
      .Text = titulo & Chr(13) & "(" & Date & ")"
      lenDate = Len(.Text) - Len(titulo)
      .Characters.Font.Bold = msoTrue
      .Characters(1, Len(titulo)).Font.Size = 14
      .Characters(1 + Len(titulo), lenDate).Font.Size = 10
    End With[/PHP]

Comenta tu experiencia, por favor.

Saludos, Cacho R.

Tese y Cacho R. muchas gracias a ambos, me funciono perfectamente lo que me propusieron con lo de Tese intente pero no pude seleccionar el texto ya que el largo del titulo era variable, me faltaba la parte de definir el integer y reemplazar como dijo Cacho.

Nuevamente agradeciendo a ambos doy por solucionado el tema

Saludos