buenos días expertos estoy modificando mi programa, pero lo que intento es, desde un botón generar nuevos TextBox, no se como puedo hacerlo , agradecería mucho vuestra ayuda

gracias de antemano

si es posible un ejemplo practico

Pues por ejemplo para crear 4 controles de texto y sus etiquetas con las descripciones a la izquierda al lanzar el formulario el código podría ser:

Private Sub UserForm_Initialize()

    Dim ctrLBL As MSForms.Label     'Para las etiquetas

    Dim ctrTB As MSForms.TextBox    'Para los cuadros de texto

    Dim n As Byte


    With Me

        For n = 1 To 4

            Set ctrLBL = .Controls.Add("Forms.Label.1")

            With ctrLBL

                .Caption = "Etiqueta " & n

                .Height = 16

                .Width = 40

                .Top = ((n - 1) * 16) + 3

                .Left = 40

                .BorderStyle = fmBorderStyleSingle

                .Font.Size = 8

                .Name = "Etiqueta" & n

            End With


            Set ctrTB = .Controls.Add("Forms.TextBox.1")

            With ctrTB

                .Value = 0

                .Height = 16

                .Width = 40

                .Top = ((n - 1) * 16) + 3

                .Left = 81

                .Font.Size = 8

                .TextAlign = fmTextAlignRight

                .Name = "Cuadro_de_Texto" & n

            End With

        Next n

    End With

End Sub[/CODE]

Para que funcione bien aconsejo usarlo en un formulario en blanco, porque si hubiese más controles el código podría poner encima los creados por él.

Saludos.