Jump to content

Transponer si hay datos


Recommended Posts

Hola;

llevo unos dias intentando transponer unos datos pero no consigo hacerlo, he probado con la función transponer, pero no es exactamente eso lo que quiero.

Tengo los valores ordenador como estan en la hoja "Datos iniciales", y los quiero poner como estan en la hoja "Pasar Datos".

En el ejemplo hay 10 empleados, y 5 conceptos distintos ,pero normalmente ese proceso tiene 500 empleados con unos 15 conceptos.

Si os preguntais como se hace ahora, pues, se hace uno a uno :(, la intencion que tengo, y he probado es pasar los datos mediante access (tabla vinculada), a una tabla oracle, que es donde lo necesito.

pero lo que no consigo es dejar los datos como estan en la hoja "Pasar Datos". los datos se pasan una vez al mes.

Me podriais ayudar porfavor.

Un Saludo.

Jose Maria.

ejemplo.xls

Link to comment
Share on other sites

Guest Cacho R

Hola! José.

¿Puedes confirmar que la estructura de datos que tienes es tal como la has mostrado, y que los conceptos comienzan a partir de la celda H1, y hacia la derecha "tantos como sean necesarios"?...

Link to comment
Share on other sites

Hola Cacho R;

Exactamente es eso, de echo he comprado a poner unos 100 empledos y gualap es increible lo rapido que va, aunque se crea en otro libro pero bueno. Luego la macro que utilizo para pasar los datos a la tabla vinculada de access pues la copio en el nuevo libro y sin problemas.

si fuera posible para entender un poco mas el codigo, podrias responder a las preguntas que hay 'comentadas en tu codigo, te adjunto el codigo:

Private Sub DatosParaOracle_Click()
'-------------------
' By Cacho Rodríguez
'-------------------
Dim mySh As Worksheet, C As Range, Q1 As Long, Q2 As Long, newRow As Long

Application.ScreenUpdating = False
[h1].Copy [ba1:bb1] 'que quiere decir ba1:bb1? no hay datos en eses rango, ¿no?
[ba2:bb2] = Array("<>0", "<>") ' con este rango igual
If FilterMode Then ShowAllData
Q1 = [a1].End(xlDown).Row - 1 ' con esta linea le digo que mire hasta el final del excel
Set mySh = Workbooks.Add(xlWBATWorksheet).ActiveSheet 'se crea un nuevo libro con los nuevos datos
mySh.Name = "para Oracle" ' a la variable mySh le asignas un nombre de hoja
[a1:f1].Copy mySh.[a1] ' empiezo a copiar en la nueva hoja a partir de a1, el rango a1:f1 de la hoja original ¿el rago se puede cambiar, no?
[h1].Copy mySh.[g1:h1] 'copio en la nueva hoja el valor de h1.
mySh.[g1:h1] = Array("CONCEPTO", "VALOR") ' y mientras que haya valores pues los voy poniendo

For Each C In Range([h1], [h1].End(xlToRight))
Q2 = Evaluate("SUMPRODUCT(--(" & C.Offset(1).Resize(Q1).Address & " <> 0))")
If Q2 > 0 Then
C.Copy [ba1:bb1]
C.Resize(1 + Q1).AdvancedFilter xlFilterInPlace, [ba1:bb2]
newRow = 1 + mySh.[a44444].End(xlUp).Row
[a2:f2].Resize(Q1).Copy mySh.Cells(newRow, "a")
C.Copy mySh.Cells(newRow, "g").Resize(Q2)
C.Offset(1).Resize(Q1).Copy mySh.Cells(newRow, "h")
End If
Next C ' este bucle es el que va generando y copiando en el nuevo archivo los parametros establecidos.

With mySh.[a1].CurrentRegion '¿este bucle es para poner la cabecera de la nueva hoja?
.EntireColumn.AutoFit
.Sort key1:=mySh.[a1], order1:=xlAscending, key2:=mySh.[g1], order2:=xlAscending, Header:=True
End With

ShowAllData
[ba1:bb2].Delete xlShiftToLeft ' el rango ba1:bb2 ¿que haces con el?
Application.ScreenUpdating = True
Set mySh = Nothing
End Sub[/CODE]

aunque parezca una tonteria y yo no sepa crear esa maravilla, por lo menos me gusta entenderlo un poco.

Gracias por todo.

Un Saludo.

Jose Maria.

Link to comment
Share on other sites

Guest Cacho R

Las cuatro celdas BA1:BB2 están lo suficientemente alejadas de la zona de datos útiles como para que podamos utilizarlas como "celdas auxiliares".

Ésa es la causa por la que -al final del código- sus respectivos contenidos son eliminados.

Después de:

[ba2:bb2] = Array("<>0", "<>")

inserta una línea adicional con:

Exit Sub

y corre el código...

Verás que las cuatro celdas en cuestión quedan dispuestas para aplicar un filtro avanzado.

De hecho: el código mostrado se basa en una sucesión de filros avanzados "tantos como conceptos haya".

Entonces aplica el primer filtro avanzado según te muestro en la imagen:

[ATTACH]29052.vB[/ATTACH]

¿Adviertes que ocurre?...

¡En efecto! quedaron seleccionados los únicos tres empleados que tienen datos asociados al concepto P17.

Hecho lo anterior, el código copia (al nuevo libro) las columnas A:F correspondientes a los empleados que tienen datos en el concepto P17, "arma" la columna G (del nuevo libro) con el concepto P17, y termina copiando los valores asociados.

El loop For Each C - Next C recorre -uno a uno- los conceptos y ejecuta la misma rutina.

En resumen: sólo tienes que entender bien como trabaja un filtro avanzado, cosa que -por cierto- tiene que ver con el Excel y no con el VBA.

Saludos, Cacho R.

post-78958-145877004504_thumb.jpg

Link to comment
Share on other sites

Guest Cacho R

Q1 = [a1].End(xlDown).Row - 1

Con la lista no filtrada, selecciona la celda A1.

Presiona la tecla Ctrl y -sin soltarla- presiona una sola vez la tecla de dirección (la flecha) hacia abajo.

¿Notaste que pasó?...

¡Hubo un salto "violento" hacia la última celda ocupada de la columna A!

Esa última celda es [a1].End(xlDown), mientras que .Row te brinda su fila. Luego Q1 indicará -desde un comienzo- la cantidad de filas de datos que contiene tu tabla.

_____________________

mySh.Name = "para Oracle"

mySh no es el nombre de la hoja... ¡es la hoja propiamente dicha!.

En lugar de utilizar ActiveSheet utilizo mySh.

El nombre de esa hoja es mySh.Name.

_____________________

[a1:f1].Copy mySh.[a1]

[h1].Copy mySh.[g1:h1]

mySh.[g1:h1] = Array("CONCEPTO", "VALOR")

Estas tres líneas arman el encabezado de la nueva hoja.

Puedes detener la macro después de la tercera línea y verás como queda "armado".

La segunda línea sólo cumple una función: "copiar" el formato de la celda [h1] ya que su contenido es -inmediatamente- establecido por la línea siguiente.

_____________________

With mySh.[a1].CurrentRegion

.EntireColumn.AutoFit

.Sort key1:=mySh.[a1], order1:=xlAscending, key2:=mySh.[g1], order2:=xlAscending, Header:=True

End With

Lo anterior no es -ni por casualidad- un bucle...

Te sugiero que estudies a partir de la propia ayuda del VBA tres cosas:

-> With / End With

-> Autofit (aplicado a una columna)

-> Sort (aplicado a un rango)

Link to comment
Share on other sites

Archived

This topic is now archived and is closed to further replies.

×
×
  • Create New...

Important Information

Privacy Policy